Discussion :

[ALEX80800]

Bonjour,

Je viens vers vous car je n'arrive pas avoir la logique dans le filtre pour selectionner et deselectionner les semaines que je veux voir

J'ai effectuer l'engistrement macro suivant pour voir comment cela réagissait sachant qu'au préalable les semaines allant de 40.5 à 48 étaient cochés:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Macro1()
 
    With ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields("Semaine" _
        )
        .PivotItems("40.5").Visible = False
        .PivotItems("49").Visible = True
    End With
End Sub

Donc le résultat affiche les semaines allant de 40.5 à 49 soit 10 semaines glissantes

NB : les semaine à cheval sur un mois sont subdivisées c'est à dire que pour la semaine 44 (27/10/2014 au 02/11/2014) la semaine 44 correspond à la période du 27/10 au 31/10 et la semaine 44.5 correspond à la période du 01/11 au 02/11


Donc si je reprends la macro ci dessus, je me demandais si je devais énuméré toutes les semaines et imputer une variable (boucle précisant les semaines que je veux voir et pas voir) pour dire si c'est False ou True

Merci de vos éclaircissements

[Invité]

Bonjour,

Un exemple à adapter à votre cas.

On fixe les limites début et fin des semaines à sélectionner dans la feuille du TCD (par exemple) et on regarde si la valeur Val(PvtItem.caption) se situe entre les limites.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub SelectionItems()
 
Dim ShTcd As Worksheet
Dim Pvt As PivotTable
Dim PvtItem As PivotItem
 
    Application.ScreenUpdating = False
 
    Set ShTcd = Sheets("Tcd Semaine")
    Set Pvt = ShTcd.PivotTables("Tableau croisé dynamique1")
 
    With Pvt
        ' Effacement des anciens filtres et rafraichissement du Tcd.
        .PivotFields("Semaine").ClearAllFilters
        .PivotCache.Refresh
 
       ' Mise à jour du TCD.
        For Each PvtItem In Pvt.PivotFields("Semaine").PivotItems
            If Val(PvtItem.Caption) >= ShTcd.Range("TcdSemaineDebut") And Val(PvtItem.Caption) <= ShTcd.Range("TcdSemaineFin") Then
               PvtItem.Visible = True
            Else
               PvtItem.Visible = False
            End If
        Next PvtItem
 
        .ColumnRange.ColumnWidth = 18
 
    End With
 
    Set Pvt = Nothing
    Set ShTcd = Nothing
 
    Application.ScreenUpdating = True
 
End Sub

Cordialement.

[ALEX80800]

Impeccable

Merci grandement