Discussion :

[ced0802]

Bonjour toutle monde,

Je narrive pas a comprendre ce qui ne va pas avec cette ligne de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub exp()
 
Dim db As Workbook
Set db = Workbooks("wk48production") 'Worksheets("Packing Production Schedule")
 
For x = 1 To 1000
 
db.Worksheets("Packing Production Schedule").Cells(x, 5) = _
Application.WorksheetFunction.IfError(Application.WorksheetFunction.VLookup(db.Worksheets("Packing Production Schedule").Cells(x, 7), Workbooks("vba stock Final version").Worksheets("feuil1").Range("A9:K102"), 7, False), "")
On Error Resume Next

message d erreur :

Run time error 1004
Unable to get the vlookup property of the worksheetfunction class

Merci a vous.

[Theze]

Bonjour,

et de cette façon ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub exp()
 
    Dim Fe As Worksheet
    Dim Plage As Range
    Dim Tbl()
    Dim X As Integer
    Dim Ligne As Integer
 
    Set Fe = Workbooks("wk48production").Worksheets("Packing Production Schedule")
    Set Plage = Workbooks("vba stock Final version").Worksheets("feuil1").Range("A9:K102")
 
    Ligne = Fe.Cells(Rows.Count, 5).End(xlUp).Row
 
    ReDim Tbl(1 To Ligne)
 
    With Application.WorksheetFunction
 
        For X = 1 To Ligne
 
            Tbl(X) = .IfError(.VLookup(CStr(Fe.Cells(X, 7).Value), Plage, 7, False), "")
            'Fe.Cells(X, 5).Value = .IfError(.VLookup(CStr(Fe.Cells(X, 7).Value), Plage, 7, False), "")
 
        Next X
 
    Fe.Range(Fe.Cells(1, 5), Fe.Cells(Ligne, 5)).Value = .Transpose(Tbl)
 
    End With
 
End Sub

J'ai utilisé un tableau pour la récupération des valeurs et ensuite, après la recherche je colle le tableau dans la feuille. Pour la recherche de la valeur, je force en String -->"CStr(Fe.Cells(X, 7).Value)"
Teste et reviens nous dire ce qu'il se passe. Vérifie aussi au niveau de la transposition si elle est nécessaire -->" .Transpose(Tbl)" (je ne me souviens pas si il faut transposer et comme je n'ai rien testé...)

[ced0802]

Merci beaucoup Theze d'avoir pris le temps de ;e repondre. Ca fonctonne. Genial !