Discussion :

[calindoudou]

Bonjour,
j'ai presque fini mes 2 fichiers .xls (que je vous met en PJ) pour ma toute petite entreprise
je coince sur 2-3 points et sollicite votre aide.


->Pour le fichier "compta" :
dans le ruban "compta-gestion"
* Dans "definition date" ; je voudrais rentrer 2 dates (qui se trouve dans la feuille "parametre" cellule F16 et F17
* Dans "quitter" ; l'idée serait de sauvegarder & quitter

-> pour "paie":
* juste je n'arrive toujours pas dans l'onglet "selectionnez mois" à renvoyer sur les bonnes feuilles.

Merci d'avance pour tout

[pgz]

Bonjour.

J'ai regardé le classeur PAIE.
Pour faire marcher ta commande, le plus simple est de modifier le nom de certaines feuilles qu'il faut orthographier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Fév ou fév
Mar ou mar
Jui ou jui (pour juillet)
Aoû ou aoû
Sep ou sep
Déc ou déc.

Sinon, tu dois modifier la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sub SelectionMois(control As IRibbonControl, id As String, index As Integer)

D'ailleurs dans cette procédure la dernière ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("GestionVB").Range("D15").Value = ActiveSheet.Range("K2").Value

semble à supprimer s'il n'y a pas dans ton classeur de feuille nommée GestionVB.

Cordialement,

PGZ

[calindoudou]

Super PGZ,
ce point la est réglé (j'avue que j'avais cherché et je ne trouvais pas) ...

[pgz]

Bonsoir,

Pour ce classeur compta il y a plusieurs choses à faire

Dans le module de code, lancer le debogage et corriger les pb. Par exemple la procédure Print_Mois est erronée.

Pour le bouton Quit. Il suffit de modifier la procédure prévue, par exemple comme cela (je n'ai pas changé le nom de cette procédure)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
'Callback for quitte onAction
Sub Part(control As IRibbonControl)
 
If Application.Workbooks.Count = 1 Then
    ThisWorkbook.Save
    Application.Quit
Else
    ThisWorkbook.Close True
End If
 
End Sub

Pour la saisie des dates de période, le pb c'est que le ruban appelle une procédure Date qui n'existe pas. En plus, il ne faut pas appeler une procédure Date (c'est déja une fonction).
Tu vas devoir renommer la procédure OnAction du Custom Ui, j'ai choisi "InputDates" et donc éditer le ruban.
Ensuite tu ajoutes cette procédure au module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
'Callback for date onAction
Sub InputDates(control As IRibbonControl)
Dim sRep As String
Dim dte1 As Date, dte2 As Date
 
'saisie de date de début
sRep = vbNullString
While sRep = vbNullString
 
    sRep = InputBox("Saisir la date de début de période", "Période")
    If sRep = vbNullString Then GoTo etqSaisieAnnulee
 
    If IsDate(sRep) Then
        dte1 = CDate(sRep)
        ThisWorkbook.Worksheets("Parametre").Range("F16") = dte1
    Else
        MsgBox "Vous devez saisir une date"
        sRep = vbNullString
    End If
 
Wend
 
'saisie de date de fin
sRep = vbNullString
While sRep = vbNullString
 
    sRep = InputBox("Saisir la date de fin de période", "Période")
    If sRep = vbNullString Then Exit Sub
 
    If IsDate(sRep) Then
        dte2 = CDate(sRep)
        ThisWorkbook.Worksheets("Parametre").Range("F17") = dte2
    Else
        MsgBox "Vous devez saisir une date"
        sRep = vbNullString
    End If
 
Wend
 
MsgBox "Vous avez saisi : " & vbCrLf & "Période du " & Format(dte1, "dd/mm/yyyy") & " au " & Format(dte2, "dd/mm/yyyy") & "."
 
etqSortie:
    Exit Sub
 
etqSaisieAnnulee:
    MsgBox "Saisie annulée"
    GoTo etqSortie
 
End Sub

Et cela devrait fonctionner. Tu peux encore ajouter un contrôle supplémentaire sur les dates, comme dte2 > dte1.

Voilà.

COrdialement,

PGZ

[calindoudou]

PGZ,

super, j'ai galéré depuis décembre pour faire cela
je sais que j'ai des debug a faire, car je me suis servi de differents forum et tuto pour créer mon truc, du coup va falloir que je me penche à découvrir comment deboguer


dis moi je peux te déranger encore une minute ou deux :
* pour le fichier compta.xlm je voudrais ne pas mettre à jour le calcul auto (d'ou l'icone calcul) et quand je ferme il remet cette fonction pour mes autres fichiers
(je sais pas si ca existe)
* pour le fichier paie, j'ai crée un bouton contrat, l'objectif est de me rediriger vers "mesdocuments/salariés" (meme si j'en ai qu'un mais je pense à l'avenir), quelle commande dois-je mettre

et peut on faire une sorte de bouton, qui quand je clique dessus, il m'affiche le "ruban complet office" (au cas ou je dois améliorer certaines feuilles)



Et franchement je ne sais comment te remercier pour ce travail fait, sauf si tu aimes les doudous

Cordialement,

[pgz]

CalinDoudou,

* pour le fichier compta.xlm je voudrais ne pas mettre à jour le calcul auto (d'ou l'icone calcul) et quand je ferme il remet cette fonction pour mes autres fichiers
(je sais pas si ca existe)

Si je comprends la question, il suffit de mettre dans la module de code ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Option Explicit
 
Private Sub Workbook_Activate()
Application.Calculation = xlCalculationManual
End Sub
 
Private Sub Workbook_Deactivate()
Application.Calculation = xlCalculationAutomatic
End Sub

* pour le fichier paie, j'ai crée un bouton contrat, l'objectif est de me rediriger vers "mesdocuments/salariés" (meme si j'en ai qu'un mais je pense à l'avenir), quelle commande dois-je mettre

Là, je ne comprends pas ce que tu veux faire.

et peut on faire une sorte de bouton, qui quand je clique dessus, il m'affiche le "ruban complet office" (au cas ou je dois améliorer certaines feuilles)

Oui, mais il faut modifier le xml standard du ruban pour mettre les onglets sous condition.

* franchement je ne sais comment te remercier pour ce travail fait, sauf si tu aimes les doudous

Pour être franc entre un doudou et un câlin...

Cordialement,

PGZ