Discussion :

[Arukya]

Bonjour à tous

J'aurais besoin d'un peu d'aide ne connaissant pas grand chose au batch.
J'ai besoin d'un petit script qui récupère tous les .pdf et .docx de mon C:\ (y compris tous les sous dossiers de ce dernier)
afin de copier coller ces derniers dans mon D:\DocBureautique.

A l'heure actuelle je suis incapable de trouver comment faire pour parcourir tous les dossiers de mon C:\

Un ami m'a conseiller d'utiliser le PowerShell pour ce genre de chose, cela serait plus pratique?

Merci infiniment d'avance.

[hackoofr]

Tester ce code et dites moi s'il existe un bug lors du test ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
@echo off
Mode con cols=100 lines=10 & Color 9B
Title Recherche et copie de tous les fichiers de type *.DOCX et *.PDF du C:\  (by Hackoo 2014)
Setlocal EnableDelayedExpansion
CD /D C:\
Set Destination=D:\DocBureautique
echo.
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type DOCX dans le C:\ ...
Dir /b /d /s *.docx > DOCX.txt
CLS
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier !Destination!\DOCX\ ...
For /F "delims=" %%X in ('Type DOCX.txt') do (Set Source="%%X" & Xcopy /I /D /Y /S /J /C !Source! !Destination!\DOCX\)
CLS
echo. 
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type PDF dans le C:\ ...
Dir /b /d /s *.pdf > PDF.txt
CLS
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier !Destination!\PDF\ ...
For /F "delims=" %%X in ('Type PDF.txt') do (Set Source="%%X" & Xcopy /I /D /Y /S /J /C !Source! !Destination!\PDF\)
echo.
echo Termine !
echo.
pause
Explorer !Destination!

[Arukya]

Bonjour et merci beaucoup hackoofr de votre aide et du mal que vous vous êtes donné, je ne pensais pas que cela serait si long

A première vue cela semble très bien fonctionner, je testerais ce soir tout cela plus en détail afin d'être sûr de mon affirmation ^^

[sachadee]

En beaucoup plus court et beaucoup plus rapide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
@echo off
echo Traitement en cours....
for /f "delims=" %%a in ('dir c:\ /b/s *.docx,*.pdf') do copy "%%a" "D:\DocBureautique"
echo termin‚
pause

@Hackoo Tu n'as pas besoin de l'expansion retardé ton :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Source="%%X"

est inutil

Tu peux directement utiliser la variable de ton FOR :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Xcopy /I /D /Y /S /J /C "%%X"

[Arukya]

Merci à toi
Je vais faire mes petits tests de mon coté pour voir alors

[hackoofr]

et pour ces remarques constructives Sacha
Effectivement, en tenant compte du dernier script posté, on constate bien qu'il est beaucoup plus rapide que le mien, alors voici le code testé chez moi en appliquant le script de Sacha
Remarque : Dans ce script j'ai créé un dossier DOCX et un dossier PDF dans le chemin de destination pour une meilleure organisation de copie selon l'extension

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
@echo off
Mode con cols=100 lines=10 & Color 9B
Title Recherche et copie de tous les fichiers de type *.DOCX et *.PDF du C:\  (by Hackoo and Sachadee 2014)
echo                                       Traitement en cours....
Set Destination=D:\DocBureautique
If Not Exist %Destination% MD %Destination%
CD /D C:\
echo.
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type DOCX dans le C:\ ...
Dir /b /d /s *.docx > DOCX.txt
CLS 
echo.
echo                           Creation du dossier "%Destination%\DOCX\"
Timeout /T 2 /NOBREAK >Nul
If Not Exist %Destination%\DOCX\ MD %Destination%\DOCX\
CLS
Title Veuillez patienter un peu ... on copie tous les fichiers de type DOCX dans le dossier %Destination%\DOCX\ ...
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type DOCX dans le dossier %Destination%\DOCX\ ...
for /f "delims=" %%a in ('Type DOCX.txt') do copy "%%a" "%Destination%\DOCX\"
Title Veuillez patienter un peu ... on cherche tous les fichiers de type PDF dans le C:\ ...
CLS
echo. 
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type PDF dans le C:\ ...
Dir /b /d /s *.PDF > PDF.txt
CLS 
echo.
echo                           Creation du dossier "%Destination%\PDF\"
Timeout /T 2 /NOBREAK >Nul
If Not Exist %Destination%\PDF\ MD %Destination%\PDF\
CLS
Title Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier %Destination%\PDF\ ...
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier %Destination%\PDF\ ...
for /f "delims=" %%a in ('Type PDF.txt') do copy "%%a" "%Destination%\PDF\"
Title Traitement Termine !
CLS
echo.
echo                                           Traitement Termine !
echo.
echo                        Appuyez sur une touche pour ouvrir le dossier %Destination%
pause >nul
Explorer %Destination%

@Sacha : "n'hésites surtout pas à ajouter vos commentaires et vos remarques Chef "

[Arukya]

Ayant oublier le chargeur de mon PC au boulot je n'ai pas pu tester tout cela hier soir :/
Je vais m'en occuper aujourd'hui et je reviens vers vous si j'ai des soucis :p
Merci infiniment à vous 2 pour votre précieuse aide

[Arukya]

Fabuleux :')

Juste par curiosité, est-il compliqué de rajouter une condition afin que les fichier copiés ne soit que ceux dont la taille dépasse 1mo par exemple?

Si cela est trop compliqué ce n'est pas grave, je me satisfait pleinement du script actuel
Merci encore !

[sachadee]

Essaye ceçi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
@echo off
echo Traitement en cours....
for /f "delims=" %%a in ('dir c:\ /b/s *.docx,*.pdf') do (
  if  %%~za GTR 1000000 copy "%%a" "D:\DocBureautique")
echo Termin‚
Pause

[hackoofr]

Essayez ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
@echo off
Mode con cols=100 lines=10 & Color 9B
Title Recherche et copie de tous les fichiers de type *.DOCX et *.PDF du C:\  (by Hackoo and Sachadee 2014)
echo                                       Traitement en cours....
Set Destination=E:\DocBureautique
::maxbytessize = 1Mo = 1000000
Set maxbytesize=1000000
If Not Exist %Destination% MD %Destination%
CD /D C:\
echo.
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type DOCX dans le C:\ ...
Dir /b /d /s *.docx > DOCX.txt
CLS 
echo.
echo                           Creation du dossier "%Destination%\DOCX\"
Timeout /T 2 /NOBREAK >Nul
If Not Exist %Destination%\DOCX\ MD %Destination%\DOCX\
CLS
Title Veuillez patienter un peu ... on copie tous les fichiers de type DOCX dans le dossier %Destination%\DOCX\ ...
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type DOCX dans le dossier %Destination%\DOCX\ ...
for /f "delims=" %%a in ('Type DOCX.txt') do (if %%~za GEQ %maxbytesize% copy "%%a" "%Destination%\DOCX\")
Title Veuillez patienter un peu ... on cherche tous les fichiers de type PDF dans le C:\ ...
CLS
echo. 
echo       Veuillez patienter un peu ... on cherche tous les fichiers de type PDF dans le C:\ ...
Dir /b /d /s *.PDF > PDF.txt
CLS 
echo.
echo                           Creation du dossier "%Destination%\PDF\"
Timeout /T 2 /NOBREAK >Nul
If Not Exist %Destination%\PDF\ MD %Destination%\PDF\
CLS
Title Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier %Destination%\PDF\ ...
echo. 
echo       Veuillez patienter un peu ... on copie tous les fichiers de type PDF dans le dossier %Destination%\PDF\ ...
for /f "delims=" %%a in ('Type PDF.txt') do (If %%~za GEQ %maxbytesize% copy "%%a" "%Destination%\PDF\")
Title Traitement Termine !
CLS
echo.
echo                                          Traitement Termine !
echo.
echo                       Appuyez sur une touche pour ouvrir le dossier %Destination%
pause >nul
Explorer %Destination%

[nothi]

hackoofr tu peux me repondre svp http://www.developpez.net/forums/d14...ript-hackoofr/ ( vous pouvez svp me donner votre compte fb pr vous contacter )

[Arukya]

Merveilleux
Merci encore et encore c'est parfait

[Arukya]

Après moultes essais je constate que les pdf cachés ne semblent pas être copiés.
C'est sûrement normal, je suppose qu'il n'y a rien pour y remédier?

[sachadee]

Après moultes essais je constate que les pdf cachés ne semblent pas être copiés.
C'est sûrement normal, je suppose qu'il n'y a rien pour y remédier?

Tu peux faire un :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
echo Traitement en cours....
attrib c:\*.pdf -H /s
for /f "delims=" %%a in ('dir c:\ /b/s *.docx,*.pdf') do (
  if  %%~za GTR 1000000 copy "%%a" "D:\DocBureautique")
echo Termin‚
pause

[Arukya]

Merci de ton coup de pouce