Discussion :

[evost]

Bonjour à tous,

Je cherche à utiliser les données d'un tableau dynamique comme critère dans AutoFilter. Le problème que j'ai est que, seule la première valeur de mon tableau est prise en compte.
Pour résumer : Je commence par déclarer un tableau en début de process puis j'enregistre des données dans ce tableau. Ces données correspondent à des "codes" que je souhaite utiliser ensuite comme critères, lors d'un filtrage de données d'une autre feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub test()
 
Sheets("Feuil2").Select
 
dl_code = Range("A1").End(xlDown).Row
 
Dim tab_code()
ReDim tab_code(dl_code - 2, 0)
For i = 0 To dl_code - 2
    tab_code(i, 0) = Range("A" & i + 2)
Next
 
Sheets("Feuil1").Select
ActiveSheet.Range("A1:Q" & [A65536].End(xlUp).Row).AutoFilter Field:=2, Criteria1:=tab_code(), Operator _
    :=xlFilterValues
 
End Sub

Lorsque j’exécute ce code, la macro fonctionne correctement mais seule la valeur déclarée en "tab_code(0, 0)" est utilisée. Comment faire pour que toutes les valeurs déclarées dans mon tableau soient prise en compte comme critère ?

Merci d'avance

[joe.levrai]

Bonjour,

une proposition écrite à main levée

ta propre proposition avait des mauvaises habitudes (sélections de feuilles, boucle inutile) et le fait de travailler en Base 0 est dangereux quand ensuite on travaille sur des feuilles de calcul

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
'Dim tab_code()
'tab_code = Application.Transpose(Sheets("Feuil2").UsedRange.Value)
                                           ' tab_code
Sheets("Feuil1").Range("A1").AutoFilter 2, Application.Transpose(Sheets("Feuil2").UsedRange.Columns(1).Value), xlFilterValues
                ' inutile de citer toute la plage
                ' on indique la première cellule A1 uniquement
End Sub

Attention à bien Reset ton filtre entre deux utilisation (un .Autofilter sans critère suffit)

[evost]

Bonjour Joe et merci pour ta réponse

Ton code fonctionne et le résultat attendu est bien là ! Je vais faire quelques recherches pour essayer de comprendre ta démarche. Peux-tu juste m'expliquer à quoi correspond le "Base 0" s'il te plait ? Comme tu l'auras remarqué, je débute en VBA et en programmation tout court...

Merci encore.

[joe.levrai]

De façon native, un Tableau (array) commence à l'indice 0
La "Base" est donc 0

Quand on va travailler sur le tableau, dans des boucles, en corrélation avec Excel ou toute source qui commence à 1 (ligne, colonne etc...), on doit toujours trifouiller les indices des variables pour faire coïncider 0 (premier élément du array) et 1 (premier élément tiers) ... pas franchement pratique et lisible dans le code.

Donc, on peut forcer le début d'un tableau sur l'indice 1 de deux manières différentes :

- en haut du module, on déclare

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Option Base 1

Et tout array déclaré dans ce module commencera à l'indice 1

- quand on dimensionne le tableau manuellement, on spécifie clairement la plage de début à 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim MonTableau(1 to 40)

Et seulement ce tableau sera affecté par la Base 1


A noter également que quand on récupère une plage de données pour la mettre dans un Array, il sera par défaut en Base 1 (et ce sera accessoirement un tableau à deux dimensions).
C'est ce que je fais dans ma proposition, j'aspire la colonne A de Feuil2 et on obtient un tableau 2D de X lignes sur 1 colonne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim MonTableau()
MonTableau = Feuil1.UsedRange.Value
MsgBox Ubound(MonTableau,1)  ' donnera 1 car c'est l'indice du premier élément

En tant que tel, ce n'était pas ton problème.
Le problème exact, c'est que ton tableau était "à l'envers", donc quand tu l'utilisais comme critère de filtre, VBA transmet à excel le premier élément uniquement de ton tableau 1D ... d'où la résolution appliquée dans ma proposition : j'ai transposé le tableau pour inverser les dimensions

Si on reprend ton code intial, en transposant simplement ton tableau final, on doit obtenir le même résultat, je te laisse tester et constater

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub test()

Sheets("Feuil2").Select

dl_code = Range("A1").End(xlDown).Row

Dim tab_code()
ReDim tab_code(dl_code - 2, 0)
For i = 0 To dl_code - 2
    tab_code(i, 0) = Range("A" & i + 2)
Next

Sheets("Feuil1").Select
ActiveSheet.Range("A1:Q" & [A65536].End(xlUp).Row).AutoFilter Field:=2, Criteria1:=Application.Transpose(tab_code), Operator _
    :=xlFilterValues

End Sub

[evost]

Bonjour Joe,

Un grand merci pour ces explications détaillées qui m'ont permis de comprendre mes erreurs mais aussi l'utilisation de "UsedRange" et "Transpose", notions que je ne connaissais pas du tout !
En effet si je reprend mon code initial en inversant les dimensions du tableau le résultat est correct, mais je vais plutôt essayer de simplifier un maximum comme tu le fais pour alléger le code final.

A bientôt et merci !