Menu multiple Batch

**yoan111** · 08/05/2018, 16h41

comment fait pour valider des menu multiple ???

Ex. Fichier par Fichier ou un groupe de fichier ?? 1 ou 2 :
et après choisir de menu du dvd ??
je m’explique convertx peut soit convertir
au optimiser mon code si c'est possible MERCI.

un fichier normal

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

"%_Path%" /file "%%I" /menu="%_diapo%" /auto=true /close))

soit un groupe de fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
dir *.avi ou mp4 ou mpg dans un dossier /B>file_list.txt
"%_Path%" /fl "file_list.txt" /auto=true /close

mon but c'est de faire choisir entre 1 groupe de fichier dans seule dvd ou un par fichier separer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
@echo off
setlocal enableextensions
Set _Path=C:\Program Files (x86)\VSO\ConvertX\5\ConvertXtoDvd.exe
Set _diapo=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\film\film_5ch.ini
Set _bleu1=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso1\vso1_4ch.ini
Set _bleu4=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_blue_4ch.ini
Set _bleu6=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_blue_6ch.ini
Set _vert4=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_green_4ch.ini
Set _vert6=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_green_6ch.ini
Set _rose4=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_magenta_4ch.ini
Set _rose6=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_magenta_6ch.ini
Set _gris4=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_metal_4ch.ini
Set _gris6=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_metal_6ch.ini
Set _noir4=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_clear_4ch.ini
Set _noir6=C:\ProgramData\VSO\ConvertXtoDVD\5\templates\vso glossy\vsoglossy_clear_6ch.ini
:main
cls
echo 01 - Menu Diapo
echo 02 - Menu Bleu 1
echo 03 - Menu Bleu 4
echo 04 - Menu Bleu 6
echo 05 - Menu Vert 4
echo 06 - Menu Vert 6
echo 07 - Menu Rose 4
echo 08 - Menu Rose 6
echo 09 - Menu Gris 4
echo 10 - Menu Gris 6
echo 11 - Menu Noir 4
echo 12 - Menu Noir 6
echo 13 - Quitter
set /p reponse="Choix du Menu entre 1 et 13 ? "
If "%reponse%"=="" goto :sub_error
If "%reponse%"=="1" goto :01
If "%reponse%"=="2" goto :02
If "%reponse%"=="3" goto :03
If "%reponse%"=="4" goto :04
If "%reponse%"=="5" goto :05
If "%reponse%"=="6" goto :06
If "%reponse%"=="7" goto :07
If "%reponse%"=="8" goto :08
If "%reponse%"=="9" goto :09
If "%reponse%"=="10" goto :10
If "%reponse%"=="11" goto :11
If "%reponse%"=="12" goto :12
If "%reponse%"=="13" goto :end
:sub_error
cls
goto main
:01
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_diapo%" /auto=true /close))
goto :end
:02
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_bleu1%" /auto=true /close))
goto :end
:03
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_bleu4%" /auto=true /close))
goto :end
:04
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_bleu6%" /auto=true /close))
goto :end
:05
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_vert4%" /auto=true /close))
goto :end
:06
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_vert6%" /auto=true /close))
goto :end
:07
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_rose4%" /auto=true /close))
goto :end
:08
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_rose6%" /auto=true /close))
goto :end
:09
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_gris4%" /auto=true /close))
goto :end
:10
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_gris6%" /auto=true /close))
goto :end
:11
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_noir4%" /auto=true /close))
goto :end
:12
for /F "delims=;" %%I in ('2^>nul dir *.mp4 /B') do (
echo Conversion de %%I avec le menu choix du menu en Cours...
if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%I" /menu="%_noir6%" /auto=true /close))
goto :end
:end
exit

**barnabe0057** · 09/05/2018, 21h18

Bonjour,

Voilà le même code, mais optimisé cette fois-ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
@echo off
setlocal enableextensions enabledelayedexpansion

Set _Path=C:\Program Files (x86)\VSO\ConvertX\5\ConvertXtoDvd.exe
set template=C:\ProgramData\VSO\ConvertXtoDVD\5\templates

Set _Diapo=%template%\film\film_5ch.ini
Set _Bleu1=%template%\vso1\vso1_4ch.ini
Set _Bleu4=%template%\vso glossy\vsoglossy_blue_4ch.ini
Set _Bleu6=%template%\vso glossy\vsoglossy_blue_6ch.ini
Set _Vert4=%template%\vso glossy\vsoglossy_green_4ch.ini
Set _Vert6=%template%\vso glossy\vsoglossy_green_6ch.ini
Set _Rose4=%template%\vso glossy\vsoglossy_magenta_4ch.ini
Set _Rose6=%template%\vso glossy\vsoglossy_magenta_6ch.ini
Set _Gris4=%template%\vso glossy\vsoglossy_metal_4ch.ini
Set _Gris6=%template%\vso glossy\vsoglossy_metal_6ch.ini
Set _Noir4=%template%\vso glossy\vsoglossy_clear_4ch.ini
Set _Noir6=%template%\vso glossy\vsoglossy_clear_6ch.ini

:main
cls & set "reponse="

set nb=0
for %%A in (Diapo Bleu1 Bleu4 Bleu6 Vert4 Vert6 Rose4 Rose6 Gris4 Gris6 Noir4 Noir6 Quitter) do (
	set /a nb+=1
	if !nb! LSS 10 (set nb= !nb!)
	if "%%A"=="Quitter" (echo !nb! - %%A) else (echo !nb! - Menu %%A)
)

echo. & set /p reponse="Choix du Menu entre 1 et 13 ? "
if not defined reponse (goto :main)
if %reponse% EQU 13 (exit /b 0)

set nb=0
for %%A in (Diapo Bleu1 Bleu4 Bleu6 Vert4 Vert6 Rose4 Rose6 Gris4 Gris6 Noir4 Noir6) do (
	set /a nb+=1
	If "%reponse%"=="!nb!" (call :conversion %%A)
)
goto :main

:conversion
for /F "delims=;" %%I in ('2^>nul dir "*.mp4" /B') do (
	echo. & echo Conversion de %%I avec le menu choix du menu en Cours...
	if not exist "c:\DVDVolume\%%~nI" ("%_Path%" /file "%%~I" /menu="!_%1!" /auto=true /close)
)
pause
goto :eof

rem

Menu multiple Batch

Scripts/Batch

Vue hybride

Discussions similaires

Partager

Partager