Discussion :

[GADENSEB]

Bonjour,
Je cherche à créer un script qui me permet de changer mes paramétres de connexion réseau en fonction du réseau auquel je me connecte en wifi, je m'explique :

- Je fais les va et viens entre plusieurs connexion freebox et cela me *** de changer les paramétres réseau à chaque fois.
- Je souhaiterais que quand je me connecte au réseau :

Réseau A :

Adresse IP : 192.168.0.10
Masque de sous-réseau : 255.255.255.0
Passerelle par défaut : 192.168.0.254

Serveur DNS préféré : 212.27.40.241
Serveur DNS auxiliaire : 212.27.40.240

Réseau B :

Obtenir une adresse IP automatiquement
Obtenir les adresses des serveurs DNS automatiquement


Est-ce possible ?


Bonne journée

Sébastien

[hackoofr]

Version Autoit
Changement d'adresse ip automatique (Travail + Maison)

[GADENSEB]

Hello !


heu c'est un peu confu pour moi !

Pou précision, je passe par chrome !
mais je veux modifier les parametres de cartes, pas sur le navigateur

Pourrais-tu me guider,svp

Seb

[hackoofr]

Testez ce Vbscript

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Option Explicit
Dim Title,ws,MessageA,MessageB,intAnswer,MsgEmptyInputBox,MsgNumbers
Title = "Basculer entre deux types de connexions © Hackoo"
MessageA = "1 - Réseau A : "& VbCrLF & VbTab & "Adresse IP : 192.168.0.10" & VbCrLF &_
VbTab & "Masque de sous-réseau : 255.255.255.0"& VbCrLF &_
VbTab & "Passerelle par défaut : 192.168.0.254"& VbCrLF &_
VbTab & "Serveur DNS préféré : 212.27.40.241"& VbCrLF &_
VbTab & "Serveur DNS auxiliaire : 212.27.40.240"
MessageB = "2 - Réseau B : Obtenir une adresse IP automatiquement DHCP Activé "
MsgEmptyInputBox = "La boîte se saisie est vide !"& Vbcr &" Quitter le script !"
MsgNumbers = "ATTENTION ! "& Vbcr &"Vous devez utiliser les numéros 1 ou 2 "
Set ws=CreateObject("wscript.shell")
Do
    intAnswer = InputBox(MessageA & VbCrLF & MessageB, "Entrer 1 ou 2 puis valider par OK © Hackoo","1")
    If intAnswer = "" Then 
        ws.Popup MsgEmptyInputBox,"2",Title,0+48
        Wscript.Quit
    End if
    If Not isNumeric(intAnswer) Then
        ws.Popup MsgNumbers,"2",Title,0+48
    end if
Loop until (isNumeric(intAnswer) And intAnswer <> "")
If int(intAnswer) = 1 Then
    Call IpStatique()
    MsgBox MessageA & VbCrLF & " est activé ",VbInformation,Title
Elseif int(intAnswer) = 2 Then
    Call ActiverDHCP()
Else
    ws.Popup MsgNumbers,"2",Title,0+48
    Wscript.Quit
End if
'***************************************************************************************************
Sub IpStatique()
    On Error Resume Next
    Dim objWMIService,objNetAdapter,strComputer,arrIPAddress,arrSubnetMask
    Dim arrGateway,colNetAdapters,errEnableStatic,errGateways,arrDNSServers,errDNSServers
    strComputer = "."
    arrIPAddress = Array("192.168.0.10")
    arrSubnetMask = Array("255.255.255.0")
    arrGateway = Array("192.168.0.254")
    arrDNSServers = Array("192.168.1.100","192.168.1.200")
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colNetAdapters = objWMIService.ExecQuery("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
    For Each objNetAdapter in colNetAdapters
        errEnableStatic = objNetAdapter.EnableStatic(arrIPAddress, arrSubnetMask)
        If Not errEnableStatic = 0 Then
            MsgBox "Failure assigning IP/Subnet." & VbCrLF &_
            "non attribution IP / sous-réseau",VbCritical,Titre
        End If
        errGateways = objNetAdapter.SetGateways(arrGateway)
        If Not errGateways = 0 Then
            WScript.Echo "Failure assigning Gateway." & VbCrLF &_
            "non attribution passerelle",VbCritical,Titre
        End If
        errDNSServers = objNetAdapter.SetDNSServerSearchOrder(arrDNSServers)
        If Not errDNSServers = 0 Then
            WScript.Echo "Failure assigning DNS Servers." & VbCrLF &_
            "Echec attribution des serveurs DNS",VbCritical,Titre
        End If
    Next
End Sub
'***************************************************************************************************
Sub ActiverDHCP() 
    Dim Titre,strComputer,objWMIService,colNetAdapters,objNetAdapter,errEnable,errGateways,errDNSServers
    Titre = "Connexion avec WIFI DHCP Activé"
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    
    Set colNetAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
    
    For Each objNetAdapter in colNetAdapters
        errEnable = objNetAdapter.EnableDHCP()
        errGateways = objNetAdapter.SetGateways()
        errDNSServers = objNetAdapter.SetDNSServerSearchOrder()
    Next
    If errEnable = 0 AND errGateways = 0 AND errDNSServers = 0 Then
        MsgBox "L'adresse IP a été bien changé et le DHCP est désormais Activé !" & vbCrLf & Titre,64,Titre
    Else
        MsgBox "L'adresse IP n'a pas été changé !" ,16, "Changer IP"
    End If
End Sub
'***************************************************************************************************

[GADENSEB]

OULA SUPER CODE !

dans quoi je le mets pour qu'il s'éxécute ?

Je dois renommée Réseau A et Réseau B avec les vrais noms de réseau WIFI ?

[hackoofr]

OULA SUPER CODE !
dans quoi je le mets pour qu'il s'éxécute ?
Je dois renommée Réseau A et Réseau B avec les vrais noms de réseau WIFI ?

Juste vous copier et coller ce code dans votre Notepad puis enregistrer-le sous le nom par exemple : ChangeMyIp.vbs
Puis exécutez-le par un simple double-clique => un petit menu avec inputbox

1. Valeur = 1 pour Réseau A
   
2. Valeur = 2 pour Réseau B