Discussion :

[stsym]

Bonjour
Je suis débutant en vba et essaie d'adapter les codes trouvés sur le site à mon application.
Mais là je suis bloqué.
J'ai une macro qui permet de rechercher dans une colonne la ligne qui contient le libellé "Largeur" et qui sur toute la ligne remplace la virgule par un point.
Tout fonctionne bien mais certaines fois ce champ n'existe pas dans cette colonne.
Evidemment dans ce cas ma macro bug.
Ma question est donc : comment passer à l'action suivante si ce champ n'existe pas.
D'avance merci pour votre aide.
Cordialement.
StStym

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
    Application.Goto Reference:="C_ProductId"
    ActiveCell.EntireColumn.Select
    Selection.Find(What:="Largeur", After:=ActiveCell, LookIn:= _
        xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:= _
        xlNext, MatchCase:=False, SearchFormat:=False).Activate
    ActiveCell.EntireRow.Select
    Selection.NumberFormat = "@"
    For Each Cell In Selection
    Cell.Value = Replace(Cell.Value, ",", ".")
    Next

[Theze]

Bonjour,

Avant toutes choses, il faut tester si Find retourne bien un Range :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
 
    With Worksheets("Feuil1")
 
        Set Plage = .Range(.Range("C_ProductId"), .Cells(Rows.Count, .Range("C_ProductId").Column).End(xlUp))
 
        Set Cel = Plage.Find("Largeur", , xlFormulas, xlPart)
 
        If Not Cel Is Nothing Then
 
            Set Plage = .Range(.Cells(Cel.Row, Cel.Column), .Cells(Cel.Row, Columns.Count).End(xlToLeft))
            Plage.NumberFormat = "@"
 
            For Each Cel In Plage: Cel.Value = Replace(Cel.Value, ",", "."): Next Cel
 
        Else
 
            MsgBox "Pas trouvé !"
 
        End If
 
    End With
 
End Sub

Hervé.

[stsym]

Bonjour Theze
Génial tout fonctionne très bien.
Il faut que j'adapte ton code.
En effet au lieu d'avoir le message "MsgBox "Pas trouvé !",
il faut que je vérifie que dans cette colonne si les libellés " Longueur" et "Hauteur" sont aussi présents et changer leurs données en remplaçant la virgule par un point.
Pour moi la discussion est résolue mais si tu as une solution à ma demande je suis preneur.
Cordialement.
StSym

[Theze]

Bonjour,

Ceci peut être ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tbl
    Dim I As Integer
 
    Tbl = Array("Hauteur", "Largeur", "Longueur")
 
    With Worksheets("Feuil1")
 
 
        For I = 0 To UBound(Tbl)
 
            Set Plage = .Range(.Range("C_ProductId"), .Cells(Rows.Count, .Range("C_ProductId").Column).End(xlUp))
 
            Set Cel = Plage.Find(Tbl(I), , xlValues, xlPart)
 
            If Not Cel Is Nothing Then
 
                Set Plage = .Range(.Cells(Cel.Row, Cel.Column), .Cells(Cel.Row, Columns.Count).End(xlToLeft))
                Plage.NumberFormat = "@"
 
                For Each Cel In Plage: Cel.Value = Replace(Cel.Value, ",", "."): Next Cel
 
            Else
 
                MsgBox "Pas trouvé !"
 
            End If
 
        Next I
 
    End With
 
End Sub

Hervé.