Discussion :

[halaster08]

Bonjour,

J'utilise un TCD avec des slicers pour restreindre l'affichage et j'aurais deux questions concernant la manipulation des slicers par macro.

1) Peut-on récuper le nombre d'item selectionnés dans un slicers?

2) Peut-on choisir la selection par macro?
j'ai essayé avec l'enregistreur de macro, mais il me recopie toute ma la liste d'item avec selected = true ou false, mais j'aimerais ne pas avoir a recopier toute la liste si c'est possible
par exemple dire le "a" et le "c" true le reste false


Merci d'avance.

[cerede2000]

Point 1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveWorkbook.SlicerCaches(1).VisibleSlicerItems.Count

Pour le point 2, je te conseil un coup d'enregistreur de macro Tu aura la réponse.

Edit : Point 2, il n'est pas possible dans un slicer de n'en avoir aucun de sélectionner puis d'en sélectionner un.
Donc l'idée est d'itérer les SlicerItems en désélectionnant ce que tu ne veux pas, genre ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub test()
    Dim sl As SlicerCache
    Dim sli As SlicerItem
 
    Set sl = ActiveWorkbook.SlicerCaches("SlicerName")
 
    sl.ClearAllFilters
 
    For Each sli In sl.SlicerItems
        If sli.Name = "A" Or sli.Name = "B" Then
            sli.Selected = True
        Else
            sli.Selected = False
        End If
    Next
End Sub

A adapter ensuite avec un tableau pour passer les valeurs à sélectionner

[halaster08]

Merci de répondre si vite

Avec ton code j'obtient l'erreur "invalid use of property"
De plus comme j'ai plusieurs slicer j'aimerais l'appeler par son prénom suffit il de remplacer SlicerCaches(1) par SlicerCaches("prénom")?

pour le point j'ai édité mon premier post pendant que répondait, j'ai essayer l'enregistreur de macro mais la sortie qu'il me donne ne me semble pas automatisable.
en fait je pense qu'il faurait une boucle sur tous éléments du slicers et avec un if choisir si on met true ou false, mais je ne sais pas comment lui dire de boucler sur les elements du slicer

[cerede2000]

J'ai éditer ma réponse précédente

Oui tu peux appeler les Slicer par le petit nom

[halaster08]

Merci encore

il ne veut pas toujours pas ".count"
idem pour la boucle il bloque au "sl.ClearAllFilters"
Toujours avec le même message "invalid use of property"

Je suis sur Excel 2010, est-il possible que ce soit un problème de version?

edit: si j'enlève la ligne qui pose problème la macro avec la boucle s'exécute sans râler et donne le bon résultat

[cerede2000]

Arf, je suis en XL2k16
Je n'ai pas de 2k10 pour tester, il est possible que cette propriété n'existais pas.

Edit : Confirmer sur MSDN Visiblesliceritems est apparu avec Excel 2k13
Tu peux le faire toi même avec le même principe que la boucle du coup.
Tu compte le nombre qui sont en Selected True:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
    Dim sl As SlicerCache
    Dim sli As SlicerItem
    Dim nbSliVisible As Integer
 
    Set sl = ActiveWorkbook.SlicerCaches("SlicerName")
 
    For Each sli In sl.SlicerItems
		If sli.Selected Then
			nbSliVisible = nbSliVisible + 1
		End If
    Next
 
    Debug.print "Il y a " & nbSliVisible & " sliceritems Visible" 
End Sub