Discussion :

[argoet]

l'unixien que je suis va péter un cable sous windows
j'ai besoin de faire un litle script qui renomme les fichiers passés en parametre en fichier.madate.monheure.extention
mais je me bat avec ces p****n de variable dans les ".bat"

Voici mon code Tbatch.bat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
echo OFF
rem ====================================================
rem == Renomme les 1 à 9 fichiers  passés en paremetres 
rem ==  (s'ils existent)  en nom(origine).date.time.ext(origine)
rem ====================================================

for /f "tokens=1-3 delims=/" %%f in ("%date%") do (set mydate=%%f%%g%%h)
for /f "tokens=1-3 delims=:," %%f in ("%time%") do (set mytime=%%f%%g%%h)

for %%a in (%1 %2 %3 %4 %5 %6 %7 %8 %9) do (
  if exist %%a (
     rem == recup du nom sans l'extention de %%a
     for /F %%I In ("%%a") Do Set nom=%%~nI
     rem == recup de l'extension sans le nom de %%a
     for /F %%I In ("%%a") Do Set ext=%%~xI
     echo ren %%a %nom%.%mydate%.%mytime%.%ext% 
  )
)

Quand je l'execute ce n'est pas du tout le resultat attendu
je m'attendais à ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
ren bb bb.23122014.174615.
ren ii ii.23122014.174615.
ren EN01.txt EN01.23122014.174615.txt
ren EN141212_061609.xml EN141212_061609.23122014.174615.xml

mais j'ai cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
ren bb EN141212_061609.23122014.174615.
ren ii EN141212_061609.23122014.174615.
ren EN01.txt EN141212_061609.23122014.174615.
ren EN141212_061609.xml EN141212_061609.23122014.174615.

d'avance merci de votre aide
@argoet

[sachadee]

Salut,

On va un peu simplifier et pas limiter le code à 9 fichiers. Tu peux mettre 1 fichier ou 15.
Ensuite pas besoin de boucle FOR pour accéder au delimiters. On utilise un CALL.
ce qui nous évite la création de variable.

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
::By SachaDee 2014
echo OFF
rem ====================================================
rem == Renomme les X fichiers  passés en paremetres 
rem ==  (s'ils existent)  en nom(origine).date.time.ext(origine)
rem ====================================================
 
for /f "tokens=1-3 delims=/" %%f in ("%date%") do (set mydate=%%f%%g%%h)
for /f "tokens=1-3 delims=:," %%f in ("%time%") do (set mytime=%%f%%g%%h)
 
for %%a in (%*) do call:traite "%%a"
exit/b
 
:traite
  if exist %1 (
     echo ren %1 %~n1.%mydate%.%mytime%%~x1 
  )

Tu vois que le BAT n'est pas si compliqué....

[argoet]

Un Grand Merci à vous sachadee.
Joyeux Noel
@Argoet
[resolu]