InnoSetup - Ecrire dans un fichier config

**viny123456789** · 17/11/2007, 18h12

Bonjour,

J'utilise innosetup pour mon programme d'installation et j'en suis très content, mais... j'ai un problème je voudrais à la fin de l'installation générer un fichier config.ini à un endroit précis contenant le chemin d'installation du programme.

Ma question est il possible d'utiliser innosetup pour générer/modifier le contenu d'un fichier ?

Merci pour toute vos réponses.

**ThierryAIM** · 18/11/2007, 15h29

Envoyé par viny123456789

Ma question est il possible d'utiliser innosetup pour générer/modifier le contenu d'un fichier ?

Oui

**Chibitox** · 28/11/2007, 14h17

J'ai besoin de faire également ce genre de chose (écrire dans un fichier "déclaré" dans ISTool des informations qui ont été saisies via dialogue utilisateur lors du setup ).
Est-il possible d'avoir un exemple ou une petite explication sur la manière de procéder sachant que je suis un newbie sur le langage script utilisé par inno setup ?

**ThierryAIM** · 28/11/2007, 17h41

Envoyé par Chibitox

le langage script utilisé par inno setup ?

le langage utilisé par IS est du pascal (proche de Delphi, le logiciel lui-même étant écrit en grande partie, en Delphi)

Envoyé par Chibitox

J'ai besoin de faire également ce genre de chose (écrire dans un fichier "déclaré" dans ISTool des informations qui ont été saisies via dialogue utilisateur lors du setup ).

Si tu me dis quel genre de dialogue a été utilisé : pages standards de IS ou pages persos ?
(ou ce que tu veux faire, si rien n'est déjà écrit)

**Chibitox** · 29/11/2007, 15h46

Tout d'abord merci de prendre le temps de se pencher sur mon pbm.

En fait pour le moment on m'a donné un setup assez basique qui ne contient pas de section [code].
Je dois lui ajouter une fenêtre qui permette à l'utiliteur d'entrer le nom d'une source et d'un driver ODBC dans des textbox par exemple. Une fois ces infos entrées, je veux aller les écrire dans mon fichier .ini.

Finalement le fichier .ini dans lequel je dois écrire n'était pas déclaré dans une section [INI] mais il est déclaré dans la section [files] de la manière suivante:

Source: Fichiers\AppPath\POSTE.INI; DestDir: {app}

Je suppose qu'il doit utiliser cette ligne pour le copier dans le repertoire de l'application. Mais que si moi je veux pouvoir écrire dedans je dois le déclarer dans la section [INI] non ?

La question que je me pose c'est: comment ?
En regardant l'aide je trouve cet exemple:

Filename: "MyProg.ini"; Section: "InstallSettings"; Key: "InstallPath"; String: "{app}"

Le pbm c'est de savoir ce que je dois mettre dans filename, est-ce le nom du fichier, son chemin absolu d'origine ou son chemin une fois qu'il aura été copié.
Etant donné que je n'ai aucune idée de l'ordre de séquencement dans lequel se feront les choses (va-t-il écrire avant de copier le fichier ou après ?) je ne sais pas trop comment renseigner ce champ.

Pour ce qui est des pages personalisées et des textboxs je pense pouvoir m'en sortir, ce qui me pose pbm c'est donc plus la récupération des infos saisies puis l'écriture dans le .ini.

**ThierryAIM** · 29/11/2007, 19h42

Voilà de quoi commencer:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
[Setup]
AppName=My Program
AppVerName=My Program 1.5
AppPublisher=My Company, Inc.
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputBaseFilename=setup_istest
Compression=lzma
SolidCompression=yes
 
[Languages]
Name: french; MessagesFile: compiler:Languages\French.isl
 
[Files]
Source: C:\Program Files\Inno Setup 5\Examples\MyProg.exe; DestDir: {app}; Flags: ignoreversion
Source: istest.ini; DestDir: {app}; Flags: ignoreversion
 
[Icons]
Name: {group}\My Program; Filename: {app}\MyProg.exe
Name: {commondesktop}\My Program; Filename: {app}\MyProg.exe; Tasks: desktopicon
 
[INI]
Filename: "{app}\istest.ini"; Section: InstallSettings; Flags: uninsdeletesection
Filename: "{app}\istest.ini"; Section: InstallSettings; Key: Param1; String: {code:GetParam1}; Flags: createkeyifdoesntexist
Filename: "{app}\istest.ini"; Section: InstallSettings; Key: Param2; String: {code:GetParam2}; Flags: createkeyifdoesntexist
 
 
[ Code ]
// Procédures d'évenements
var
  PageParam: TInputQueryWizardPage;
 
// Creer les Pages Personnalisées
procedure CreateTheWizardPages;
 
begin
  // Create the page
PageParam := CreateInputQueryPage(wpWelcome,
  'Personal Information', 'Who are you?',
  'Please specify your name and the company for whom you work, then click Next.');
 
// Add items (False means it's not a password edit)
	PageParam.Add('Name:', False);
	PageParam.Add('Company:', False);
	PageParam.Values[0]:= 'Valeur_1';
	PageParam.Values[1]:= 'Valeur_2';
end;
 
 
// Fonctions de retour
function GetParam1(Param: String): String;
begin
    Result := PageParam.Values[0];
end;
function GetParam2(Param: String): String;
begin
    Result := PageParam.Values[1];
end;
 
{*** INITIALISATION ***}
procedure InitializeWizard;
begin
  CreateTheWizardPages;
end;

**Chibitox** · 04/12/2007, 11h44

Merci beaucoup.

**Met@lnono** · 15/01/2008, 09h36

Est il possible d'internationaliser le texte de la page par rapport à la langue qui serait choisi au début de l'install, et si possible comment faire ?
Merci

**ThierryAIM** · 15/01/2008, 12h10

c'est possible

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
[Setup]
AppName=My Program
AppVerName=My Program 1.5
AppPublisher=My Company, Inc.
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputBaseFilename=setup
Compression=lzma
SolidCompression=yes
OutputDir=C:\InnoSetup\Output
 
[Languages]
Name: en; MessagesFile: compiler:Default.isl
Name: fr; MessagesFile: compiler:Languages\French.isl
 
[CustomMessages]
; Français
fr.TaskIconGroup=Icônes :
fr.TaskDesktopIcon=Créer une icône sur le &bureau
fr.TaskQuickLaunchIcon=Créer une icône de &démarrage rapide
fr.PageParamTitre=Informations personnelles
fr.PageParamText1=Qui êtes vous ?
fr.PageParamText2=Entrez votre nom et votre société, puis cliquez sur Suivant.
fr.PageParamLbl1=Nom :
fr.PageParamLbl2=Société :
 
;English
en.TaskIconGroup=Icons :
en.TaskDesktopIcon=Create a desktop icon
en.TaskQuickLaunchIcon=Create a quicklaunch icon
en.PageParamTitre=Personal Informations
en.PageParamText1=Who are you ? ?
en.PageParamText2=Please specify your name and the company for whom you work, then click Next.
en.PageParamLbl1=Name :
en.PageParamLbl2=Company :
 
[Tasks]
Name: DesktopIcon; Description: {cm:TaskDesktopIcon}; GroupDescription: {cm:TaskIconGroup}; Flags: checkedonce
Name: QuickLaunchIcon; Description: {cm:TaskQuickLaunchIcon}; GroupDescription: {cm:TaskIconGroup}; Flags: unchecked
 
[Files]
Source: C:\Program Files\Inno Setup 5\Examples\MyProg.exe; DestDir: {app}; Flags: ignoreversion
;Source: istest.ini; DestDir: {app}; Flags: ignoreversion
 
[Icons]
Name: {group}\My Program; Filename: {app}\MyProg.exe
Name: {commondesktop}\My Program; Filename: {app}\MyProg.exe; Tasks: desktopicon
 
[INI]
Filename: {app}\istest.ini; Section: InstallSettings; Flags: uninsdeletesection
Filename: {app}\istest.ini; Section: InstallSettings; Key: Param1; String: {code:GetParam1}; Flags: createkeyifdoesntexist
Filename: {app}\istest.ini; Section: InstallSettings; Key: Param2; String: {code:GetParam2}; Flags: createkeyifdoesntexist
 
 
[ Code ]
var
  PageParam: TInputQueryWizardPage;
 
// Procédures d'évenements
 
// Creer les Pages Personnalisées
procedure CreateTheWizardPages;
 
begin
  // Create the page
PageParam := CreateInputQueryPage(wpWelcome,
  ExpandConstant('{cm:PageParamTitre}'), ExpandConstant('{cm:PageParamText1}'),
  ExpandConstant('{cm:PageParamText2}'));
 
// Add items (False means it's not a password edit)
	PageParam.Add(ExpandConstant('{cm:PageParamLbl1}'), False);
	PageParam.Add(ExpandConstant('{cm:PageParamLbl2}'), False);
	PageParam.Values[0]:= 'Valeur_1';
	PageParam.Values[1]:= 'Valeur_2';
end;
 
 
// Fonctions de retour
function GetParam1(Param: String): String;
begin
    Result := PageParam.Values[0];
end;
function GetParam2(Param: String): String;
begin
    Result := PageParam.Values[1];
end;
 
{*** INITIALISATION ***}
procedure InitializeWizard;
begin
  CreateTheWizardPages;
end;

**Met@lnono** · 15/01/2008, 21h15

Merci beaucoup c'est exactement se que je cherchais

**cisse-aboubacar** · 18/09/2015, 19h30

avant toute chose je souhaiterai vous remercier pour avoir prêter attention a ma requette.
j'ai configuré inno setup et tout marche bien lorsque je créer l’exécutable et l'installation de l'application de se déroule très bien d’ailleurs mais mon soucis est que je souhaiterai Ecrire un script a l’intérieur qui agira sur le lancement de l'application c'est a dire changer le lien du raccourcis de lancement de l'application sur le bureau et aussi un autre script qui demande a l'utilisateur de d’insérer par exemple des informations qui seront ensuite stocker dans un fichier "ini" et que l'application lise les informations contenue dans le fichier "ini".

Merci cordialement de vos différentes réponses

InnoSetup - Ecrire dans un fichier config

Installation, Déploiement et Sécurité VB

Discussions similaires

Partager

Partager