Discussion :

[chanam69]

Bonjour à tous,

J'ai cherché sur pas mal de forum mais je n'ai pas trouvé de réponse, je me tourne donc vers vous.
J'ai un fichier avec un TCD et des filtres (ceux qui se trouvent au dessus du TCD).
J'ai besoin de modifier la selection dans ces filtres via VBA mais je n'y arrive pas.

J'arrive à filtrer uniquement quand mon champs se trouve dans les lignes du TCD.

Dans mon exemple: Tests.xlsx
C'est le champs "Qui" que je veux filtrer automatiquement.

D'avance merci à ceux qui pourront m'aider =)

Bonne journée

[Invité]

Bonjour,

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Option Explicit
 
Sub ChangerLeQui(ByVal Pvt As PivotTable, ByVal NomDuQui As String)
 
Dim PvtItem As PivotItem
Dim PvtItems As PivotItems
 
    With Pvt
         With .PivotFields("Qui")
              Set PvtItems = .PivotItems
              For Each PvtItem In PvtItems
                  If PvtItem.Name = NomDuQui Then
                     PvtItem.Visible = True
                  Else
                     PvtItem.Visible = False
                  End If
              Next PvtItem
              Set PvtItems = Nothing
         End With
    End With
 
End Sub
 
Sub TestChangerLeQui()
 
Dim Pvt1 As PivotTable
 
    Set Pvt1 = ActiveSheet.PivotTables("Tableau croisé dynamique2") ' Adapater
    ChangerLeQui Pvt1, "Paul"
    Set Pvt1 = Nothing
 
End Sub

[Jean-Philippe André]

Salut,

en principe, en utilisant l'enregistreur de macro, tu peux trouver tes petits

[chanam69]

Bonjour,

Avec l'enregistreur de macro, il me met le nom ou les noms en dur de ma liste.
Si j'ai 3 personnes, il va me les citer une à une.

Si j'ai "Pierre", "Paul", "Pierre / Paul" dans mon "qui", j'ai besoin de pouvoir prendre les occurences un peu comme un "like" en SQL.

Si ma variable vaut "Paul", j'ai besoin de pouvoir prendre "Paul" et "Pierre / Paul".

Je ne suis pas sure d’être très claire >_<

Je vais testé la première macro et l'adapter =)

Merci


==> erreur 1004 :/

[Invité]

==> erreur 1004 :/

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub ChangerLeQui(ByVal Pvt As PivotTable, ByVal NomDuQui As String)
 
Dim PvtItem As PivotItem
Dim PvtItems As PivotItems
 
    With Pvt
         With .PivotFields("Qui")
              .ClearAllFilters
              .EnableMultiplePageItems = True
              Set PvtItems = .PivotItems
 
              For Each PvtItem In PvtItems
                  If PvtItem.Name = NomDuQui Then
                     PvtItem.Visible = True
                  Else
                     PvtItem.Visible = False
                  End If
              Next PvtItem
              Set PvtItems = Nothing
              .EnableMultiplePageItems = False
         End With
 
    End With
 
End Sub

Pièce jointe 310273

[chanam69]

Un énorme merci !

J'ai refais mes TCD pour qu'ils ne soient plus dans des plages de données et ça fonctionne nickel !