Discussion :

[chevinou]

Bonjour à tous et à toutes et surtout, merci de me lire,

Alors, j'ai écumé les forums et autre à la recherche d'une réponse... sans succès, alors je me tourne vers vous, au cas ou,

J'ai fait un petit script car nous sommes victimes d'un grand nombre de profil temporaire (Authentification par carte) et je souhaiterais donc supprimer dans regedit un ensemble de clef automatique dans HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\

En effet, je souhaiterais détruire les clefs qui serait en S-1-5xxxxxxxxxxxxxxxxxxxxxx.bak et seulement celle qui se termine par .bak.

Alors, dites moi je vous prie, si il existe une solution pour sélectionner et supprimer un ensemble de clef simplement en indiquant une partie de son nom ou encore une autre solution que je n'ai peut-être pas envisagé

Voici mon script au cas ou

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
@echo off
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\*.bak"
if not errorlevel 1 goto suite
echo Aucun probleme
goto fin
:suite
echo Suppression de la clef
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\*.bak" /f
echo clef supprimeée
:fin

Merci d'avance

[devilsnake88]

Bonjour,

C'est marrant j'avais codé un script pour mon travail ^^
Teste bien le script avant sinon tu vas avoir une mauvaise surprise...

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off & cls
Setlocal enabledelayedexpansion
 
for /f "tokens=*" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"^|findstr /ie ".bak"') do (
	set "key=%%a"
    for /f "tokens=1,2*" %%i in ('reg query "%%a"^|find /i "ProfileImagePath"^|findstr /i "Users"') do (
		Set "ImgPath=%%~k"
		if defined ImgPath (
			Set "User=!ImgPath:%SystemDrive%\Users\=!"
			if not "!User!" == "Administrateur" (
                if not "!User!" == "Public" (
                    if not "!User!" == "Default" (
                        echo --- !User! ---------------
                        echo Clef: %%~na 
                        echo Chemin du profile: !ImgPath!
                        echo Utilisateur : !User!
                        reg delete "!key!" /f >nul
                        echo !key! a bien ‚t‚ supprim‚e
 
                        if exist "%SystemDrive%\Users\TEMP" rd /S /Q "%SystemDrive%\Users\TEMP"
                        if exist "!ImgPath!" rd /S /Q "!ImgPath!"
                        echo ------------------
                    )
                )
			)
		)
	)
)
endlocal
pause
exit

Il n'est pas parfait mais il fonctionne et est relativement clair.

[chevinou]

Merci infiniment pour ton script, je vais tester cela dans la journée.

Merci encore

---

Evidement comme je suis un gars bien, je passerais mon post en résolu si tout est OK!!!

[chevinou]

Bonjour, je viens d'adapter et de tester... Ca marche du tonnerre! j'ai mis ce script au démarrage des postes et... Plus de profil temporaire... Un régal, tu n'as pas idée du temps que tu viens de me faire gagner.

Alors, merci milles fois!

A tout bientôt

[devilsnake88]

Oh si crois moi je sais, je gère également un parc informatique imposant ^^.
Au plaisir