Discussion :

[tomv701]

Salut à tous!

Alors je ne connais rien sur VBA (ou presque) mais j'ai besoin d'un programme qui exécuterais une formule

alors voici la formule que le programme doit executer :

=A1

=(1+C1)*A1+B1

=(1+C1+C1^2)*A1+(1+C1)*B1

=(1+C1+C1^2+C1^3)*A1+(1+C1+C1^2)*B1

=(1+C1+C1^2+C1^3+C1^4)*A1+(1+C1+C1^2+C1^3)*B1

=(1+C1+C1^2+C1^3+C1^4+C1^5)*A1+(1+C1+C1^2+C1^3+C1^4)*B1

etc....
Soit la cellule A1=8 , B1=-0.2 et C1=0.7

J'aimerais que ce programme me calcul cette formule et qu'elle mecrive le résultat de chaque étape dans une cellule différente.
Le résultat avec ces données devrait atteindre 2 à +l'infinie.

Je pense que c'est facile pour vous, mais je ne suis pas doué du tout :/

Merci d'avance

Si cela facilite la chose, vous pouvez commencer direct à l'étape 3.

[mercatog]

Une fonction basique qui prend les paramètres A, B, C et l'étape n (qui commence à 0)

A mettre dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Function Poly(ByVal A As Double, ByVal B As Double, ByVal C As Double, ByVal n As Integer) As Double
Dim Alfa As Double, Beta As Double
Dim i As Integer
 
If n >= 0 Then
    Alfa = 1
    For i = 0 To n - 1
        Beta = Alfa
        Alfa = 1 + C * Alfa
    Next i
    Poly = Alfa * A + Beta * B
End If
End Function

[tomv701]

Merci!

Mais comment je fais fais pour l'utiliser dans mon cas?
Désolé vraiment...

[mercatog]

Si tu veux l'appliquer directement par la barre des formules sur la feuille
Tu écris la fonction dans un module standard
en A5 tu mets 0
en A6, tu mets 1
...etc

en B5 tu écris la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Poly($A$1;$B$1;$C$1;A5)

où en A1, B1 et C1 tu as tes données A1=8 , B1=-0.2 et C1=0.7

Tu tires la formules jusqu'en bas


Si tu veux le tout en vba, il suffit d'appeler la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub EcrireFonction()
Dim i As Integer
 
With Worksheets("Feuil3")    'à adapter
    For i = 0 To 50
        .Cells(i + 5, 1) = i
        .Cells(i + 5, 2) = Poly(.Range("A1"), .Range("B1"), .Range("C1"), i)
    Next i
End With
End Sub

PS. désolé d'avoir proposé un code clé en main. Pour un étudiant il faudra commencer par le début.

[tomv701]

Je n'ai pas du tout compris la procédure mais en tout cas ça marche.
Je vous remercie beaucoup!

[mercatog]

Il te faut comprendre avant d'utiliser sinon tu auras l'aire "pas bien"