Discussion :

[cysalea]

Bonjour,

Après différentes recherches, je n'ai pas trouvé ce que je voulais.

J'arrive à créer une entête avec la macro automatique mais il y a énormément de lignes et je ne sais pas lesquelles supprimées.

Quelqu'un pourrait-il m'aider ?

Merci beaucoup

En résumé

- à gauche : je veux en format 8 : Requête
- au centre : en gras format 11 : Contrôle interne Supervision VDUREE MOIS
- à droite : je veux en format 8 : Requête du VDATEJOUR
VINIT

Je joins mon fichier en format vb

[Invité]

Bonjour,

- Lorsque plusieurs séquences de mise en page sont enchaînées, il ne faut garder que la dernière. Dans votre cas, les deux premières sont à supprimer.
- Si vous n'avez pas encore modifié la mise en page, la macro créée avec l'enregistreur donne les valeurs par défaut de votre mise en page. En créant une deuxième macro modifiant votre mise en page, vous conservez les lignes qui ont changé et vous pouvez supprimer les autres, mais vous n'êtes pas obligée, ce sera plus facile pour la maintenance le cas échéant.

A vérifier si le code ci-dessous fonctionne correctement sur votre micro. Il y a sans doute d'autres lignes non obligatoires.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Sub MEPage_IG()
 
Dim MOIS As String
Dim VDUREE As String
Dim VDATEJOUR As Date
Dim VINIT As String
 
'Définition de boite de messages
MOIS = InputBox("Entrer le mois et l'année : Exemple : si requête lancée en mai noter avril 2016")
VDUREE = InputBox("définir la durée : 10 ou 18 mois")
VDATEJOUR = InputBox("Entrer la date du jour au format JJ/MM/AAAA", "Date du jour", Date)
VINIT = InputBox("Entrer vos initiales")
 
' A supprimer
'MOIS = "avril 2016"
'VDUREE = "18"
'VDATEJOUR = Date
'VINIT = "EK"
 
    'Application.PrintCommunication = False ' Si cette ligne est activée, vérifier que les initiales dans VINIT sont toutes présentes.
    With ActiveSheet.PageSetup
 
        .LeftHeader = "&8Requête" & Chr(10) & """IJ_" & VDUREE & "mois_Ctrl_Interne.sql"""
        .CenterHeader = "&""-,Gras""&11CONTROLE INTERNE" & Chr(10) & "SUPERVISION " & VDUREE & " MOIS" & Chr(10) & UCase(MOIS)
        .RightHeader = "&8Requête du " & VDATEJOUR & Chr(10) & VINIT
 
        .Orientation = xlLandscape
        .Draft = False
        .PaperSize = xlPaperA4
        .FirstPageNumber = xlAutomatic
        .Order = xlDownThenOver
        .FitToPagesWide = 1
        .FitToPagesTall = False
 
        .PrintErrors = xlPrintErrorsDisplayed
        .ScaleWithDocHeaderFooter = True
        .AlignMarginsHeaderFooter = True
 
    End With
    'Application.PrintCommunication = True  ' Si cette ligne est activée, vérifier que les initiales dans VINIT sont toutes présentes à l'édition.
 
 
End Sub

Nb : La quantité d'inputbox à saisir est particulièrement irritante. Vous devriez créer un userform pour n'avoir qu'un seul masque à saisir ou bien créer une zone de saisie sur un onglet.

Cordialement.