Copier un onglet d'un classeur A dans un classeur B selectionné

**cirbouille** · 05/04/2016, 22h17

Bonjour à tous,
J'ai besoin de mettre à jour une qte astronomique de fichiers au coup par coup.
Pour ce faire, j'ai un fichier A dont un onglet me sert de "modèle"
Je souhaite choisir un fichier B avec GetOpenFilename, y insérer un nouvel onglet et y coller le "modèle" précédemment copier.

Ma procédure est d'ouvrir le fichier A, de lancer la macro qui copie le "modèle", ouvre la boite de dialogue pour sélection du fichier B, y insére une feuille, y coller le "modèle".
J'ai bien dégrossi le truc mais je ne trouve pas comment travailler sur le fichier B que je viens de sélectionner

, la feuille que j'insère se crée dans le fichier A

Même si j'utilise souvent de petites macros, je ne suis pas un as du VBA et là... je sèche.

Par avance merci aux généreux contributeurs

**Theze** · 06/04/2016, 07h59

Bonjour,

une piste :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Sub Test()
 
    Dim Cls As Workbook
    Dim Fe As Worksheet
    Dim Fich As String
 
    Set Fe = ThisWorkbook.Worksheets("Feuil1")
 
    Fich = Fichier("C:\Mon Dossier\") '<-- adapter !
 
    Set Cls = Workbooks.Open(Fich)
 
    Fe.Copy Cls.Sheets(Cls.Sheets.Count)
 
End Sub
 
Function Fichier(Dossier As String) As String
 
    With Application.FileDialog(3) 'fichiers
 
        .Filters.Clear
        .Filters.Add "Classeurs Excel", "*.xls; *.xlsx; *.xlsm"
        .InitialFileName = Dossier
        .AllowMultiSelect = False '1 seul
        .Show
 
        If .SelectedItems.Count <> 0 Then
            Fichier = .SelectedItems(1)
        Else
            Fichier = ""
        End If
 
    End With
 
End Function

**cirbouille** · 06/04/2016, 20h35

Merci Theze, je regarde à ta piste dès que possible mais comme je n'aime pas trop recopier sans comprendre et que je ne demande qu'à apprendre, pourrais tu, s'il te plait, donner quelques explications sur la traduction de tout ça.

**Theze** · 07/04/2016, 07h03

Bonjour,

Commentaire dans le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
Sub Test()
 
    Dim Cls As Workbook
    Dim Fe As Worksheet
    Dim Fich As String
 
    'défini la feuille à copier qui se situe dans le classeur contenant cette macro en utilisant une variable feuille
    Set Fe = ThisWorkbook.Worksheets("Feuil1") 'le nom de la feuille est à adapter bien sûr !
 
    'appelle la fonction pour récupérer le classeur à ouvrir
    Fich = Fichier("C:\Mon Dossier\") 'adapter le chemin à tes besoins !
 
    'traite la non sélection d'un classeur (sortie de procédure)
    If Fich = "" Then Exit Sub
 
    'utilise une variable objet "Classeur" pour ensuite travailler avec
    Set Cls = Workbooks.Open(Fich)
 
    'copie la feuille dans le classeur venant d'être ouvert et en dernière position
    Fe.Copy , Cls.Sheets(Cls.Sheets.Count) '<-- là, j'avais homis la virgule pour placer la feuille au bon endroit :-(
 
End Sub
 
Function Fichier(Dossier As String) As String
 
    With Application.FileDialog(3) 'fichiers
 
        'seuls les classeurs avec les extensions précisées apparaîtront
        .Filters.Clear
        .Filters.Add "Classeurs Excel", "*.xls; *.xlsx; *.xlsm"
 
        .InitialFileName = Dossier 'ouvre sur le dossier passé en argument
        .AllowMultiSelect = False 'ne permet qu'une seu1e sélection
        .Show 'affiche la boite
 
        'si sélection il y a, passe le chemin à la fonction sinon retourne une chaine vide
        If .SelectedItems.Count <> 0 Then
            Fichier = .SelectedItems(1)
        Else
            Fichier = ""
        End If
 
    End With
 
End Function