Discussion :

[Dédé6621]

Bonjour,

Je souhaite copier une plage de données d'un classeur dans la première ligne d'un autre classeur, mais une erreur 1004 est retournée. Voici le code avec la ligne fautive soulignée:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Test()
        
        Dim data As Workbook
        Dim dc As Workbook
        Dim der As Integer
        
        Set data = ActiveWorkbook
        Set dc = Workbooks.Open("Macintosh HD:Users:Chemin:Nom du fichier.xlsx")
        der = Cells(Columns(1).Cells.Count, 1).End(xlUp).Row + 1
        
        dc.Sheets(3).Range("F5:J6").Copy Destination:=data.Sheets(1).Range("F5:J6")
        dc.Sheets(3).Range("A8:K8").Copy Destination:=data.Sheets(1).Range(Cells(der, 1), Cells(der, 11))
        
        dc.Close
        
End Sub

Ce qui est étonnant, c'est que la copie de la première plage ("F5:J6") ne pose pas de problème et que ce code fonctionne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test2()
 
        Dim der As Integer
 
        der = Cells(Columns(1).Cells.Count, 1).End(xlUp).Row + 1
 
        Range(Cells(der, 1), Cells(der, 11)).Select
 
End Sub

Pourriez-vous m'aider?

[casefayere]

Bonjour,
ici, tu ouvrés un fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set dc = Workbooks.Open("Macintosh HD:Users:Chemin:Nom du fichier.xlsx")

(en espérant que le chemin et le nom soient corrects), donc il devient le fichier actif
sur cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

der = Cells(Columns(1).Cells.Count, 1).End(xlUp).Row + 1

"der" fait donc référence à la première ligne vide de la feuille active de ce fichier
je ne suis pas sur que ça soit ce que tu cherches au vu de la ligne soulignée

[Dédé6621]

Merci pour cette réponse casefayere! Ce n'était en effet pas intentionnel.

Ça aurait peut-être pu être la cause d'une erreur étant donné que der devient alors 2 et que la plage copiée fait référence à des cellules relativement au-dessus de la ligne 1.

Mais le problème persiste...
Voici le code mis à jour:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Test()
        
        Dim data As Workbook
        Dim der As Integer
        Dim dc As Workbook
        
        Set data = ActiveWorkbook
        der = Cells(data.Sheets(1).Columns(1).Cells.Count, 1).End(xlUp).Row + 1
        Set dc = Workbooks.Open("Macintosh HD:Users:Chemin:Nom du fichier.xlsx")
        
        dc.Sheets(3).Range("F5:J6").Copy Destination:=data.Sheets(1).Range("F5:J6")
        dc.Sheets(3).Range("A8:K8").Copy Destination:=data.Sheets(1).Range(Cells(der, 1), Cells(der, 11))
        
        dc.Close
        
End Sub

P.S: Le chemin est correct, le fichier s'ouvre bien et la plage "F5:J6" est bien copiée, mais le fichier ne se ferme pas à la fin, car le code renvoie l'erreur avant

[casefayere]

et comme ça ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Data.Sheets(1)
  dc.Sheets(3).Range("A8:K8").Copy Destination:=.Range(.Cells(der, 1), .Cells(der, 11))
End With

[Dédé6621]

Oui, ça marche! Magnifique!!!

En gros, VBA ne savait pas de quelles cellules je parlais (objet "Cells" non défini). Il aurait fallut que j'ajoute "data.Sheets(1)" avant chaque "Cells".
J'ai vraiment l'impression de comprendre un peu mieux le langage VBA. Et merci pour la commande "With/End With" qui permet de ne pas avoir à répéter la définition de l'objet. J'apprends

Voici le code qui marche:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Test()
 
        Dim data As Workbook
        Dim der As Integer
        Dim dc As Workbook
 
        Set data = ActiveWorkbook
        der = Cells(data.Sheets(1).Columns(1).Cells.Count, 1).End(xlUp).Row + 1
        Set dc = Workbooks.Open("Macintosh HD:Users:Chemin:Nom de fichier.xlsx")
 
    With data.Sheets(1)
        dc.Sheets(3).Range("F5:J6").Copy Destination:=.Range("F5:J6")
        dc.Sheets(3).Range("A8:K8").Copy Destination:=.Range(.Cells(der, 1), .Cells(der, 11))
    End With
 
        Application.DisplayAlerts = False
    dc.Close
 
End Sub