Discussion :

[adama13]

Bonjour !

Je souhaite changer la valeur de la propriété form.modal à true pour tous les formulaires de ma base de données.

En faite ma base compte une trentaine (30) de formulaire donc ouvrir et modifier cette valeur formulaire par formulaire n'est pas aisée.

J'ai essayé en utilisant la boucle for each mais il m'est impossible d'atteindre la propriété form.modal(Fen modale)

Merci d'avance pour votre aide !

[kiki29]

Salut, de la lecture et pas seulement : Visual Basic Editor

[adama13]

Bonjour kiki29 et merci de t'être penché sur mon problème

J'avais déjà explorer cet article, j'arrive pas à l'adapter a mon cas vu que mon problème concerne ACCESS et non EXCEL

Voici la petite fonction que j'ai utilisé pour parcourir les formulaires de ma base de données

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Function ListeForms()
Dim db As DAO.Database, doc As DAO.Document
 
Set db = CurrentDb
For Each doc In db.Containers("Forms").Documents
  Debug.Print doc.Name
Next
 
Set db = Nothing
End Function

Je veux juste qu'au lieu qu'il me liste le nom des formulaires, qu'il me permettent de changer la valeur de la propriété form.modal à true

Encore merci pour ton temps

[marot_r]

Bonjour. C'est un bon début.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Sub ModifierForms()
Dim db As DAO.Database, doc As DAO.Document
dim f as form
 
Set db = CurrentDb
 
For Each doc In db.Containers("Forms").Documents
  Debug.Print doc.Name
  call docmd.OpenForm(doc.name, acDesign) 'ouvre le formulaire pour modification
  set f=forms(doc.name)
  f.modal=true
  call docmd.Save(acForm, doc.name) 'Sauvegarde les modifications
  call docmd.close(acForm, doc.name) 'Ferme le formulaire
  set f=nothing
Next doc
 
Set db = Nothing
End sub

En théorie on pourait faire la fermeture et la sauvegarde en même temps mais j'ai découvert que certaines modifications ne sont pas sauvegardées par cette oppération mais qu'en séparant les 2 il n'y a pas de problème. Depuis je ne prends plus de chance.

A+

[adama13]

Bonsoir Marot

Encore vous

Merci infiniment d'être toujours là

ça marche très bien j'arrive a changer la valeur de la propriété fen modale à oui pour tous mes formulaires(et c'est rapide comme l’éclaire !) et je crois que je peux même faire d'autres modifications

Encore merci à vous kiki pour votre temps et à vous aussi Marot

Bon Dimanche et très bon début de semaine à tous