Discussion :

[cirbouille]

Bonjour à tous,
Dans un précédent sujet, Theze m'a aidé à résoudre mon pb. Pour résumer, je lance une macro qui me permet de sélectionner un fichier où j'insère un onglet A dans lequel je viens coller des valeurs copiées dans des onglets existants B,C & D.

Aujourd'hui, je suis confronté au pb suivant :
Parfois un des onglets B,C ou D n'existe pas , j'opte donc pour la fonction "if" mais quelle est la syntaxe pour dire IF onglet B existe THEN continuer la macro ELSE passer à l'opération suivante ? et qu'est-ce qui défini l'opération suivante ( copier dans l'onglet C, puis D) ?

Ou y a-t-il une autre solution plus efficace ?

J'ai été aussi clair que possible même si je sens que c'est pas top

D'avance merci

[galopin01]

Bonjour,
Tu peux utiliser cette fonction personnalisée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Function WsExist(Nom$) As Boolean
On Error Resume Next
WsExist = Sheets(Nom).Index
End Function

... Ensuite dans ton code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If WsExist("Feuill2") Then...

A+

[kiki29]

Salut, au choix

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Function FeuilleExiste1(sNomFeuille As String, Optional Wkb As Workbook = Nothing) As Boolean
Dim Ws As Worksheet
    FeuilleExiste1 = False
    If Wkb Is Nothing Then
        Set Wkb = ThisWorkbook
    End If
    For Each Ws In Wkb.Worksheets
        If Ws.Name = sNomFeuille Then
            FeuilleExiste1 = True
            Set Wkb = Nothing
            Exit For
        End If
    Next Ws
    Set Wkb = Nothing
End Function
 
Private Function FeuilleExiste2(ByVal sNom As String) As Boolean
    On Error Resume Next
    FeuilleExiste2 = Sheets(sNom).Name <> ""
    Err.Clear
End Function
 
Function FeuilleExiste3(sNomFeuille As String) As Boolean
    FeuilleExiste3 = Not (IsError(Evaluate("='" & sNomFeuille & "'!A1")))
End Function
 
Function FeuilleExiste4(NomFeuille As String, Optional Classeur As Workbook = Nothing) As Boolean
Dim Ws As Worksheet
    If Classeur Is Nothing Then Set Classeur = ThisWorkbook
    For Each Ws In Classeur.Worksheets
        If Ws.Name = NomFeuille Then
            FeuilleExiste4 = True
            Exit For
        End If
    Next Ws
End Function
 
Function FeuilleExiste5(ByVal sNom As String) As Boolean
Dim Ws As Worksheet
    On Error Resume Next
    Set Ws = Worksheets(sNom)
    If Err.Number <> 0 Then FeuilleExiste5 = False Else FeuilleExiste5 = True
End Function
 
Function FeuilleExiste6(sFeuille As String) As Boolean
    FeuilleExiste6 = Evaluate("ISREF('" & sFeuille & "'!A1)")
End Function

[cirbouille]

Bon déjà merci à vous 2, j'y regarde de plus près asap.

Cependant, je ferais la même remarque qu'à Theze, pourriez vous, svp, mettre quelques explications à ces lignes ? Je ne demande pas un cours magistral mais 2 ou 3 infos sur le concept et la syntaxe seraient sympa
Quoi qu'il en soit, merci encore

[kiki29]

Salut, pour cela il y a les FAQs, tutos et autres : Les fonctions personnelles dans Excel