Discussion :

[Areis]

Bonjour,

Je cherche à créer une mise en forme conditionnelle via un code VBA. J'ai réussi à faire en sorte que la ligne complète de mon tableau soit mise sur fond gris si la cellule I2 est vide, avec le code suivant (en partie trouvée via l'enregistreur de macro) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Mise_en_forme()
    ' Récupération des dimensions du tableau (utilisées à d'autres endroits dans ma macro complète...)
    Range("A1").Select
    Nb_rows = ActiveCell.SpecialCells(xlLastCell).Row
    Nb_columns = ActiveCell.SpecialCells(xlLastCell).Column
 
    ' Ajout de la mise en forme conditionnelle
    Range("A2").Select
    Range(Cells(2, 1), Cells(Nb_rows - 1, Nb_columns)).Select
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=$I2="""""
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    Selection.FormatConditions(1).Interior.Color = RGB(211, 211, 211)
    Selection.FormatConditions(1).StopIfTrue = False
End Sub

Si mon code marche bien avec la cellule I2 pour tout mon tableau, je ne sais pas comment faire pour lui dire de prendre l'antépénultième cellule de ma ligne (celle qui m'intéresse réellement) ; je peux la calculer la référence de la colonne avec Nb_columns-2 mais je ne sais pas comment utiliser cette information dans le code...

J'ai tenté de remplacer la formule avec ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=R2C[Nb_columns-2]="""""

... mais ça ne fonctionne pas... J'imagine que ce n'est pas très compliqué mais quelqu'un peut-il m'aider ?

[joe.levrai]

Bonjour,

tu peux calculer ce numéro de colonne et ensuite l'utiliser ?
une proposition qui part des principes suivants :

- les données commencent en A1
- il n'y a aucune ligne ou colonne entièrement vide dans ta plage (les données sont contigües)
- la MEF ne doit pas s'appliquer à la ligne 1, je pars du principe que ce sont des en-têtes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Mise_en_forme()
    ' la plage contigüe
    With Thisworkbook.Worksheets("MaFeuille").Range("A1").CurrentRegion
        ' on ne prend que les données (pas la ligne 1)
        With .Offset(1, 0).Resize(.Rows.Count - 1, .Columns.Count)
            ' mise en place de la formule avec la colonne en référence absolue et la ligne en référence relative
            ' on prend l'avant avant-dernière colonne
            .FormatConditions.Add xlExpression, , "=" & Cells(2, .Columns.Count - 2).Address(False, True) & "="""""
            .FormatConditions(.FormatConditions.Count).SetFirstPriority
            .FormatConditions(1).Interior.Color = RGB(211, 211, 211)
            .FormatConditions(1).StopIfTrue = False
        End With
    End With
End Sub

A éventuellement adapter

[Areis]

A éventuellement adapter

C'est parfait, exactement ce que je cherchais !

Juste en terme de syntaxe, c'est le ".Adress(False, True)" signifie que les colonnes sont en référence absolue et les lignes en référence relative ?

Un grand merci Joe !

[joe.levrai]

Oui c'est ça

la propriété .Address possède deux paramètres facultatifs pour spécifier le mode de référencement des lignes/colonnes en absolu.

Par défaut, les propriétés RowAbsolute et ColumnAbsolute sont à True

https://msdn.microsoft.com/fr-fr/vba...property-excel

[Areis]

C'est top, merci à toi