Discussion :

[debdev]

Bonjour,

J'ai besoin de vos conseils car même si j'ai déjà écrit des posts sur DAO/ADO, j'ai encore de grandes difficultés à comprendre à quoi ça correspond. Mon objectif final est d'injecter ma syntaxe SQL écrite en partie en VBA dans une requête SQL direct.

Jusque là, mon programme fonctionnait à peu près car il se pouvait que, de façon aléatoire, il y ait parfois un message indiquant que l'appel à ODBC avait échoué. Comme j'avais déjà eu ce problème, j'ai voulu changer DAO en ADO en pensant que ça allait résoudre la situation...

Voici le code où j'utilise un recordset DAO et où parfois j'ai une erreur:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Public Sub ComputeQueries(SQLWhere As String, db As DAO.Database)
 
    On Error GoTo err
    Dim RstTable As DAO.Recordset
    Dim strSQLModele As String
    Dim strNomRqt As String
 
    Set RstTable = db.OpenRecordset("SELECT QueryName, QueryCode FROM QUERIES where TypeV='TYPE1'")
    RstTable.MoveFirst
    While Not RstTable.EOF
        strNomRqt = RstTable.Fields("QueryName").Value
        strSQLModele = RstTable.Fields("QueryCode")
        db.QueryDefs(strNomRqt).SQL = strSQLModele ' cette ligne injecte la syntaxe SQL contenue dans strSQLModele dans ma requête SQL direct déjà existante au nom strNomRqt
        RstTable.MoveNext
    Wend
    RstTable.Close
    Set RstTable = Nothing
 
    Exit Sub
err:
    MsgBox "Une erreur est survenue" & vbCrLf & err.Description, vbCritical, "ComputeQueries"
End Sub

Voici le code où j'utilise un recordset ADO qui semble marcher mais j'ai peur de tout mélanger en mixant du code DAO et ADO (j'ai laissé db as DAO.database) donc j'aimerai avoir votre avis sur ce code: suis-je en train de faire n'importe quoi ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Public Sub ComputeQueriesADO(SQLWhere As String, db As DAO.Database)
 
    On Error GoTo err
 
    Dim oCn As ADODB.Connection
    Dim oRS As ADODB.Recordset
    Dim sSql As String
    Dim strSQLModele As String
    Dim strNomRqt As String
 
    Set oCn = Application.CurrentProject.Connection
    Set oRS = New ADODB.Recordset
    Set oRS.ActiveConnection = oCn
    sSql = "SELECT QueryName, QueryCode FROM QUERIES where TypeV='TYPE1'"
    oRS.Open sSql, , adOpenForwardOnly, adLockReadOnly, adCmdText
 
    oRS.MoveFirst
    While Not oRS.EOF
        strNomRqt = oRS.Fields("QueryName").Value
        strSQLModele = oRS.Fields("QueryCode")
        db.QueryDefs(strNomRqt).SQL = strSQLModele
        oRS.MoveNext
    Wend
    oRS.Close
    Set oRS = Nothing
    oCn.Close
    Set oCn = Nothing
 
    Exit Sub
err:
    MsgBox "Une erreur est survenue" & vbCrLf & err.Description, vbCritical, "ComputeQueriesADO"
End Sub

Pouvez-vous me dire si je m'y prends bien ?
J'ai fait des tests en utilisant command et catalogue ADOX mais je ne m'en suis pas sortie donc je suis revenue à QueryDefs ...
Merci !

[LedZeppII]

Bonjour,

La première sub (ComputeQueries) me semble parfaite.
La seconde (ComputeQueriesADO) ne fait rien de plus qu'utiliser un recordset ADO au lieu d'un recordset DAO pour parcourir la table QUERIES.

Je ne crois pas que tes erreurs ODBC viennent de la façon dont tu changes le code sql de la requête SQL-Direct.
Sans le message erreur provenant du pilote ODBC c'est difficile de se faire une opinion.
Le message d'erreur que cites vient d'Access et il est incomplet.
Il faudrait peut-être, quand le problème se produit, essayer d'ouvrir un recordset sur la requête SQL-Direct.
DAO devrait fournir un message plus explicite.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub TestSQLDirect()
Dim db As DAO.Database, rs As DAO.Recordset
Dim errX As DAO.Error, strErrMsg As String
 
On Error GoTo ErrH
 
Set db = Application.CurrentDb
Set rs = db.OpenRecordset("select * from [nom requête sql-direct]")
 
rs.Close
 
ExitS:
    Set rs = Nothing
    Set db = Nothing
    If Len(strErrMsg) <> 0 Then MsgBox strErrMsg
    Exit Sub
 
 
ErrH:
    strErrMsg = "Erreur N° " & CStr(Err.Number) & " : " & Err.Description
    strErrMsg = strErrMsg & vbCrLf & vbCrLf & _
       ">>> Erreurs DAO :" & vbCrLf & _
       "======================"
    'Récupérations Erreur(s) DAO
    For Each errX In DBEngine.Errors
        strErrMsg = strErrMsg & vbCrLf & Format(errX.Number, "00000") & " : " & errX.Description
    Next
 
    Resume ExitS
 
End Sub

A+

[LedZeppII]

Bonjour,

J'ai fait des tests en utilisant command et catalogue ADOX mais je ne m'en suis pas sortie donc je suis revenue à QueryDefs ...

J'ai mis du temps à trouver, mais finalement je crois avoir trouvé.
Je mets mon code juste pour information, car je pense qu'ADOX n'apporte rien de plus que DAO (si ce n'est plus de lignes de code).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Public Sub ComputeQueriesAdoX(SQLWhere As String, db As DAO.Database)
    Dim RstTable As DAO.Recordset
    Dim strSQLModele As String
    Dim strNomRqt As String
    Dim oCat As Object, oProc As Object, oCmd As Object
 
    On Error GoTo ErrH:
 
    ' Créer Catalogue ADOX sur la base en cours
    Set oCat = CreateObject("ADOX.Catalog")
    Set oCat.ActiveConnection = Application.CurrentProject.Connection
 
    Set RstTable = db.OpenRecordset("SELECT QueryName, QueryCode FROM QUERIES where TypeV='TYPE1'")
    RstTable.MoveFirst
    While Not RstTable.EOF
        strNomRqt = RstTable.Fields("QueryName").Value
        strSQLModele = RstTable.Fields("QueryCode")
        ' Référencer la requête SQL-Direct
        ' (elle est vue comme une procédure et non comme une Vue à cause de son type SQL-Direct)
        Set oProc = oCat.Procedures(strNomRqt)
        ' Référencer la commande
        Set oCmd = oProc.Command
        ' Modifier le SQL de la commande
        oCmd.CommandText = strSQLModele
        ' Actualiser la requête
        Set oProc.Command = oCmd
        oCat.Procedures.Refresh
        ' Enregistement suivant
        RstTable.MoveNext
    Wend
    RstTable.Close
    Set RstTable = Nothing
    Set oCmd = Nothing
    Set oProc = Nothing
    Set oCat = Nothing
    Exit Sub
 
ErrH:
    MsgBox "Une erreur est survenue" & vbCrLf & err.Description, vbCritical, "ComputeQueriesAdoX"
End Sub

L'astuce pour que ça fonctionne se trouve ligne 26.
Sans cette ligne, les modifications ne sont pas enregistrées.

A+

[debdev]

Salut !

Merci pour tes réponses LedZeppII. Avant d'envoyer ce message, j'ai procédé à des tests. Et j'ai été confrontée à un problème réseau indépendant du code VBA (pb de driver), du coup, j'ai mis du temps à répondre...

J'ai testé ton code pour injecter la syntaxe SQL dans une requête SQL direct avec ADOX Nickel, comme ça j'ai les 2 façons de faire DAO et ADOX.
Par contre, avec ADOX, mon programme met 2 fois plus de temps à s'exécuter.

Je vais donc garder DAO pour le momenet et la prochaine fois que je rencontre l'erreur ODBC, je vais tester ton code pour décrypter l'erreur. Mais j'ai une question: le code que tu m'as mis, je peux l'exécuter après coup ? C'est-à-dire que si mon programme plante, je peux l'arrêter, repérer sur quelle requête SQL il a planté et lancer ton code pour avoir une erreur plus détaillée ? Ou bien il faut que j'insère ton code dans le mien et qu'il s'exécute en même temps ?

Cette nuit, j'ai lancé mon programme intégral, tout a fonctionné.
En ce moment même, je retourne mon programme intégral, j'attends...

Un grand merci pour ton aide !

[LedZeppII]

Bonjour,

Je pense que DAO est la bibliothèque la plus appropriée pour modifier une requête SQL-Direct.
Je ne pense pas que ce soit db.QueryDefs(strNomRqt).SQL = strSQLModele qui soit à l'origine du problème.
C'est pour cette raison que je t'ai proposé ma procédure TestSQLDirect(), pour tester la requête SQL-Direct.
Son but est de tester l'exécution de la requête, en l'ouvrant avec un recordset, et d'afficher un message d'erreur plus détaillé.
Donc, oui il faut connaître le nom de la requête SQL-Direct qui est à l'origine de l'erreur ODBC.

Voila ce à quoi je pensais...:
Admettons que ta table QUERIES contienne dix requêtes nommées R_SQLDIRECT_001 à R_SQLDIRECT_010.
Tu exécutes ton code ComputeQueries qui va modifier le code SQL de ces dix requêtes.
(Je ne m'attends pas à ce qu'une quelconque erreur ODBC soit levée à ce niveau).
Je suppose qu'ensuite ces requêtes sont exploitées/exécutées d'une manière ou d'une autre.
Si une erreur ODBC est levée, il faut déterminer sur quelle requête ou quelle requête est impliquée.
Supposons que tu détermines que c'est R_SQLDIRECT_006.
Tu modifies cette ligne de mon code...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set rs = db.OpenRecordset("select * from [nom requête sql-direct]")

...en...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set rs = db.OpenRecordset("select * from [R_SQLDIRECT_006]")

... tu exécutes mon code (il faudra certainement arrêter le débogueur au préalable).
Et là, je m'attends à ce que ma procédure donne un message plus complet.
Exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Erreur N° 3146 : ODBC -- l'appel a échoué.

>>> Erreurs DAO :
======================
01064 : [MySQL][ODBC 5.2(w) Driver][mysqld-5.1.41-community-log]You have an error in your SQL syntax; check the manual that corresponds to your MySQL server version for the right syntax to use near 'all tables' at line 1
03146 : ODBC -- l'appel a échoué.

L'erreur 3146 est l'erreur générique reportée par VBA.Err.
L'erreur 1064 est plus spécifique et provient du pilote ODBC.

A+

[debdev]

Merci pour toutes tes explications

J'ai remis DAO pour parcourir le recordset initial.

J'ai lancé plusieurs fois de suite mon code et il n'a pas planté mais dès que ça recommence, j'utiliserai ta méthode permettant d'avoir un message d'erreur plus explicite.

Merci +++