Ecrire dans une feuille non active

**Mrfreeze117** · 03/08/2015, 15h15

Est-il possible d'écrire dans une feuille non active?

Parce que lorsque j'essaye ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30", Cells(30 + (DerLiTDC1 - PreLiTDC1), DerColTDC1 - 1)) = Donnees

Sur une autre feuille que TDCPPA ça ne fonctionne pas et dès que je suis dessus ça marche.

merci d'avance

**joe.levrai** · 03/08/2015, 15h24

Bonjour,

rattache ton cells à sa feuille .... si tu ne le fais pas alors VBA va utiliser la feuille active par défaut

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("TDCPPA")
    .Range("A30", .Cells(30 + (DerLiTDC1 - PreLiTDC1), DerColTDC1 - 1)) = Donnees
End With

**Mrfreeze117** · 03/08/2015, 15h31

ça ne change rien du tout. J'ai erreur d'exécution '1004': Erreur définie par l'application ou par l'objet.

Exactement la même chose que quand je mets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").

devant mon range

**joe.levrai** · 03/08/2015, 15h39

ma ligne de code fonctionne en l'état dans sa Structure
passe en mode pas à pas, quand la macro plante met ta souris sur la ligne jaune et regarde les valeurs prises par :

DerLiTDC1
PreLiTDC1
DerColTDC1

histoire d'être sûr que tu ne vas pas sur une ligne et/ou colonne de numéro "0"

**Mrfreeze117** · 03/08/2015, 15h50

PreLiTDC1 =122
DerColTDC1 =143
DerLiTDC1 =6

Mais je ne vois pas en quoi cela change quelque chose. Si mes valeurs étaient fausses ça ne marcherai pas non plus quand je me mets sur la feuille TDCPPA.

**joe.levrai** · 03/08/2015, 16h00

ça ne te semble pas étrange d'avoir :

- dernière ligne = 6
- première ligne = 122

ce qui donne dans ton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30", Cells(30 + (DerLiTDC1 - PreLiTDC1), DerColTDC1 - 1)) = Donnees

la plage suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30",Cells(30 + (6 - 122),143-21))

Soit des lignes négatives ?

**Mrfreeze117** · 03/08/2015, 16h02

Pardon j'ai inversé c'est:

PreLiTDC1 =122
DerColTDC1 =6
DerLiTDC1 =143

**joe.levrai** · 03/08/2015, 16h08

quel est le type de variable Donnees ?

et plutôt que de faire un ping pong de questions/réponses ... ton code en entier nous aiderait à y voir un peu plus clair je pense

**Mrfreeze117** · 03/08/2015, 16h12

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub test()
 
Dim PreLiTDC1 As Long, DerLiTDC1 As Long, DerColTDC1 As Long, i As Long
Dim Donnees()
Dim Pvt1 As PivotTable
 
    Set Pvt1 = ActiveSheet.PivotTables("Tableau croisé dynamique1")
 
    PreLiTDC1 = Cells.Find("TOTAL LOTS").Row  'trouve la première ligne du TDC1
    DerColTDC1 = Pvt1.TableRange1.Columns.Count + 1 'trouve la Dernière colonne du TDC1
    DerLiTDC1 = Cells(PreLiTDC1 + 1, DerColTDC1 + 1).End(xlDown).Row 'trouve la dernière ligne du TDC1
 
    ReDim Donnees(DerLiTDC1 - PreLiTDC1, DerColTDC1 - 2) 'dimentionne la matrice qui récupèrera les données
 
    Donnees = Range("B122    ", Cells(DerLiTDC1, DerColTDC1))
 
    i = 1
    While Donnees(i, 1) <> "Total par année"
        If Donnees(i, 1) = "" Then Donnees(i, 1) = Donnees(i - 1, 1)
        i = i + 1
    Wend
 
    Sheets("TDCPPA").Range("A30", Cells(30 + (DerLiTDC1 - PreLiTDC1), DerColTDC1 - 1)) = Donnees
 
    Sheets("TDCPPA").PivotTables("TDC graph inter").SourceData = "TDCPPA!A30:" & Cells(30 + (DerLiTDC1 - PreLiTDC1) - 1, DerColTDC1 - 1).Address
 
    Sheets("TDCPPA").PivotTables("TDC graph inter").PivotCache.Refresh
 
 
 
End Sub

**joe.levrai** · 03/08/2015, 17h03

Si j'ai bien compris la finalité

voici une légère retouche :

- dans le calcul de tes lignes et colonnes
- dans l'injection des données sur ton tableau
- la restitution des données dans la feuille

je te laisse :

- modifier la "Feuil8" qui correspond à ma feuille de test, pour remettre ta feuille qui contient le TCD ==> c'est le fait de ne pas toujours rattacher ta feuille aux ranges que tu manipules qui posait ton problème
- prendre en charge les deux dernières lignes du code, que je n'ai pas touché
- tester et me dire si tu as encore des soucis

j'ai crée un TCD basique (1 champs en ligne et 2 champs en colonnes)
je récupère bien l'ensemble des données dans la feuille de destination ( à partir de la ligne 30) :

- colonne A = la valeur du champs de ligne
- colonne B = les données de ma seconde colonne de TCD
- colonne C = les données de ma troisième colonne de TCD
- etc...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub test()
 
Dim PreLiTDC1 As Long, DerLiTDC1 As Long, DerColTDC1 As Long, i As Long
Dim Donnees()
Dim Pvt1 As PivotTable
 
    Set Pvt1 = Feuil8.PivotTables("Tableau croisé dynamique1")
 
    ' si c'est la ligne qui contient les étiquettes de ligne que tu cherche :
    PreLiTDC1 = Pvt1.RowRange.Row
    ' si c'est le nombre de colonnes qui composent le TCD (axe de lignes inclus)
    nbcoltdc1 = Pvt1.ColumnRange.Count + 1
    ' nombre total de lignes occupées par le TCD
    nbligtcd = Pvt1.TableRange1.Rows.Count - 1
    ' toutes les données du TCD dans ton tableau donnees
    Donnees = Feuil8.Cells(PreLiTDC1 + 1, 1).Resize(nbligtcd - 1, nbcoltdc1).Value
 
    i = 1
 
    While Donnees(i, 1) <> "Total par année"
        If Donnees(i, 1) = "" Then Donnees(i, 1) = Donnees(i - 1, 1)
        i = i + 1
    Wend
 
    Sheets("TDCPPA").Range("A30").Resize(UBound(Donnees, 1), UBound(Donnees, 2)).Value = Donnees
    'Sheets("TDCPPA").PivotTables("TDC graph inter").SourceData = "TDCPPA!A30:" & Cells(30 + (DerLiTDC1 - PreLiTDC1) - 1, DerColTDC1 - 1).Address
    'Sheets("TDCPPA").PivotTables("TDC graph inter").PivotCache.Refresh
End Sub

**Mrfreeze117** · 03/08/2015, 17h10

Merci beaucoup j'ai juste utilisé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30").Resize(UBound(Donnees, 1), UBound(Donnees, 2)).Value = Donnees

et ça marche nickel. je connais pas du tout cette syntaxe.

**joe.levrai** · 03/08/2015, 17h32

Resize permet de modifier un Range

regarde l'aide à ce sujet

par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set Plage = Cells(1,1) ' la plage contient 1 cellule : A1
Set Plage = Cells(1,1).Resize(2,1) ' la plage A1 est redimensionnée pour faire 2 lignes et une colonne soit : A1:A2
Set Plage = Cells(1,1).Resize(2,2) ' la plage A1 est redimensionnée pour faire 2 lignes et deux colonnes soit : A1:B2

Donc, comme tu dois injecter les données d'un tableau sur une plage :

- on part de la première cellule d'écriture : Range("A30")
- on la redimensionne avec le nombre de lignes du tableau (Ubound(Donnees,1)) et le nombre de colonnes du tableau (Ubound(Donnees,2))

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30").Resize(UBound(Donnees, 1), UBound(Donnees, 2)).Value = Donnees

dans ton propre code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Donnees = Range("B122    ", Cells(DerLiTDC1, DerColTDC1))

Outre les espaces après "B122" que je ne comprend pas ... ton B122 et le Cells(....) ne sont pas rattachés à une feuille ==> ta plage est donc située sur la feuille active (celle qui contient le TCD) et pas la feuille TDCPPA

**Mrfreeze117** · 04/08/2015, 12h00

Envoyé par joe.levrai

dans ton propre code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Donnees = Range("B122    ", Cells(DerLiTDC1, DerColTDC1))

Outre les espaces après "B122" que je ne comprend pas ... ton B122 et le Cells(....) ne sont pas rattachés à une feuille ==> ta plage est donc située sur la feuille active (celle qui contient le TCD) et pas la feuille TDCPPA

C'est juste un problème de copier coller.

Merci beaucoup pour ces explications.

Aujourd’hui j'ai un autre problème, qui est semblable, c'est de "cleanner" une plage pour pouvoir par la suite y remettre des données.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("TDCPPA").Range("A30", Cells.SpecialCells(xlCellTypeLastCell)).Clear

Je suis dans un autre onglet que TDCPPA. Mais du coup je ne peux pas utiliser la technique avec ubound et resize

**joe.levrai** · 04/08/2015, 12h47

Bonjour,

les mêmes causes produiront toujours les mêmes effets

j'ai à plusieurs reprises dans cette discussion alerté sur le fait que tu ne rattaches pas tes cells à leur feuille

si tu dois Supprimer dans la feuille "TDCPPA" la plage débutant en A30, alors

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("TDCPPA")
    .Range(.Cells(30, 1), .Cells.SpecialCells(xlCellTypeLastCell)).Clear
End With

**Mrfreeze117** · 04/08/2015, 12h47

J'ai trouvé une solution à force de me retourner la tête:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    y = Sheets("TDCPPA").Cells.SpecialCells(xlCellTypeLastCell).Row - 30
    z = Sheets("TDCPPA").Cells.SpecialCells(xlCellTypeLastCell).Column
    Sheets("TDCPPA").Range("A30").Resize(y, z).Clear

Y a-t-il plus propre comme méthodes?

Merci d'avance

**Mrfreeze117** · 04/08/2015, 13h30

Envoyé par joe.levrai

Bonjour,

les mêmes causes produiront toujours les mêmes effets

j'ai à plusieurs reprises dans cette discussion alerté sur le fait que tu ne rattaches pas tes cells à leur feuille

si tu dois Supprimer dans la feuille "TDCPPA" la plage débutant en A30, alors

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("TDCPPA")
    .Range(.Cells(30, 1), .Cells.SpecialCells(xlCellTypeLastCell)).Clear
End With

Je pensais que mettre sheets("TDCPPA") devant mon range "incluait" cela dans le range.

Merci encore pour tes réponses.

Ecrire dans une feuille non active

Macros et VBA Excel

Discussions similaires

Partager

Partager