Discussion :

[renardor]

Bonjour à tous,

J'ai découvert VBA il y a 2 mois, et j'ai beaucoup appris en parcourant ce forum, mais cette fois-ci, je ne trouve pas la réponse à ma question ; d'où mon post (dsl si il existait déjà, et merci de me l'indiquer).

Bref, j'ai une longue liste de nombres sur une colonne (environ 52600 lignes) et je souhaiterais la transformer en un tableau de 6 colonnes (avec le même nombre d'éléments).

Voici le code que j'ai fait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub transpose()
Application.ScreenUpdating = False
Sheets(1).Select
Dim n As Integer
    n = 365 * 24
 
For i = 0 To n - 1
    Range(Cells(2 + i * 6, 2), Cells(7 + i * 6, 2)).Copy
    Range(Cells(2 + i, 7), Cells(2 + i, 12)).PasteSpecial transpose:=True
Next i
 
Application.ScreenUpdating = True
End Sub

Le problème, c'est que vu le nombre d'opérations, ce code est beaucoup trop long à exécuter.
Avez-vous des idées pour l'optimiser ?

Merci d'avance

[Igloobel]

Salut

première indication
Integer est limité de : -32 768 à 32 767
vu que tu traite + 50 000 je te conseille de déclarer en Long

Long est limité de : -2 147 483 648 à 2 147 483 647

sinon peux- tu donner d'autres détails

et je souhaiterais la transformer en un tableau de 6 colonnes (avec le même nombre d'éléments).

comment veux-tu que ce soit :
a) 6 colonnes pour 8767 lignes
b) 6 colonnes pour 52600 lignes

et compte faire une ligne puis la suite sur la ligne suivante
ou
une colonne puis la suite sur la colonne suivante ?


à+

PS : plutôt que de traité 6 dans une constante utilise directement 6 ! (c'est plus rapide)

[eriiic]

Bonjour,

Ca devrait être plus rapide :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub transpose()
    Const nbcol As Long = 6
    Dim lig As Long, col As Long, lig1 As Long
    Dim datas, result() As Double
    datas = [A2].Resize(Cells(Rows.Count, 1).End(xlUp).Row - 1)
    ReDim result(1 To UBound(datas) / nbcol, 1 To nbcol)
    For lig = 1 To UBound(result)
        For col = 1 To nbcol
            lig1 = lig1 + 1
            result(lig, col) = datas(lig1, 1)
        Next col
    Next lig
    Sheets("Feuil2").Cells.ClearContents
    Sheets("Feuil2").[A2].Resize(UBound(result, 1), UBound(result, 2)) = result
    Sheets("Feuil2").Activate
End Sub

[casefayere]

Bonjour eriiic, Igloobel, renardor

De mon coté, j'avais préparé ce code au cas où la longueur du tableau initial n'est pas un multiple de 6

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub transposition()
Dim x As Long, y As Long, z As Long
Dim Tbl, TbResult(), Derlg As Range
With Sheets(1)
  Set Derlg = .Range("B" & .Rows.Count).End(xlUp) 'a adapter à la bonne colonne
  Tbl = .Range("B2", Derlg) 'idem
    ReDim TbResult(1 To Int(UBound(Tbl) / 6) + 1, 1 To 6)
    For x = 1 To UBound(TbResult)
        For y = 1 To 6
            z = z + 1
            If z > UBound(Tbl) Then Exit For
            TbResult(x, y) = Tbl(z, 1)
        Next y
    Next x
    .Cells.ClearContents
    .Range("B2").Resize(UBound(TbResult, 1), 6) = TbResult
End With
End Sub

[renardor]

Merci à tous de vos réponses rapides

Il s'agissait bien d'un multiple de 6. Pour être précis, c'était une valeur de puissance appelée à EDF toutes les 10 minutes (10 min par ligne, soit 365*24*6 lignes). Et pour l'intégrer dans une autre macro, il me fallait une ligne par heure et 6 colonnes pour 0,10,20,30,40 et 50 min, soit 365*24 lignes et 6 colonnes.

Enfin, ton code est excellent eriiic
Il s'est exécuté en moins d'une seconde !

Si j'ai bien compris, tu n'as utilisé que des tableaux fictifs, c'est ça ?
C'est toujours plus rapide de copier un tableau que des cellules une par une ?

Enfin, ça montre que j'ai encore pas mal de progrès à faire !

Encore merci

[eriiic]

Oui, si beaucoup de données il faut limiter les lectures/écritures sur les feuilles.
Là tout est lu en 1 bloc, travaillé en mémoire et collé en 1 bloc.
eric

[renardor]

Une dernière question, eriic (ou quelqu'un d'autre qui passerait par là):

Lorsque tu écrit [A2], est ce que c'est équivalent à range("A2") ou bien cells(2,1) ?

Je ne connaissais pas ce raccourci, est ce qu'il y en a d'autres qui utiliseraient des références avec des nombres, genre [2,1] (celui là ne marche pas, j'ai déjà essayé).

Si ça existe, ça allégerait considérablement mes futurs programmes !

[eriiic]

Bonjour,

Lorsque tu écrit [A2], est ce que c'est équivalent à range("A2") ou bien cells(2,1) ?

oui, tout à fait
Mais attention, ça n'a pas que des avantages. Tu perds l'auto-complétion ce qui peut-être handicapant quand tu débutes.

genre [2,1] (celui là ne marche pas, j'ai déjà essayé)

Non, pas d'autre à ma connaissance.
Si ce n'est with ... end with qui va alléger la lecture, mais qui te fait perdre également l'auto-complétion.

eric