Discussion :

[Phil333250]

Bonjour à toutes et tous,

Jusqu'à présent j'utilise ce code pour supprimer la dernière ligne d'un tableau structuré.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Supp_Der_Ligne()
    Sheets("NomOnglet").Activate
     DerCell = Cells(Rows.Count, "K").End(xlUp).Row
     Rows(DerCell).Delete
End Sub

Mais la feuille sur laquelle je travaille a 2 tableaux structurés séparés par une colonne vierge.
Le premier tableau est nommé "Base_Clients", le second "Tab_Nom_Client".
Si je veux supprimer la dernière ligne du tableau "Base_Clients" le code ci-dessus ne peux plus être utilisé au risque de supprimer la dernière ligne du second tableau.

Je sais créer une ligne en fin de tableau avec ce code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Ajout_Ligne()
  Dim T As ListObject ' T = Le tableau concerné
  Dim Col As Integer  ' Col = La colonne concernée
  Set T = Range("Base_Clients").ListObject
  With T
   Col = .ListColumns("Nom Col Concernée").Index
   .ListRows.Add                   ' Ajoute une nouvelle ligne à la fin du tableau
  End With
  Set T = Nothing
End Sub

Je pensais naïvement remplacer ListRows.Add par ListRows.Delete mais que nenni.

Avec l'enregistreur de macro, j'ai Selection.ListObject.ListRows(3).Delete où 3 représente la ligne 3 qui est la dernière ligne.
C'est, je pense, d'ici que doit venir la solution ListRows(3).
Mais je sèche.

J'ai essayé en m'appuyant sur le Tutoriel de laurent_ott https://laurent-ott.developpez.com/t...ux-Structures/ mais je m'y suis perdu. Surchauffe de mes petites cellules grises.

J'ai donc besoin de votre aide.
Merci
Philippe

[Tête de chat]

Bonjour,

Déjà dans le code ajout Col ne sert à rien ; simplifier en :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Ajout_Ligne()
  Dim T As ListObject ' T = Le tableau concerné
  Set T = Range("Base_Clients").ListObject
  T.ListRows.Add                   ' Ajoute une nouvelle ligne à la fin du tableau
  Set T = Nothing
End Sub

Sur le même modèle pour supprimer la dernière ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Del_Ligne()
  Dim T As ListObject ' T = Le tableau concerné
  Dim Lig As Long ' Lig = La dernière ligne
  Set T = Range("Base_Clients").ListObject
  With T
   Lig= .ListRows.count ' nb de lignes
   .ListRows(Lig).Delete                   ' supprime une ligne à la fin du tableau
  End With
  Set T = Nothing
End Sub

En passant Range sans référence particulière est relatif à la feuille active, donc limite la portée du Sub

[Phil333250]

Bonjour Tête de chat,

Merci pour votre réponse.
Cela fonctionne très bien.
En revanche, je ne comprends pas votre remarque

En passant Range sans référence particulière est relatif à la feuille active, donc limite la portée du Sub

Philippe

[Tête de chat]

Re,

En revanche, je ne comprends pas votre remarque

Effectivement dans le contexte la remarque n'est pas pertinente, le nom de tableau étant un nom global.

[deedolith]

En revanche, je ne comprends pas votre remarque

Si je puis me permettre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Supp_Der_Ligne()
    Sheets("NomOnglet").Activate
     DerCell = Cells(Rows.Count, "K").End(xlUp).Row
     Rows(DerCell).Delete
End Sub

Ici, tu fais référence aux plages de la feuille.
Tu calculs la dernière ligne, et tu la supprime.
Au final, tu supprimes une ligne de la feuille.

Tandis que Tête de chat, passe par l'objet ListObject, qui représente un tableau structuré.
La collection ListRows fait référence aux ligne du tableau.
Il calcul la dernière ligne du tableau, et supprime la dernière ligne du tableau, ce qui n'est pas la même notion que la dernière ligne de la feuille.

[Phil333250]

Bonjour Messieurs,

Merci pour vos remarques.

Bonne journée

Philippe

[laurent_ott]

J'ai essayé en m'appuyant sur le Tutoriel de laurent_ott https://laurent-ott.developpez.com/t...ux-Structures/ mais je m'y suis perdu. Surchauffe de mes petites cellules grises.

Bonjour,
Exemples pour ajouter une ligne au tableau "Base_Clients" avec les fonctions de la documentation que vous citez :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Dim T As Range
Set T = Range("Base_Clients")
Call TS_AjouterUneLigne(T)

Ou plus simplement :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Call TS_AjouterUneLigne(Range("Base_Clients"))

Et pour supprimer la dernière ligne :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Dim T As Range
Set T = Range("Base_Clients")
Call TS_SupprimerUneLigne(T, 0)

Ou

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Call TS_SupprimerUneLigne(Range("Base_Clients"), 0)

Cordialement.

[Phil333250]

Bonjour laurent_ott

Merci pour ce complément d'information.
Je vais pouvoir me replonger dans votre documentation.

Philippe