Discussion :

[tamtam64]

Bonjour,

Je cherche une methode, pour construire un range avec une condition:

On a une feuille, avec des lignes de données, on souhaite selectionner que certaines lignes selon une condition.
Exemple : on parcours la premiere colonne , si la valeur = x ou si la valeur = J alors je l'ajoute a un range que j'ai créé.
En fait avec un union j'aimerais construire un range avec les lignes que je veux.

J'ai réussi à le faire enselectionnant tt et en supprimant les lignes differente de ma condition, mais je voudrais vraiment savoir faire un range avec application.union avec une condition sur la ligne

ps : ma ligne est un range de 32 colonnes , ca n'est pas dynamique
Merci d'avance

[Marc-L]

Bonjour,

je me demande d'où vient cette mode de parcourir (donc boucle) alors que c'est plus efficace en filtrant les cellules !

Mais bon, voici un exemple d'Union des lignes impaires :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Demo()
    Dim Rg As Range, Rw As Range
 
    With Feuil1.Cells(1).CurrentRegion
        Set Rg = .Rows(1)
 
        For Each Rw In .Rows
              If Rw.Row Mod 2 Then Set Rg = Union(Rg, Rw)
        Next
    End With
 
    Debug.Print Rg.Address
    Set Rg = Nothing
End Sub

_____________________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

_____________________________________________________________________________________________________

Je suis Charlie - Je suis Bardo

[tamtam64]

Je te remercie, c'est exactement la syntaxe que je recherchais , merci

[joe.levrai]

Bonjour,

quels types de conditions ? cette plage est destinée à quoi ?

un exemple amusant sans boucle et sans union
la plage est simplement copiée pour illustrer
c'est paramétrable facilement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub SansBoucleNiUnion()
Dim Critere As String
Dim ColCritere As Long
Dim Nbcolonnes As Long
Critere = "toto"
Nbcolonnes = 32
ColCritere = 1
 
Application.ScreenUpdating = False
With Feuil1
    .AutoFilterMode = False
    With .Cells(2, Nbcolonnes + 1).Resize(.UsedRange.Rows.Count - 1, 1)
        .FormulaR1C1 = "=IF(R[0]C[-" & Nbcolonnes + 1 - ColCritere & "]=""" & Critere & """,1,0)"
              .Value = .Value
    End With
    .Cells(1, 1).AutoFilter Nbcolonnes + 1, 1
    .AutoFilter.Range.Copy Feuil2.[A1]
    .AutoFilterMode = False
    .Columns(Nbcolonnes + 1).Delete
End With
Application.ScreenUpdating = True
End Sub

EDIT : arf ! encore coiffé au poteau, Marc a soulevé les cellules filtrées avant que je poste

[tamtam64]

Merci Joe, plusieurs questions: [A1] c'est une cellule?
peux tu juste me donner quelques explications sur ton code et son fonctionnement ca m'interresse bcp

[joe.levrai]

Bonjour,

[A1] remplace Range("A1") ou Cells(1,1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub SansBoucleNiUnion()
Dim Critere As String
Dim ColCritere As Long
Dim Nbcolonnes As Long
Critere = "toto"
Nbcolonnes = 32
ColCritere = 1
 
Application.ScreenUpdating = False
With Feuil1
    .AutoFilterMode = False
    ' colonne à côté de tes données (33 dans ton cas)
    With .Cells(2, Nbcolonnes + 1).Resize(.UsedRange.Rows.Count - 1, 1)
        ' formule pour marquer les lignes qui contiennent ton critère avec le chiffre 1
        .FormulaR1C1 = "=IF(R[0]C[-" & Nbcolonnes + 1 - ColCritere & "]=""" & Critere & """,1,0)"
              ' remplacement de formules par les valeurs
              .Value = .Value
    End With
    ' filtre sur les résultats (colonne 33 = chiffre 1)
    .Cells(1, 1).AutoFilter Nbcolonnes + 1, 1
    ' copie de la plage filtrée
    .AutoFilter.Range.Copy Feuil2.[A1]
    .AutoFilterMode = False
    ' suppression de la colonne de repérage
    .Columns(Nbcolonnes + 1).Delete
End With
Application.ScreenUpdating = True
End Sub