Discussion :

[Moun10be]

Bonjour, je sollicite vôtres aides pour modifié un de mes projets que j'avais fais à l'époques avec des formules mais j'aimerai que vous puissiez m'aidé à le faire en code VBA que je trouve plus esthétique.

Dans mon fichier simplifier j'ai 4 feuilles, listes de données, voyages hors service, feuille de travaille et liste de service

1) J'aimerai que dans la feuille voyages hors service, lorsque je tape le numéro d'agent dans la cellule G7 il me retrouve le nom correspondant dans la feuille listes de données et me l'indique dans la cellules C7 de la feuille voyages hors service.


2) Dans la feuille, feuille de travaille lorsque je sélectionne un des mots qui ce trouve dans la liste déroulante de la colonne C quand fonction du mots il m'indique le temps correspondant qui ce trouve dans la feuilles listes de données a la colonne K et me l'inscrive dans la cellule correspondante de la colonne G


3) Dans la feuille, liste de service lorsque je tape le numéro d'agent dans les cellules de la colonne D, N et X il me retrouve les noms et numéro de GSM correspondant qui se trouve dans la feuille listes de données et me l'indique dans les cellules correspondante des colonnes C - E, M - O et V - Y


Compilation test.xlsm

Merci d'avance.

[EricDgn]

Bonjour,

En fait ce n'est pas vraiment une bonne idée de passer par du code VBA quand il est possible de faire les opérations directement par des formules, mais bon, voici toujours une façon de faire en utilisant du code VBA et des tableaux structurés.

Pour la feuille "Liste de service" (les autres feuilles utilisant quasi le même):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count = 1 Then
        If Not (Application.Intersect(Target, Range("D3:D14,N3:N14,X3:X14,D23:D34,N23:N34")) Is Nothing) Then
            Dim kRt As Long, kCt As Long, kR As Long
            kRt = Target.Row
            kCt = Target.Column
            If Target = "" Then
                Cells(kRt, kCt - 1) = ""
                Cells(kRt, kCt + 1) = ""
            Else
                With Worksheets("Liste de données").ListObjects("t_Pers")
                    kR = Application.WorksheetFunction.Match(Target, .ListColumns("N°").Range, 0)
                    Cells(kRt, kCt - 1) = .Range(kR, .ListColumns("Nom").Index)
                    Cells(kRt, kCt + 1) = .Range(kR, .ListColumns("Tél").Index)
                End With
            End If
        End If
    End If
End Sub

Bonne continuation.

[boisgontierjacques]

Bonsoir,

J'ai transformé le tableau de Liste de données en tableau dynamique en ayant auparavant changé l'apostrophe par un espace.


1- Voyages hors service

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count = 1 Then
        If Not Intersect(Target, [G7]) Is Nothing Then
          Position = Application.Match(Target, [tableau1[N° Gradé]], False)
          If Not IsError(Position) Then
            [C7] = [tableau1[Nom Gradé]].Item(Position, 1)
          Else
            MsgBox "Erreur de code!"
          End If
        End If
    End If
End Sub

2- Liste de service

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count = 1 Then
        If Not (Application.Intersect(Target, Range("D3:D14,N3:N14,X3:X14,D23:D34,N23:N34")) Is Nothing) Then
          Position = Application.Match(Target, [tableau1[N° Gradé]], False)
          If Not IsError(Position) Then
            Target.Offset(, -1) = [tableau1[Nom Gradé]].Item(Position, 1)
            Target.Offset(, 1) = [tableau1[N° D appel]].Item(Position, 1)
          Else
            MsgBox "Erreur de code!"
          End If
        End If
    End If
End Sub

3- Feuille de travail

Transformer en TD les colonnes J,K deListe de données

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count = 1 Then
        If Not (Application.Intersect(Target, Range("C2:C25")) Is Nothing) Then
          Position = Application.Match(Target, [tableau2[visites]], False)
          If Not IsError(Position) Then
            Target.Offset(, 4) = [tableau2[Temps]].Item(Position, 1)
          Else
            MsgBox "Erreur!"
          End If
        End If
    End If
End Sub

Boisgontier

[Moun10be]

Merci à vous deux pour votre aides et solution apporté, je comprend votre logique me conseillant de continué avec les formules au lieu du VBA ce que je m'étais attelé a faire ces dernier jours j'ai juste modifié toutes les formules pour que dans les cellules n'apparaisse plus les #NA# ou 0 je trouve cela plus esthétique sans

Mais je vais quand même tenir compte du fichier proposé en code VBA

Merci encore pour tout.

[boisgontierjacques]

Bonjour,

Avec des formules,on aurait:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
=SIERREUR(INDEX(Tableau1[Nom Gradé];EQUIV(D3;Tableau1[N° Gradé];0));"")
=SIERREUR(INDEX(Tableau1[N° D appel];EQUIV(D3;Tableau1[N° Gradé];0));"")
 
=SIERREUR(INDEX(Tableau1[Nom Gradé];EQUIV(G7;Tableau1[N° Gradé];0));"")
 
=SIERREUR(INDEX(Tableau2[Temps];EQUIV(C2;Tableau2[Visites];0));"")

Boisgontier

[Moun10be]

Merci Boisgontier pour l'exemple présenté

C'est plus ou moins le même principe que j'ai placé dans la plupart de mes cellules

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
=SI(ESTVIDE(D3);"";RECHERCHEV(D3;'Liste de données'!A2:B78;2;FAUX))
=SI(ESTVIDE(D3);"";RECHERCHEV(D3;'Liste de données'!E2:F78;2;FAUX))

Bon week-end