Discussion :

[forzatottitalia]

Bonjour tout le monde et bonne année !

Aussi étant nouveau sur le forum et néophyte dans la programmation de script, je requiert certaines infos...

Dans le cadre de mon activité,

Je cherche à établir un script qui me permettra de copier les CA (sous forme de PDF) par clients (35 au total), réalisés par mes agences Commerciales (15 au total) et de les coller dans leur dossier respectifs ...

J’éclaircis tout çà au mieux ... l' "Agence commerciale 1" travaille sur les clients "client A" ,"Client B", "Client E"
l"Agence Commerciale 2" travaille sur les Client B , Client C , Client D
etc .... etc ....

ces deux agences ont le client B en commun il devra donc y avoir sa présence dans les deux dossier.

si possible je souhaiterais avoir le dispatche des CA dans les 15 dossiers des Agences.

Les pdf sont renommées actuellement comme ceci (je peux bien sûr les renommés sans soucis si besoin) : Client1-Ventes détaillées-Janvier-Décembre-2017-2016.pdf
Client2-Ventes détaillées-Janvier-Décembre-2017-2016.pdf ..................

Est ce possible, si oui de quel manière ?
Tous les trimestres c'est une opération que je fais MANO MANO .

Merci d'avance pour vos suggestions et votre aide.
Kevin.

[barnabe0057]

Bonjour,

Voilà qui devrait convenir :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
@echo off
setlocal enableextensions enabledelayedexpansion

:: -------------------------------------------------------
:: on se positionne dans le dossier contenant les PDF
:: -------------------------------------------------------

set dossierCA=C:\Users\toto\Desktop\Chiffre d'affaire
cd %dossierCA% || exit /B 1

:: ---------------------------------------
:: on définit les clients des agences
:: ---------------------------------------

set agence1=client1 client2 client3
set agence2=client2 client5 client6 client7
set agence3=client6 client7
set agence4=client9 client10 client11
set agence5=client12 client13
set agence6=client14 client15
set agence7=client16 client17
set agence8=client18 client19 client20
set agence9=client20 client21
set agence10=client22 client23
set agence11=client24 client25
set agence12=client26 client27
set agence13=client28 client29
set agence14=client30 client31 client32 client33
set agence15=client32 client33 client34 client35

:: -----------------------------------------------------------
:: on envoie chaque fichier PDF à la fonction nommée "tri"
:: -----------------------------------------------------------

for /f "tokens=1,* delims=-" %%A in ('2^>nul dir /b /a-d "*.pdf"') do (call :tri "%%~A" "%%~B")

:: ------------------------------------------
:: on supprime chaque fichier PDF traité
:: ------------------------------------------

for /f "delims=" %%A in ('2^>nul dir /b /a-d "*.pdf"') do (del /f /q "%%~A")

:: ---------------------
:: fin du programme
:: ---------------------

echo. & pause
exit

:: ----------------------------
:: fonction de tri des PDF
:: ----------------------------

:tri
echo. & echo ##### %~1-%~2
for /l %%G in (1,1,15) do (
     for %%V in (!agence%%G!) do (
          if /i "%~1"=="%%~V" (
               if not exist "agence%%G" (mkdir "agence%%G")
               >nul copy "%~1-%~2" "agence%%G"
          )
     )
)
goto :eof

rem

Les parties soulignées sont à modifier selon ton cas.