Discussion :

[tyndare36]

Bonjour à toutes et à tous,
Je viens ici vous exposer une interrogation qui me permettra si une solution existe d’améliorer mes connaissances et de réduire le nombre de lignes de code.
Voici l’énoncé du Problème :

Sur une feuille Excel j’ai plusieurs TextBox

TextBox1
TextBox2
TextBox3
TextBox4
TextBox5
TextBox6
TextBox7

Pour chaque TextBox de la feuille le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
KeyAscii = Asc(UCase(Chr(KeyAscii)))
End Sub
 
Private Sub TextBox2_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
KeyAscii = Asc(UCase(Chr(KeyAscii)))
End Sub
 
Private Sub TextBox3_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
KeyAscii = Asc(UCase(Chr(KeyAscii)))
End Sub

Ce code permet de saisir du texte en minuscule dans la TextBox et de le transformé simultanément en majuscule.

Vous comprendrez qu’il est long et fastidieux de rentrer pour chaque TextBox ces trois lignes de code.
Je me demande donc s’il n’existe pas une solution pour faciliter et améliorer le codage.
Par exemple un module de classe qui ferait que chaque TextBox et nouvelles TextBox de la feuille Excel auraient une saisie en minuscule qui simultanément passe en majuscule.
Débutant en Visual Basic même si j’ai un peu bidouillé avec VBA la création, l'utilisation et la rationalisation des modules de classe qui demandent bien plus de pratique ne sont pas à ma portée.

Voilà pourquoi je m’adresse à vous.

Merci d’avance à toutes et à tous

[Theze]

Bonjour,

A mettre dans le module du classeur pour que la proc soit exécutée à l'ouverture de celui-ci. Pour le test, tu peux la lancer comme une proc normale car elle ne demande pas d'arguments :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Dim Txt() As New Classe1
 
 
Private Sub Workbook_Open()
 
    Dim TxtOLE As OLEObject
    Dim I As Integer
 
    For Each TxtOLE In Worksheets("Feuil1").OLEObjects
 
        If InStr(TxtOLE.Name, "TextBox") <> 0 Then
 
            I = I + 1
            ReDim Preserve Txt(1 To I)
            Set Txt(I).GroupeTxt = TxtOLE.Object
 
        End If
 
    Next TxtOLE
 
End Sub

A mettre dans le module de classe que tu aura au préalable ajouté au projet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Public WithEvents GroupeTxt As MSForms.TextBox
 
Private Sub GroupeTxt_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
 
    KeyAscii = Asc(UCase(Chr(KeyAscii)))
 
End Sub

Hervé.

[tyndare36]

Merci Hervé,

je vais l'adapter et l'utiliser.

Merci encore pour ton aide
Cordialement