Discussion :

[dave5]

Bonjour,

Dans le but de paramétrer les valeurs d'un fichier.vbs comportant certains paramètres utilisateurs a modifier, j'ai choisi d'ouvrir et lire le fichier vbs en question sous format txt voici un apercu de mon code :

Et voici ce j'obtiens en l'exécutant :

C'est le résultat correspondant au première ligne de mon fichier.vbs que je lis en format txt, vu que je suis débutant sous VBscript je souhaite pouvoir changer les valeurs du a,b,c, d.....

Merci pour votre aide.

[ericlm128]

Merci d'utiliser les balises code afin que l'on puisse t'aider.

[l_autodidacte]

Merci d'utiliser les balises code afin que l'on puisse t'aider.

Remarque pertinente. J'ai aussi à dire qu'une capture d'écran n'est pas utilisable dans un tel cas, il est nécessaire d'envoyer un texte(sans oublier les balises code ) qu'on peut copier et utiliser pour le test, car si on essaie de t'aider, on sera obligé de tout ré-écrire.

[EDIT] : Quand tu dis

C'est le résultat correspondant à la première ligne de mon fichier.vbs que .....

Cela ne peut pas être correct car les valeurs retournées sont sur des lignes différentes(avec retour chariot).

[dave5]

Bonsoir,

Effectivement, je posterai le code avec les balises, les valeurs retournées ne sont que les lignes existants dans le fichier en lecture txt Model.vbs, je cherche a avoir un script permettant de modifier ces valeurs : a,b,c.. j'ai essayé ForAppending ca n'a pas marché comme je l'aurais souhaité .
Cordialement;

[l_autodidacte]

Tu sembles avoir une bonne volonté pour progresser, je peux alors te donner un coup demain avec ce

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Option Explicit 
 
Const ForReading = 1, ForWriting = 2
Dim fso, F, Affichage, TB, intMsg, iCount, Reponse, Result, Contenu, TargetFile
Function ReadTextFileTest()
     Dim   Msg ',Folder
     ' On n'a pas besoin de la ligne suivante car si on ne donne pas un chemin pour le 
     ' fichier et on donne juste son nom, Wscript le cherche en premier dans le répertoire 
     ' de travail(répertoire courant).
    ' C'est cette ligne => Folder = Replace(Wscript.ScriptFullName, "\" & Wscript.ScriptName, "") 
     Set fso = CreateObject("Scripting.FileSystemObject") 
     Set F = fso.OpenTextFile("Model.vbs", ForReading, False) 
     ReadTextFileTest = F.Read(1012)
     F.Close
     Set fso = Nothing
End Function
 
MsgBox ReadTextFileTest
Affichage = Mid(ReadTextFileTest, 538, 164)
MsgBox Affichage
 Set fso = CreateObject("Scripting.FileSystemObject")
 TargetFile = fso.GetFile("Model.vbs").Path
 intMsg = MsgBox("Souhaitez-vous modifier les valeurs des paramètres ?", vbYesNo, "Modifier les paramètres") 
 If intMsg = vbYes Then
    TB = SPlit(Affichage, vbCrlf)
    For iCount = 0 To UBound(TB) - 1
      Reponse = InputBox("Modifier les paramètres ?", "Faire un choix", TB(iCount))
      If Reponse = "" Then 
         MsgBox "Aucune modification n'a été apportée au fichier " & TargetFile
         Wscript.Quit 0
      End If
      Result = Result & Reponse & vbNewLine
    Next
    ' On ajoute la dernière valeur sans retour chariot
    Reponse = InputBox("Modifier les paramètres ?", "Faire un choix", TB(UBound(TB)))
    If Reponse = "" Then 
         MsgBox "Aucune modification n'a été apportée au fichier " & TargetFile
         Wscript.Quit 0
    End If
    Result = Result & Reponse
    ' On lit la totalité du fichier puis on le ferme
    Set F = fso.OpenTextFile("Model.vbs", ForReading, False)
    Contenu = F.ReadAll
    F.Close
    ' On écrit les modifications apportées au fichier et on le ferme
    Set F = fso.OpenTextFile("Model.vbs", ForWriting, False) 
    Contenu = Replace(Contenu, Affichage, Result)
    F.Write Contenu
    F.Close
    MsgBox "Modification terminée"
Else
    Wscript.Quit 0
End If

Adapte le script selon ton besoin notamment les valeurs de début et de fin pour la fonction Mid.
Le fichier Model.vbs(que j'ai utilisé pour le test) se présente ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Option Explicit
 
Function ShowVolumeInfo(drvpath)
   Dim fso, d, s
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set d = fso.GetDrive(fso.GetDriveName(fso.GetAbsolutePathName(drvpath)))
   s = "Lecteur " & d.DriveLetter & " :  " & d.VolumeName
   ShowVolumeInfo = s
End Function
'MsgBox ShowVolumeInfo("C:\Windows")
'==============================
Function ShowDriveType()
   Dim fso, d, t, Ret, S
   Set fso = CreateObject("Scripting.FileSystemObject")
   For Each d In fso.Drives
      Select Case d.DriveType
          Case 0: t = "Inconnu"
          Case 1: t = "Amovible"
          Case 2: t = "Fixe"
          Case 3: t = "Réseau"
          Case 4: t = "CD-ROM"
          Case 5: t = "Disque virtuel"
      End Select
       If d.IsReady Then 
          S = UCase("Prêt   ") & d.VolumeName 
       Else 
          S = UCase("non Prêt")
       End If
     Ret = Ret & d.DriveLetter & " : " & t & "  [" & S & "]" & vbNewLine
    Next 
   ShowDriveType = Ret 
End Function
MsgBox ShowDriveType
'============================
Const CDROM = 4
Const VIRTUAL = 5
Dim drv, Ret, fso
Set fso = CreateObject("Scripting.FileSystemObject")
For Each drv In fso.Drives
    If drv.IsReady  Then
        If drv.DriveType = CDROM  Then
           Ret = "Lecteur CD :  " & drv.DriveLetter & " : " &  drv.VolumeName & vbNewLine & "==============="  & vbNewLine 
        ElseIf drv.DriveType = VIRTUAL  Then
           Ret = "Lecteur Viruel :  " & drv.DriveLetter & " : " &  drv.VolumeName & vbNewLine & "==============="
        End If
    Else 
       Ret = Ret & "Disque " & drv.DriveLetter & " non prêt !"  & vbNewLine
    End If
Next
MsgBox Ret

[ericlm128]

Cela ne peut pas être correct car les valeurs retournées sont sur des lignes différentes(avec retour chariot).

Je pense que ça peut être correcte malgré tout. "F.read(1000)" doit lire les retours chariots ?!