Discussion :

[r.faure]

Bonjour a Tous,

Dans un Userform j'essaie de récupérer les entêtes de colonnes de 4 onglets dans 4 listbox.
Une boucle de 0 a 3. Le premier tours de boucle fonctionne mais arrivé a i=1, l'objet MyRange ne fonctionne plus. Et j'avoue ne pas savoir pourquoi.

Erreur d’exécution '1004':
Erreur définie par l'application ou par l'objet.

A mon avis y'a un gros truck sous mon nez, je le sens dans ma tripaille.
Et si vous constatez un meilleur code pour arrivé a mes fins, je suis preneur.

Merci pour votre aide.

Bonne journée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Private Sub UserForm_Initialize()
    Dim TabOngl(3) As String
    Dim TabObj(3) As Object
    Dim MyRange As Range
    Dim i as Integer
    Dim MyLong As Long
    Dim element As Object
 
    TabOngl(0) = "SFR MOBILE"
    TabOngl(1) = "SFR FIXE ADSL"
    TabOngl(2) = "ORANGE MOBILE"
    TabOngl(3) = "ORANGE FIXE"
    Set TabObj(0) = Me.LB_ParamColExistSM
    Set TabObj(1) = Me.LB_ParamColExistSFA
    Set TabObj(2) = Me.LB_ParamColExistOM
    Set TabObj(3) = Me.LB_ParamColExistOF
 
    For i = 0 To 3
        MyLong = Sheets(TabOngl(i)).UsedRange.Columns.Count - 1
        Set MyRange = Sheets(TabOngl(i)).Range(Cells(1, 1), Cells(1, MyLong))
        For Each element In MyRange
            TabObj(i).AddItem element
        Next element
        Set MyRange = Nothing
    Next i
End Sub

[joe.levrai]

Bonjour,

es-tu certain que tes 4 onglets contiennent bien des données en ligne 1 ?

Sinon, ça serait fâcheux car MyLong vaudrait 0 .... d'où le plantage évident de MyRange qui ne peut contenir une cellule avec une colonne numéro 0

[r.faure]

Salut joe.levrai,

Tu m'as mis le doute, j'ai donc vérifié malheureusement MyLong est a 152. Du coups un trop grand nombre de colonnes peut il engendrer un problème?

Par contre je te remercie. J'ai oublié de gérer le cas ou Mylong serait a 0.

[joe.levrai]

rajoute la feuille hôte devant chacun des cells, j'avais pas fait gaffe à ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MyRange = Sheets(TabOngl(i)).Range(Sheets(TabOngl(i)).Cells(1, 1), Sheets(TabOngl(i)).Cells(1, MyLong))

[r.faure]

Sans déconné c’était trop easy.
Je suis une vrais quiche lorraine, c'était évident comme le nez au milieu de la figure.

Merci a toi joe.levrai, et désolé pour la perte de temps.

Et continuez comme ça sur le Forum je suis une vrais groupie de votre boulot. (C'est français ça ? )

Au plaisir de vous lire dans d'autres topics.

Bye

[joe.levrai]

Après la groupie du pianiste, la groupie de DVP.net