Discussion :

[laurent27530]

Bonjour je desire coller la le contenu de la feuille A a la suite du contenu de la feuilleB sans prendre la premiere ligne de la feuille A

j'arrive pas a adapter mon vba

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
test()
 
i = Workbooks(1).Worksheets("A").Cells(Rows.Count, 2).End(3).Row + 1
Sheets("A").UsedRange.Copy Worksheets("B").Cells(i, 1)
 
end sub

Merci pour votre aide

[Invité]

Bonjour,

Une solution possible avec ce code à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
 
Sub CopierLaFeuilleADansB()
 
Dim ShSource As Worksheet
Dim LigneDeTitreSource As Long
Dim DerniereLigneSource As Long
Dim DerniereColonneSource As Long
Dim AireSource As Range
 
Dim ShCible As Worksheet
Dim DerniereLigneCible As Long
 
     Set ShSource = Sheets("Feuil1") ' A adapter
     Set ShCible = Sheets("Feuil2")  ' A adapter
 
     With ShSource
            LigneDeTitreSource = 1  ' A adapter
            DerniereLigneSource = .Cells(.Rows.Count, 1).End(xlUp).Row
            DerniereColonneSource = .Cells(LigneDeTitreSource, .Columns.Count).End(xlToLeft).Column
            Set AireSource = .Range(.Cells(LigneDeTitreSource + 1, 1), .Cells(DerniereLigneSource, DerniereColonneSource))
     End With
 
     With ShCible
            DerniereLigneCible = .Cells(.Rows.Count, 1).End(xlUp).Row
            AireSource.Copy .Cells(DerniereLigneCible + 1, 1)
     End With
 
     Set AireSource = Nothing
     Set ShSource = Nothing
     Set ShCible = Nothing
 
End Sub

Cordialement.

[Marc-L]

Bonjour !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Demo()
    Dim Rg As Range
    With Worksheets("B").UsedRange:  Set Rg = .Rows(.Rows.Count).Cells(1).Offset(1):  End With
    With Worksheets("A").UsedRange:  .Offset(1).Resize(.Rows.Count - 1).Copy Rg:      End With
    Set Rg = Nothing
End Sub

_________________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

[laurent27530]

MERCI