Discussion :

[ddblu]

Bonjour,

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
strImagePath = CurrentProject.Path & "\GrandePhotos\" & Me.RéfProduit & ".jpg"

En fait, Me.RéfProduit place le nom de la référence produit exact dans cette chaîne. Ce que j'essaie de faire c'est de créer une expression qui dise à Access de placer toutes les instances existantes dans le dossier GrandePhotos et qui incluent cette référence du produit. Par exemple, si le nom de la référence est 0002, je veux que access aille chercher toutes les références qui inclut ce 0002 (0002a, 0002b, 0002c....) dans le dossier GrandePhotos.

Merci par avance de votre aide.

Dan

[Invité]

Bonjour,

cette fonction permet de récupérer le chemin et le nom des fichiers qui correspondent à un chamin et à un nom de fichier générique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Public Function GetCheminNomFichiers(ByVal CheminNomGenerique As String) As String()
On Error GoTo catch
Dim aFichier() As String, Fichier As String, i As Long
 
ReDim aFichier(0 To 0)
 
If CheminNomGenerique <> vbNullString Then
    Fichier = Dir(CheminNomGenerique)
    While Fichier <> vbNullString
        i = i + 1
        ReDim Preserve aFichier(0 To i)
        aFichier(i) = Left$(CheminNomGenerique, InStrRev(CheminNomGenerique, "\", -1, vbBinaryCompare)) & Fichier
        Fichier = Dir()
    Wend
End If
 
Finally:
    GetCheminNomFichiers = aFichier
    Exit Function
catch:
    MsgBox "Erreur n°" & err & vbCrLf & "Description : " & err.Description, vbExclamation, "GetCheminNomFichiers()"
    Resume Finally
End Function

Exemple d'utilisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Public Function TestFichiers()
Dim strImagePath As String, a() As String, i As Long, s As String
strImagePath = CurrentProject.Path & "\GrandePhotos\" & Me.RéfProduit & "?.jpg"
a = GetCheminNomFichiers(strImagePath)
For i = 1 To UBound(a)
    s = s & "-> " & a(i) & vbCrLf
Next i
MsgBox s
End Function

Dans l'exemple, on recherche les fichiers dont le nom commence par me.réfproduit et se termine par un caractère quelconque représenté par ?
On peut aussi remplacer ? par * ce qui indique aucun à plusieurs caractères quelconques à la fin du nom générique

[ddblu]

Merci beaucoup !!