Discussion :

[Aniss00]

Bonjour j'ai besoin de faire un script qui affichera des message selon le langage de windows. je veux savoir s'il existe une cmd qui retourne le langage de windows (francais, anglais....). MERCI

[hackoofr]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
@echo off
set language=
ver /?|find /i "Displays">nul
if not errorlevel 1 set language=english
ver /?|find /i "Affiche">nul
if not errorlevel 1 set language=french

if not "%language%"=="" goto %language%
echo Unknown Language
goto end

:english
Echo. & The language of windows is English  
goto end

:french
Echo. & Echo le langage de windows est francais
goto end

:end
pause

[sachadee]

Salut Hackoo, Aniss00,

Ton code Hackoo te permet uniquement de tester si ton windows est français ou anglais.

Pour un solution un peu plus PRO jettez un coup d'oeil sur ce thread :

http://www.developpez.net/forums/gro...880&do=discuss

[hackoofr]

Sacha
SVP le lien nous indique :

Discussion du groupe social spécifié(e) non valide. Si vous suivez un lien valide, veuillez notifier l'administrateur

Postez directement le code ici
en faites sacha tu m'as fais l'analyse pour HackooFixTool.bat ? ou pas encore

[sachadee]

OK,

Apparemment il faut être membre du groupe pour pouvoir lire les discussions.

Donc voici un des projet de version de [NTGetLang] que l'on avais mises au point avec @minnesota dans le thread en question :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
@set "NTGetLang="
@set "NTGetLangDescription="
@setlocal
@set "user_language="
@call :set_reg_key_path "HKCU\Control Panel\International"
@call :set_reg_key_name "sLanguage"
@call :get_reg_key_value
@call :get_NTGetLangDescription
@endlocal& @if not "%reg_key_value%"=="" (@set "NTGetLang=%reg_key_value:~,2%"
                                          @set "NTGetLangDescription=%Description%")
@echo %NTGetLang%
@echo %NTGetLangDescription%
@if "%NTGetLang%"=="" @call :set_internal_error error
@goto:eof

:set_reg_key_path
@set "reg_key_path=%~1"
@goto:eof

:set_reg_key_name
@set "reg_key_name=%~1"
@goto:eof

:get_reg_key_value
@set /a fields=0
@for %%i in (%reg_key_name% +1) do @set /a fields+=1
@for /f "tokens=%fields%,*" %%i in ('@reg query "%reg_key_path%" /v "%reg_key_name%" 2^>nul ^|findstr /i "%reg_key_name: =.%"') do @set "reg_key_value=%%~j"
@goto:eof

:get_NTGetLangDescription
@for /f "delims=" %%a in ('type "%~pnx0" ^|findstr /i "%reg_key_value%"') do @set %%a
@call set "Description=%%%reg_key_value%%%"
@goto:eof

:set_internal_error
@verify %~1 >nul 2>&1
@goto :eof

:codes_list
csy=Czech               
dan=Danish                   
deu=German                   
des=German (Swiss)          
dea=German (Austrian)        
ell=Greek                    
ena=English (Australia)      
enc=English (canada)         
eng=English (U.K.)           
eni=English (Irish)          
enu=English (U.S.)           
enz=English (New Zeal.)      
esm=Spanish (Mexican)        
esn=Modern Spanish           
esp=Castilian Spanish        
fin=Finnish                  
fra=French                   
frb=French (Belgian)
frc=French (Canadian)
frs=French (Swiss)
hun=Hungarian
isl=Icelandic
ita=Italian
its=Italian (Swiss)
nlb=Dutch (Belgian)
nld=Dutch
non=Norwegian (Nynorsk)
nor=Norwegian (Bokmal)
plk=Polish
ptb=Portuguese (Brazilian)
ptg=Portuguese
rus=Russian
sky=Slovak
svc=Swedish
trk=Turkish
@goto :eof

Il y a encore plus de langues possibles à vous de voir si vous voulez les implementer ou pas. La méthode est là....



Hackoo non j'ai pas encore eu le temps pour ton analyse, mais ça va venir....