Discussion :

[vincedu74]

Bonjour à tous,

J'essaye de remplir une combobox avec l'outil mondico.

J'ai une plage de cellule allant de F43 à K56. Je cherche à remplir ma combobox avec les valeurs de ces cellules de manière unique.

Par ailleurs je souhaite si possible récupérer cette liste de valeur afin de limiter une plage de cellules aux valeurs récupérer dans ce dictonnaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Set mondico3 = CreateObject("scripting.dictionary")
a = F.Range("F43:K56")
For i = LBound(a) To UBound(a)
   If a(i, 1) <> "" Then mondico3(a(i, 1)) = ""
   Next i
    Me.Supplierbox.List = mondico3.keys
    Supplierbox.AddItem "ALL", 0
    Supplierbox.AddItem "", 1

Je n'ai pas de messages d'erreur mais ma combobox n'est pas remplie non plus....


En vous remerciant par avance pour votre aide...

[boisgontierjacques]

Bonjour,

Exemple en PJ

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  Set MonDico = CreateObject("Scripting.Dictionary")
  a = f.Range("A2:A" & f.[A65000].End(xlUp).Row)  ' tableau a(n,1) pour rapidité
  For i = LBound(a) To UBound(a)
   If a(i, 1) <> "" Then MonDico(a(i, 1)) = ""
  Next i
  Me.ComboBox1.List = MonDico.keys
  Me.ComboBox1.AddItem "xx"
End Sub

Boisgontier

[vincedu74]

Bonjour Jacques et merci pour ton retour.

Ici l'ensemble des valeurs de la combobox sont sur une unique colonne.

Est-il possible de rassembler avec cette même méthode les valeurs contenues dans PLUSIEURS colonnes ?

En vous remerciant

[boisgontierjacques]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  Set MonDico = CreateObject("Scripting.Dictionary")
  a = f.Range("A2:D" & f.[A65000].End(xlUp).Row)  ' tableau a() pour rapidité
  For Each c In a
   If c <> "" Then MonDico(c) = ""
  Next c
  Me.ComboBox1.List = MonDico.keys
  Me.ComboBox1.AddItem "xx"
End Sub

Boisgontier

[vincedu74]

Merci beaucoup Jacques ! ca fonctionne impeccable.


Savez vous comment utiliser cette liste afin qu'elle soit la liste des valeurs autorisée pour une plage de cellule "validation de données" ?

[boisgontierjacques]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If Target.Address = "$B$2" Then
    Set d = CreateObject("Scripting.Dictionary")
    Set f = Sheets("bd")
    a = f.Range("A2:D" & f.[A65000].End(xlUp).Row)  ' tableau a() pour rapidité
    For Each c In a: d(c) = "": Next c
    Target.Validation.Delete
    Target.Validation.Add xlValidateList, Formula1:=Join(d.keys, ",")
  End If
End Sub

Boisgontier

[vincedu74]

Ca a fonctionné impeccable encore merci jacques !