Discussion :

[nibledispo]

Bonjour,

Ma précédente demande n'a pas rencontré un franc succès, j'espère que celle-ci ne subira pas le même outrage.

Ci-dessous une portion de programme qui me permet de sélectionner dans un TCD l'exercice (année) à imprimer.
Tout fonctionne bien excepté si pour une quelconque raison (sortie brutale) toutes les années n'ont pas été ré affichées en sortant.
Exemple : si j'ai 2011 ,2012 , 2013 , 2014 et que je suis sorti avec seulement 2014 visible, il y a plantage.

Ce que fait ce programme:
- Il masque toutes les années dans la boucle
- Il affiche l'année demandée (v_annee) hors de la boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
With ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields("Années")
        ShtO.Activate     ' Feuille base de données
        n_annee = Year(Cells(vDebutImpr, 3)) 'initialisation à la première année dans TCD ' n_année $ première année dans base de donnée
        ShtS.Activate  ' feuille YCD
        Do While n_annee < Year(Date)
            .PivotItems(CStr(n_annee)).Visible = False
            n_annee = n_annee + 1
        Loop
        .PivotItems(CStr(vAnnee)).Visible = True  'v_annee = année à imprimer préalablement sélectionné
    End With

Avant de quitter je ré affiche bien entendu toutes les années en situation normale.

QUESTION : Y a-t-il une méthode plus simple voire plus propre de faire ce travail

Merci
Paul

[Invité]

Bonjour,


Un code à tester contenant 3 procédures. Je ne l'ai pas testé moi-même, mais celui-ci est adapté d'un de mes fichiers. A vérifier si la déclaration de N_Annee en variant est pertinente.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Sub SelectionItems(ByVal FeuilleTcd As Worksheet, ByVal N_Annee As Variant)
 
Dim Pvt As PivotTable
Dim PvtItem As PivotItem
 
    'Application.ScreenUpdating = False
 
    Set Pvt = FeuilleTcd.PivotTables("Tableau croisé dynamique1")
 
    With Pvt
        ' Effacement des anciens filtres et rafraichissement du Tcd.
        .PivotFields("Années").ClearAllFilters
        .PivotCache.Refresh ' Pas obligatoire
 
       ' Mise à jour du TCD.
        For Each PvtItem In Pvt.PivotFields("Années").PivotItems
            If PvtItem.Caption = CStr(N_Annee) Then
               PvtItem.Visible = True
            Else
               PvtItem.Visible = False
            End If
        Next PvtItem
 
    End With
 
    Set Pvt = Nothing
 
    'Application.ScreenUpdating = True
 
End Sub
 
 
Sub DeSelectionnerLesItems(ByVal FeuilleTcd As Worksheet)
 
    FeuilleTcd.PivotTables("Tableau croisé dynamique1").PivotFields("Années").ClearAllFilters
 
End Sub
 
 
 
Sub EssaiSelectionItems()
 
    SelectionItems ActiveSheet, Year(ShtO.Cells(vDebutImpr, 3))
 
    ' Traitement suivant....
 
    DeSelectionnerLesItems ActiveSheet
 
 
End Sub

Cordialement.

[nibledispo]

Bonjour ERIC,

Tout marche à merveille !
Mon problème était dû à mon ignorance de la fonction ClearAllFilters qui supprime tous les filtres.

En effet, comme je l'ai écrit dans ma question, le problème ne survenait qu'avec un champs Années du TCD comportant des filtres. En situation normale (sortie propre) cela ne pouvait se produire, mais il convenait que j'éradique ce risque.

Du coups mon morceau de programme supprimant les filtres avant de sortir va s'en trouvé simplifié (je passais dans une boucle chaque année en revue pour les mettre à visible = true

je retiens également le set qui évite des instructions inutilement longues.

Merci de m'avoir enlevé cette épine du pieds.

cordialement,
Paul