[access 03 + vba] Envois de mail

**973thom** · 13/06/2006, 12h48

Bonjour à tous !

J'ai bien regardé dans la FAQ mais je me demandais s'il y a pas quelque chose de plus simple.

En fait je voudrais, qd on clique sur un bouton, que l'application mail par défaut du pc s'active pour ouvrir une fenêtre de rédaction de mail à une adresse bien précise.

Un peu comme dans le "mailto" de HTML...

Merci de votre aide.

**cotmar** · 13/06/2006, 13h21

Bonjour 973thom,

J'ai quelquechose comme ça, mais pour Outlook (pas Outlook Express).
Ca pourra peut être t'aider (attention ici je ne gère pas les pièces jointes) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
 
 
'****************************************************************************************
'* Module comprenant les fonctions d'interfaçage avec Outlook
'****************************************************************************************
 
Option Compare Database
Option Explicit
 
Public Function FctSendEmail( _
    ByVal StrDestinataire As String, _
    ByVal StrSujet As String, _
    ByVal StrMessage As String) As Boolean
 
'Envoie de mail
 
Dim objOutlook          As New Outlook.Application
Dim objOutlookMsg       As Outlook.MailItem
 
    On Error GoTo ErrHandler
 
    FctSendEmail = False
 
    Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
    With objOutlookMsg
           .To = StrDestinataire    '"Adresse@Destinataire"
           .Subject = StrSujet      '"Objet du message"
           .Body = StrMessage       '"Texte du message"
           .Display                 '.Send
    End With
 
    FctSendEmail = True
 
ExitHandler:
    Set objOutlookMsg = Nothing
    Exit Function
 
ErrHandler:
'Resume
    FctSendEmail = False
    MsgBox Err.Description, vbExclamation, CstAppName
    Resume ExitHandler
 
End Function

A bientôt.

Marco.

**973thom** · 13/06/2006, 14h04

Bonjour et merci !

Je vais essayer cela et voir si je peux l'adapter à mon appli.
Pas de pb pour les pièces jointes, je n'en ai pas besoin.

Je te tiendrai au courant si j'ai un problème

Merci de ton aide

**973thom** · 13/06/2006, 14h52

une p'tite question...

N'y aurait il pas une référence à cocher car là j'ai plein de bug et je comprends pas d'où ça vient...

**Z[ee]k** · 13/06/2006, 15h01

Étant intéréssé aussi, je c/c, ca ne fonctionne pas, forcement VB et moi ca fait 36...alors si tu pouvais nous éclairer !

**cotmar** · 13/06/2006, 15h05

Bonsoir,

En fait j'ai mis le code précédent dans un module à part (appelé ModOutlook) et j'appelle la fonction FctSendMail(...) avec les arguments qui vont bien de la manière suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57



Private Sub CmdDiffuser_Click()
'Envoi d'un email automatique au destinataire :
' - L'utilisateur rempli le/les destinataires,
' - Un mail complètement formaté est généré.
' - > Revoir juste le text de l'email
'On Error GoTo ErrHandler
On Error Resume Next

    Dim StrMessage          As String
    Dim StrDateIncident     As String
    Dim StrNumSite          As String
    Dim StrVille            As String
    Dim StrRegion           As String
    Dim StrCompteRendu      As String
    Dim StrMesures          As String
    
    Me.DatIncident.SetFocus
    StrDateIncident = Me.DatIncident.Text
    Me.NumSite.SetFocus
    StrNumSite = Me.NumSite.Text
    Me.TxtVille.SetFocus
    StrVille = Me.TxtVille.Text
    Me.TxtRegion.SetFocus
    StrRegion = Me.TxtRegion.Text
    Me.CompteRendu.SetFocus
    StrCompteRendu = Me.CompteRendu.Text
    Me.MesuresSecurisationIntermédiaires.SetFocus
    StrMesures = Me.MesuresSecurisationIntermédiaires.Text
    
    StrMessage = "Bonjour," & vbCrLf & vbCrLf & _
                "Un incident est survenu le : " & StrDateIncident & vbCrLf & vbCrLf & _
                "Sur le site " & StrNumSite & " de : " & StrVille & " dans la région : " & StrRegion & vbCrLf & vbCrLf & _
                "Dont le descriptif suit : " & vbCrLf & vbTab & StrCompteRendu & vbCrLf & vbCrLf & _
                "Les actions suivantes ont été mises en oeuvre : " & vbCrLf & vbTab & StrMesures & vbCrLf & vbCrLf & _
                "Cordialement."
    
    If Not ModOutlook.FctSendEmail("", CstAppName & " - Incident sur le réseau", StrMessage) Then
        Exit Sub
    Else
        Call ModLogFile.SubAddAction("Diffusion de l'incident par email.")
    End If

ExitHandler:
    Exit Sub

ErrHandler:
'Resume
    If Err.Number <> 2110 Then
        MsgBox Err.Description, vbExclamation, CstAppName
    End If
    Resume ExitHandler
    
End Sub

Quel sont les messages d'erreur que tu obtiens ? Est ce que tu es sur d'utiliser Outlook (et pas Outlook Express ou un autre) dans ton entreprise ? Car dans ce cas, ça ne focntionne pas du tout de la même manière.

A très bientôt et courage.

Marco content d'aider quelqu'un (pour une fois).

**973thom** · 13/06/2006, 15h08

Ben en fait pour ma part j'essai de l'adapter à thunderbird ou nescape... donc pas facile. c'est pour ça que je me demandais s'il n'y avais pas une référence à sélectionner car ça bug de partout...

Des variables soit disant non définies...

Vive l'informatique.

**cotmar** · 13/06/2006, 15h27

En fit c'est pas tant un problème d'adaptation... Il faut carrément trouver les bonnes fonctions pour Thunderbird ou Netscape.

Même si les deux sont similaires ou inspirées l'une par l'autre (je ne me rappelle plus bien), il peut quand même y avoir des différencesd. Il faut donc tester.

A bientôt.

Marco.

**cotmar** · 13/06/2006, 17h26

Sinon, petite question, est ce que tu as pensé à cocher la réfr&érence à Mozilla ou à Netscape dans le menu de VBA de Access ?

A bientôt.

Marco.

**973thom** · 14/06/2006, 06h26

Envoyé par cotmar

Sinon, petite question, est ce que tu as pensé à cocher la réfr&érence à Mozilla ou à Netscape dans le menu de VBA de Access ?

A bientôt.

Marco.

Heu ben non j'lai pas trouvé !!!

ça va pas être du gateau je le sens !

**=JBO=** · 14/06/2006, 07h31

Bonjour,

Envoyé par 973thom

En fait je voudrais, qd on clique sur un bouton, que l'application mail par défaut du pc s'active pour ouvrir une fenêtre de rédaction de mail à une adresse bien précise.

La méthode SendObject de l'objet DoCmd convient parfaitement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
DoCmd.SendObject OutputFormat:=acFormatTXT, _
    To:="don.ald@canard.com", Cc:="riri@ailleurs.net;fifi@partout.eu", _
    Subject:="Envoyer un e-mail", MessageText:="Ceci est un essai !"

**973thom** · 14/06/2006, 07h37

Bon ben c'est super...

C'est exactement ce que je voulais... prendre l'appli mail par défaut sur le PC et ouvrir une fenêtre de message...

Merci beaucoup =JBO= !!!

Bonne journée à toi et à tous

[access 03 + vba] Envois de mail

Access

Discussions similaires

Partager

Partager