Discussion :

[NODIX86]

Bonjour,
- j'ai crée un fichier excel qui contient plusieurs bouton activex
- j'aimerai qu'en cliquant sur chaque bouton, une photo de mon ordinateur apparaisse sur la plage de cellules (U3:AG27) en supprimant la précédente.
-les photos à importer font la même taille que la plage de cellules (U3:AG27) donc je suppose que si l'import se fait en U3 sans redimenssionnement ce serait parfait.

-jusque la j'ai réussi à créer une macro qui insert les photos mais elles ne se places pas au bon endroit et la précédente n'est pas supprimé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub bouton_2000_click()
Dim Fichier As String
 
Fichier = "C:\Users\NORMAN\Desktop\11.png"
Feuil1.Pictures.Insert Fichier
End Sub

Voilà si quelqu'un peut m'aider ça serait fort sympa, merci

[Phil Free]

Bonjour,

un petit exemple ici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub ExempleInsertionImage()
 
Dim MonImage As Picture
Dim CelluleDAncrage As Range
 
With ActiveSheet
    Set CelluleDAncrage = .Range("j5") ' on defint la cellule d'ancrage de l'image
    Set MonImage = .Pictures.Insert("C:\Users\NORMAN\Desktop\11.png")
    With MonImage
        .Placement = xlMoveAndSize 'l'image sera déplacée et redimensionnée avec la cellule
        .Left = CelluleDAncrage.Left 'positionne l'image à gauche de la cellule spécifiée
        .Top = CelluleDAncrage.Top 'positionne l'image en haut de la cellule spécifiée
    End With
End With
End sub

Philippe

[Phil'oche]

Décidément, les grands esprits des Philippe(s) se rencontrent !

Pour compléter le code ci-dessus, avec la suppression :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub ExempleInsertionImage()
 
Dim MonImage As Picture 'ici picture peut être remplacé par object 
Dim CelluleDAncrage As Range
Dim sh As Shape
 
For Each sh In ActiveSheet.Shapes
    If (sh.Type = msoLinkedPicture Or sh.Type = msoPicture) And sh.Name = "MaBelleImage" Then sh.Delete 'On supprime l'image précédente (appelée MaBelleImage)
Next sh
 
With ActiveSheet
    Set CelluleDAncrage = .Range("j5") ' on defint la cellule d'ancrage de l'image
    Set MonImage = .Pictures.Insert("C:\Users\NORMAN\Desktop\11.png")
    With MonImage
        .Placement = xlMoveAndSize 'l'image sera déplacée et redimensionnée avec la cellule
        .Left = CelluleDAncrage.Left 'positionne l'image à gauche de la cellule spécifiée
        .Top = CelluleDAncrage.Top 'positionne l'image en haut de la cellule spécifiée
        .Name = "MaBelleImage"
    End With
End With
End sub