Discussion :

[shipuden64]

Bonjour à tous,
J'ai une macro qui me permet de copier des cellules d'une feuille "Montage" (du classeur "Calcul2") vers une feuille "Feuil1" (du classeur "Calcul1"). Parfois le classeur Calcul1 peut être ouvert. J'ai donc mis en place une gestion d'erreur pour que ma macro fonctionne même si le classeur est déjà ouvert sauf que j'ai une erreur et je n'arrive pas a mettre le doigt dessus malgré plusieurs modifications. J'ai besoin d'un oeil plus expert que le mien
Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub export()
Dim classeurA As Workbook
Dim classeurB As Workbook
 
On Error Resume Next
Workbooks("Calcul1.xls").Activate
 
If Err.Number <> 0 Then
 Application.Workbooks.Open "C:\Desktop\Calcul1.xls"
End If
On Error GoTo 0
 
Set classeurA = Workbooks.Open("C:\Desktop\Calcul1.xls")
Set classeurB = Workbooks("Calcul2.xlsm")
 
m = classeurA.Sheets("Feuil1").Cells(Rows.Count, "A").End(xlUp).Row + 1
For i = 1 To 500 Step 1
If classeurB.Worksheets("Montage").Range("A" & i) <> 0 Then
    classeurB.Worksheets("Montage").Range("A" & i, "L" & i).Copy Destination:=classeurA.Worksheets("Feuil1").Range("A" & m)
m = m + 1
End If
Next i
 
MsgBox ("Exportation réussie")
End Sub

Merci à vous tous

[Invité]

Bonjour,

Une autre façon d'accéder à un fichier avec la possibilité qu'il soit déjà ouvert :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub OuvertureFichiers(ByVal NomFichier As String, ByVal RepertoireFichier As String)
 
Dim Wb As Workbook
Dim WbDejaOuvert As Workbook
Dim Continuer As Boolean
 
    Continuer = True
    For Each Wb In Workbooks
        Select Case Wb.Name
            Case NomFichier
                Set WbDejaOuvert = Wb
                Continuer = False
                Exit For
        End Select
    Next Wb
 
    If Continuer = True Then
        Workbooks.Open Filename:=RepertoireFichier & "\" & NomFichier
    Else
        WbDejaOuvert.Activate
        Set WbDejaOuvert = Nothing
    End If
 
End Sub

Cordialement.

[joe.levrai]

Bonjour,

quand tu dis que le classeur1 peut parfois être ouvert, c'est ouvert par toi ou par un autre utilisateur ?


voici quelques exemples de gestion de ces problématiques :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub shipuden64()
 
    Dim Wb As Workbook
    Dim Present As Boolean
 
    ' on cherche si le classeur est déjà ouvert dans l'instance
    For Each Wb In Application.Workbooks
        If Wb.Name = "Nom de ton classeur" Then
            Present = True
            Exit For
        End If
    Next Wb
 
    ' on gère soit son ouverture, soit son instanciation dans la variable Wb
    If Present = False Then
        Set Wb = Workbooks.Open("Chemin du fichier")
    Else
        Set Wb = Workbooks("Nom du fichier")
    End If
 
    ' on teste l'état de lecture seule
    If Wb.ReadOnly = True Then
        MsgBox "Fichier en lecture seule"
    End If
 
End Sub

[shipuden64]

Bonjour à vous deux,
Ouvert par moi même.

Ca marche niquel j'ai opté pour le code de joe.levrai
Merci à vous deux. Problème résolu