Discussion :

[RyuAutodidacte]

Bonjour PBELL,

j'ai besoin de mettre une signature dans l'envoi d'e-mails aussi bien dans Mail que dans OutLook.

Pour ce faire, a priori je ne vois que 2 façons de faire (voir peut-être 3, toutes suggestions sont les bienvenues) :
• l'envoi via une signature enregistrée dans les préférences de l'application Mail ou OutLook
• l'envoi d'une signature faite manuellement dont je pense (je ne suis pas sur) serait inclu dans le paramètre content (le plus simple à faire)
• l'envoi d'une signature au format html (là, je n'ai aucune idée de la façon dont il faut s'y prendre)

J'ai trouvé comment assigné une signature par défaut qui a été créé dans les préférences de Mail (mais pas dans OutLook) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

	set theMessage to make new outgoing message with properties {subject:My_Subject, content:Txt_Content, visible:true, message signature:signature "Signature #1"}

… à condition de connaître le nom de la signature mis dans les préférences de l'application Mail (ou Outlook), sinon il faut surement pouvoir récupérer les signatures existantes dans les préférences afin de pouvoir en appliquer une … ?


Pour ce qui est d'une signature manuelle je pense qu'il faudrait s'y prendre de cette manière (aussi bien pour Mail que pour OutLook) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
set Txt_Content to "Mon Texte"
set My_Signature to "Ma signature"
	set theMessage to make new outgoing message with properties {subject:My_Subject, content:Txt_Content & return & return & My_Signature}

- A voir signature en html ??

Les problématiques :
• Comment fais t-on pour inclure une signature dans OutLook via une signature enregistré dans les préférences de l'application ?
• pour Mail et OutLook : dans le cas où l'on ne connait pas le nom de la signature enregistrée dans les préférences de l'application,
comment doit on faire pour récupérer les signatures enregistrées dans les préférences de l'application puis en appliquée une ?
• pour Mail et OutLook : dans le cas où l'on ne trouve pas de signature enregistrée dans les préférences, en appliquée une alors qui est manuelle
(suggestions ? fenêtre qui propose d'écrire et de récupérer le texte de la signature ?? autres ? …)
• pour Mail et OutLook : Faire une signature html (je me demande si une fonction ne serait pas approprié afin de remplir seulement les paramètres à part).
Y a t-il une façon de faire, une méthode, comment pourrais je m'y prendre.

Bien sur toutes suggestions, liens internets et aides aux codes sont la bienvenues (à vrai dire la pêche aux infos sur le net me donne que des petites prises, donc pas évident)

PS : Pour Mail il faut prendre en compte les pièces jointes afin que celles-ci se mettent bien après la signature, quand il y en a une

Merci d'avance

Ryu

[PBELL]

Bonsoir Ryu,


Dans Mail:
Les signatures semblent être définies pour chaque compte Mail.
Il ne s'agit que d'une limitation de l'interface utilisateur.
Les signatures sont en fait définies au niveau de l'application.
Une signature est composée de 2 propriétés: "Name" et "Content"


Pour obtenir toutes les signatures déjà crées :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
tell application "Mail"
    set MesSignatures to every signature
    repeat with aSign in MesSignatures
        log "Nom=" & name of aSign
        log "Contenu=" & content of aSign
    end repeat
end tell

La variable "content" renvoie une version Plain text si nécessaire (polices et styles)


Pour créer une signature (attention elle reste dans l'application !) la syntaxe théorique serait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
make new signature at end of signatures with properties {name:"Test", content:"Philippe"}

Cependant, cette instruction crée bien une nouvelle signature visible dans la liste des signatures, mais la variable "content" est vide dans le mail qui l'utilise et génère une erreur en cherchant à la l'afficher (log content). Si un nouveau message est créé par script, il aura bien la signature "Test", mais aucune valeur ne sera visible en fin de message.
J'ai fait quelques essais, et je pense que c'est une limitation de Applescript sur Mail. La variable interne à Mail est plus riche que celle interface en Applescript !




Je te conseille donc de lire les signatures existantes et d'en sélectionner une à mettre dans ton email... C'est tout !


Si tu souhaites cependant passer plus de temps sur ce thème, sache que les signatures Mail sont dans ta Bibliothèque / Mail / Sous_Dossier_nom_variable / MailData / Signatures / AllSignatures.plist.
Le sous dossier peut avoir des noms type V2, V3 (ou autres ?).
Le fichier Plist contient pour chaque signature :
- SignatureRich -> un boolean yes/no pour indiquer si c'est un rich test ou non
- SignatureName -> le nom
- Signature UniqueID -> une string contenant un identifiant pointant vers le contenu de la signature
Cet identifiant est le nom d'un fichier dans le même dossier, avec l'extension .mailsignature
Il contient une description html. En voici un exemple (contenu brut, non formaté html):


Content-Transfer-Encoding: 7bit
Content-Type: text/html;
charset=us-ascii
Message-Id: <0E11BDE6-A789-4167-A5A1-55F788B504F0@home>
Mime-Version: 1.0 (Mac OS X Mail 8.2 \(2104\))

<body style="color: rgb(0, 0, 0); letter-spacing: normal; orphans: auto; text-align: start; text-indent: 0px; text-transform: none; white-space: normal; widows: auto; word-spacing: 0px; -webkit-text-stroke-width: 0px; word-wrap: break-word; -webkit-nbsp-mode: space; -webkit-line-break: after-white-space;"><div>Philippe</div><div><a href="mailto:mai-Account">Ligne1</a></div><div>Ligne2</div><div>Ligne3</div><div>Ligne4</div><div><br></div></body><br class="Apple-interchange-newline">




Dans Outlook:
Je n'ai pas trouvé dans le dictionnaire Outlook Applescript les objets relatif aux signatures.
Pourtant Outlook gère bien des signature....

Cordialement

[RyuAutodidacte]

Bonsoir PBELL,

Merci de tes réponses je vais regarder cela à tête reposer.


Concernant Outlook, je continue de chercher :

Dans la bibliothèque de OutLook, c'est la seule description que j'ai pu trouver concernant la signature; je n'arrive toujours pas à savoir comment cela fonctionne. Y a t-il un bug ??

Signature Suite

Classes and commands for Outlook signature features.

signature n [inh. object > item] : A signature.
elements
contained by application.
properties
name (text) : The name of a signature.

content (text) : The HTML content of a signature.

plain text content (text) : The content of a signature as plain text.

include in random (boolean) : This field is no longer in use.
-------------------------------------------------------------------------------------------------------------
inherited from object
elements
contained by main windows, folders.
properties
id (integer, r/o) : The unique ID of a record.


Mais j'ai quand même réussi à faire cela : récupérer la liste des signatures et leur contenus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
tell application id "com.microsoft.Outlook"
	set List_Sign to {name, plain text content} of every signature
end tell

Ryu

[PBELL]

Bonjour,
Tu dois avoir une version plus récente d'Outlook (j'ai la 14.0.0) car mon dictionnaire ne contient aucune référence au signature.
Je ne peux donc plus t'aies pour la suite

Cordialement

[RyuAutodidacte]

Bonjour PBELL,

Le but est d'y arriver même si pour cela on contourne le problème.
Je continue de chercher afin de trouver le moindre indice …

(j'ai la 14.0.0) car mon dictionnaire ne contient aucune référence au signature.

En fait en allant sur le net cette référence est apparue sur office 2011 avec une update : je cite :

Signature Suite was added in the 14.1 update to Outlook.

le lien :https://answers.microsoft.com/en-us/...4c8421c?auth=1
ou ce lien : http://www.officeformachelp.com/2011...look-2011-sp1/
donc il est surement possible avec la MAJ d'y acceder (si tu veux bien évidement).

J'ai testé dans Outlook :
• l'ajout d'une signature dans les préférences de OutLook => ok
• la suppression d'une signature dans les préférences OutLook => ok

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
tell application id "com.microsoft.Outlook" --"Microsoft Outlook"
	delete signature named "toto"
end tell

à force de faire des minis code avec la signature on tombera surement sur la bonne facon de le coder … en fin j’espère !

je continue … et te tiens au courant (peut être que l'alternative sera de passer par un contournement bcp plus simple …)

Ryu

[RyuAutodidacte]

Bonjour PBELL,

Pour l'instant, je n'ai pas encore trouvé de solution pour la signature avec OutLook pour envoyer celle-ci dans un e-mail,
mais j'ai trouvé un moyen de contournement non conventionnel afin que la signature puisse apparaître dans l'e-mail (seulement en texte) :
PS : la fonction utilisée dans mon code m'a généré une erreur => "Erreur dans Microsoft Outlook*: Il est impossible de poursuivre list_position.",
donc je l'ai fait sans fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
tell application id "com.microsoft.Outlook"
	set List_Sign to {name, plain text content} of every signature
	set Choix to (choose from list of item 1 of List_Sign with prompt "Choisir une signature") as string
	--set i to list_position(Choix, item 1 of List_Sign)
	repeat with i from 1 to count of item 1 of List_Sign
		if item i of item 1 of List_Sign is Choix then
			exit repeat
		end if
	end repeat
	set Sig to ""
	try
		set Sig to return & return & item i of item 2 of List_Sign
	end try
	set My_content to "Montexte"
	set Sign to My_content & Sig
	set theMessage to make new outgoing message with properties {subject:"Sujet", plain text content:Sign}
	open theMessage
end tell
 
(*on list_position(this_item, this_list)
	repeat with i from 1 to the count of this_list
		if item i of this_list is this_item then return i
	end repeat
	return 0
end list_position*)

Pour ce code ci-dessus, il faudrait qu'ils soit arrangé en prenant compte des différentes situations auxquels je n'ai pas pensé.
- As tu des pistes ? vois tu des erreurs de codage dans la façon de faire ?
- Qu'en est il pour la MAJ de Outlook ?

Ryu

Edit :
Cela marche sur ce principe pour afficher une signature :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
set MaList to {{"toto", "titi", "tutu"}, {"Sign1", "Sign2", "Sign3"}}
set Choix to (choose from list of item 1 of MaList with prompt "Choisir une signature") as string
set i to list_position(Choix, item 1 of MaList)
return item i of item 2 of MaList
 
on list_position(this_item, this_list)
	repeat with i from 1 to the count of this_list
		if item i of this_list is this_item then return i
	end repeat
	return 0
end list_position

[PBELL]

Bonjour,

Pour ce code ci-dessus, il faudrait qu'ils soit arrangé en prenant compte des différentes situations auxquels je n'ai pas pensé.
- As tu des pistes ? vois tu des erreurs de codage dans la façon de faire ?
- Qu'en est il pour la MAJ de Outlook ?

Ton code, tel qu'il est semble correct et n'ayant aucune idées des "différentes situations", je n'ai pas de suggestions.

Quant à la mise à jour de mon Outlook, non je ne la ferai pas car j'ai une très vieille version sans mise à jour gratuite.
Il faudrait que je paye Microsoft pour un logiciel que je n'utilise pas... non merci ! Je souffre déjà avec Outlook sur Windows au bureau, ce n'est pas pour continuer à la maison sur mon Mac personnel ;-)

Cordialement

[RyuAutodidacte]

Bonjour PBELL,

Quant à la mise à jour de mon Outlook, non je ne la ferai pas car j'ai une très vieille version sans mise à jour gratuite

il me semblait que pour la version office 2011, pour ce type de MAJ il suffisait juste de faire : dans la barre des menu "Aide => Rechercher les mises à jour"
qui sont des mises à jour gratuites (comme pour excel - mais on peut se tromper)
Mais quoiqu'il en soit je comprends et respecte ta décision - donc pas de souci.

Par contre, si tu veux bien, même si tu n'utilises pas le logiciel, j'aimerai faire appel à ta logique de codage en AS, car étant moins habitué,
j'ai certaines lacunes dans l'utilisation et la façon d'utiliser certains codes AS et la façon de comprendre la bibliothèque qui donne juste des indications mais pas d'exemples comme on peut l'avoir en VBA …

N'étant pas au point sur le déboggage, as tu une idée de la raison de l'erreur qui survient lorsque j'utilise le code et la fonction comme cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
tell application id "com.microsoft.Outlook"
	set List_Sign to {name, plain text content} of every signature
	set Choix to (choose from list of item 1 of List_Sign with prompt "Choisir une signature") as string
	set i to list_position(Choix, item 1 of List_Sign)
	set Sig to ""
	try
		set Sig to return & return & item i of item 2 of List_Sign
	end try
	set My_content to "Montexte"
	set Sign to My_content & Sig
	set theMessage to make new outgoing message with properties {subject:"Sujet", plain text content:Sign}
	open theMessage
end tell
 
on list_position(this_item, this_list)
	repeat with i from 1 to the count of this_list
		if item i of this_list is this_item then return i
	end repeat
	return 0
end list_position

l'erreur indiqué est :=> "Erreur dans Microsoft Outlook*: Il est impossible de poursuivre list_position."
Alors quavec le code de test tout est ok :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 set MaList to {{"toto", "titi", "tutu"}, {"Sign1", "Sign2", "Sign3"}}
set Choix to (choose from list of item 1 of MaList with prompt "Choisir une signature") as string
set i to list_position(Choix, item 1 of MaList)
return item i of item 2 of MaList
 
on list_position(this_item, this_list)
	repeat with i from 1 to the count of this_list
		if item i of this_list is this_item then return i
	end repeat
	return 0
end list_position

Merci pour tes réponses

Ryu

[PBELL]

Bonsoir,
L'exécution de ton code génère une erreur car l'appel à la sous-routine est fait dans un block "tell application Outlook".
Pour t'en sortir voir la documentation "tell me".

Cordialement

[RyuAutodidacte]

Bonjour PBELL,

Merci de ton retour, hier en faisant des recherches je n'ai pas réussi à trouver déjà en passant par l'aide AS et le net.
En effectuant de nouvelles recherches aujourd'hui, j'ai trouvé via ce lien : http://trad.applescript.free.fr/guid...ppleScript.pdf

La variable me se réfère au script courant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
tell application id "com.microsoft.Outlook"
	set List_Sign to {name, plain text content} of every signature
	set Choix to (choose from list of item 1 of List_Sign with prompt "Choisir une signature") as string
	set i to list_position(Choix, item 1 of List_Sign) of me
	set Sig to ""
	try
		set Sig to return & return & item i of item 2 of List_Sign
	end try
	set My_content to "Montexte"
	set Sign to My_content & Sig
	set theMessage to make new outgoing message with properties {subject:"Sujet", plain text content:Sign}
	open theMessage
end tell
 
on list_position(this_item, this_list)
	repeat with i from 1 to the count of this_list
		if item i of this_list is this_item then return i
	end repeat
	return 0
end list_position

Là c'est ok

Je vais continuer à travailler maintenant conjointement sur la signature de Mail et OutLook et te tiens au courant.
Merci encore

Ryu