Discussion :

[Vincent32]

Bonjour,

je m'essaie (enfin) aux fonctions afin d'alléger mon code. Je pense que je fais une boulette super simple mais là je coince et j'ai besoin d'un peu de savoir faire pour comprendre là où je foire.

Voici la fonction que je souhaite réaliser (But : rechercher un texte dans une liste et le sélectionner) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public Function rechlist(Liste As ListBox, texte As String)
    For i = 0 To L.ListCount - 1 Step 1
        If UserForm1.L.Column(0, i) = texte Then
            UserForm1.L.Selected(i) = True
            Exit For
        End If
    Next i
End Function

voici comment j'appelle ma fonction (la ligne apparaît en rouge et je ne comprends pas pourquoi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

rechlist(ListBox2, "Bob dit l'âne")

j'ai l'impression qu'il (Excel) veut quelque chose de semblable à variable=rechlist ...

bref pouvez vous m'indiquer les erreurs et comment faire pour y remédier,

Merci d'avance (PS j'ai parcouru le document sur les fonctions donc inutile de m'orienter vers ce document)

[joe.levrai]

Bonjour,

j'aurai plutôt vu une procédure au lieu d'une fonction ... dans la mesure où tu n'as aucun résultat à retourner mais uniquement une action à effectuer

De plus :

- L'argument Liste est à typer en msforms.ListBox
- tu utilises la variable L au lieu de Liste dans la fonction
- tu ne dois pas rattacher Liste à Userform1 : la variable Liste étant déjà une ListBox rattachée à son userform quand tu appelles la fonction

voici qui fonctionne chez moi :

dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Public Sub rechlist(Liste As msforms.ListBox, texte As String)
    With Liste
        For i = 0 To .ListCount - 1 Step 1
            If .Column(0, i) = texte Then
                .Selected(i) = True
                Exit For
            End If
        Next i
    End With
End Sub

dans le module du Userform, j'utilise :

- le contrôle ListBox1 où la recherche et selection se fera
- le contrôle TextBox1 où j'écris la chaine recherchée
- le contrôle CommandButton1 qui appelle la procédure quand on clique dessus

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub CommandButton1_Click()
    With Me
        Call rechlist(.ListBox1, .TextBox1.Value)
    End With
End Sub

[Vincent32]

Merci pour cette réponse qui semble efficace. J'ai tenté de procéder de manière similaire pour des combobox mais sans succès :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public Sub rechcombo(Combo As msforms.ComboBox, texte As String)
    For i = 0 To Combo.ListCount - 1 Step 1
        If Combo.Column(0, i) = texte Then
            Combo.Selected(i) = True
            Exit For
        End If
    Next i
End Sub

la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Combo.Selected(i) = True

semble ne pas convenir

[joe.levrai]

Les contrôles ListBox et Combobox n'ont pas toujours les mêmes méthodes et propriétés

Je te conseille de bien lire et assimiler ceci avant de te lancer dans des manipulations de contrôles : http://silkyroad.developpez.com/VBA/...serForm/#LII-F

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub RechCombo(Combo As MSForms.ComboBox, texte As String)
    With Combo
        .Value = texte
        If .ListIndex = -1 Then
            .Value = ""
            MsgBox texte & " est inexistant dans " & Combo.Name
        End If
    End With
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub CommandButton1_Click()
Call RechCombo(Me.ComboBox1, Me.TextBox1.Value)
End Sub

[Vincent32]

Merci beaucoup pour ces précieux conseils.