Discussion :

[IceCrime752]

Hello le férus,

Je me demandais s'était possible de faire une comparaison de date et déterminer si oui ou non c’est le WE. Je m'explique : je voudrais faire un prog qui se lance au démarrage (ça c'est fastoche) et qui selon si c'est le WE ou non lance des procédures différentes (ça aussi, fastoche).

Pour que le code marche, il me manque seulement le jour de la semaine. Y-a-t-il une ligne de commande déjà existante ? Ou bien tout simplement une formule ?


Merci pour votre aide,
ICE

[hackoofr]

Ah ça tombe bien je crois que vous avez de la chance, car j'ai posté il y a quelques jours dans un forum anglais un script If Monday to Friday do 1 thing, if weekend do another thing
Donc, c'est quelque chose de similaire. Je vous laisse le modifier à votre guise et de le traduire en français

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
@echo off & Setlocal EnableDelayedExpansion
Title Execute a program based on Date of Week
Call :GetWeekDayIndex "%Date%"
Set "DayOfWeekNames=Sunday Monday Tuesday Wednesday Thursday Friday Saturday"
For /f "tokens=%DayOfWeekIndex%" %%d in ("%DayOfWeekNames%") do (
    set "DayOfWeekName=%%d"
    IF /I "!DayOfWeekName!" EQU "Saturday" (
        goto Shutdown
    )    
    If /I "!DayOfWeekName!" EQU "Sunday" (
        goto Shutdown
    ) else (
        goto StartMyProgram
    )    
)
Exit
::*********************************************************************
:GetWeekDayIndex
set file="%temp%\%~n0.temp.vbs"
echo>%file% WScript.Echo weekday("%~1")
for /f %%a in ('cscript //nologo %file%') do set "DayOfWeekIndex=%%a"
del %file%
exit /b
::*********************************************************************
:shutdown
echo Today is "!DayOfWeekName!" , so we should shutdown
Timeout /T 5 /nobreak>nul
exit /b
::*********************************************************************
:StartMyProgram
echo Today is "!DayOfWeekName!", so we start our program
Start "" "Calc.exe"
Timeout /T 5 /nobreak>nul
exit /b
::*********************************************************************

[hackoofr]

Voici la version traduite en français

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
@echo off & Setlocal EnableDelayedExpansion
Title Executer un programme base sur la date de la semaine
Call :GetWeekDayIndex "%Date%"
Set "DayOfWeekNames=Dimanche Lundi Mardi Mercredi Jeudi Vendredi Samedi"
For /f "tokens=%DayOfWeekIndex%" %%d in ("%DayOfWeekNames%") do (
    set "DayOfWeekName=%%d"
    IF /I "!DayOfWeekName!" EQU "Samedi" (
        goto Shutdown
    )    
    If /I "!DayOfWeekName!" EQU "Dimanche" (
        goto Shutdown
    ) else (
        goto StartMyProgram
    )    
)
Exit
::*********************************************************************
:GetWeekDayIndex
set file="%temp%\%~n0.temp.vbs"
echo>%file% WScript.Echo weekday("%~1")
for /f %%a in ('cscript //nologo %file%') do set "DayOfWeekIndex=%%a"
del %file%
exit /b
::*********************************************************************
:shutdown
echo Aujourd'hui est : "!DayOfWeekName!" , C'est un jour de repos donc nous devrions fermer
Timeout /T 5 /nobreak>nul
exit /b
::*********************************************************************
:StartMyProgram
echo Aujourd'hui est : "!DayOfWeekName!", alors on va lancer notre programme
Start "" "Calc.exe"
Timeout /T 5 /nobreak>nul
exit /b
::*********************************************************************

[IceCrime752]

Rapide précis et concis...

J'adore ce site et ses utilisateurs !!
Merci à toi hackoofr, tout est résolu.

Bonne continuation