Discussion :

[kilou88]

Bonjour,

Par le biais d'un script PowerShell, je souhaite ouvrir un site web sélectionner/copier son contenu (Control-A/Control-C) puis ouvrir un éditeur de texte par exemple notepad pour coller les infos collectées.

Pour cela j'utilise le script ci-dessous qui ouvre bien le site et notepad, mais pas de sélection (ni copier/coller).

Pour info je suis débutant ... si qq peux m’éclairer merci pour votre réponse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
add-type -AssemblyName microsoft.VisualBasic
add-type -AssemblyName System.Windows.Forms
 
$Process = Start-Process "firefox.exe"  "http://monsite-web/index.php"
Start-Sleep -Milliseconds 500
[Microsoft.VisualBasic.Interaction]::AppActivate($Process.Id)
[System.Windows.Forms.SendKeys]::SendWait("^{A}")
[System.Windows.Forms.SendKeys]::SendWait("^{C}")

$Process = Start-Process notepad.exe -PassThru
Start-Sleep -Milliseconds 500
[Microsoft.VisualBasic.Interaction]::AppActivate($Process.Id)
[System.Windows.Forms.SendKeys]::SendWait("^{V}")
Start-Sleep -Seconds 3

[Laurent Dardenne]

Salut,
je pense que ton code attend la création du process, mais pas la fin de chargement de la page dans un onglet du process.
Une autre piste, le cmdlet Invoke-WebRequest (Gets content from a web page on the Internet).

[kilou88]

Merci, je vais chercher dans cette direction.

[hackoofr]

Je viens de tester à présent cette commande externe GRABURL.EXE
Son help :

Usage: graburl [-h] [-a] [-9] URL [URL [...]]

Supports URLs of the form:

[http://]site[:port][/path]

-h retrieve HTTP headers only
-a transfer in ASCII mode
-9 use HTTP/0.9 protocol

Examples:

graburl http://www.sun.com
graburl -h www.sun.com
graburl www.sun.com:80/index.html

Avec un Batch :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
@echo off
Cmd /c GRABURL.EXE "http://www.developpez.net/forums/d1441476/general-developpement/programmation-systeme/windows/scripts-batch/copier-coller-site-web/" > "file.html"
Start /wait file.html

Avec un Vbscript :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Option Explicit
Dim MaCommande,URL,File
URL = "http://www.developpez.net/forums/d1441476/general-developpement/programmation-systeme/windows/scripts-batch/copier-coller-site-web/"
File = "file.html"
MaCommande = "GRABURL.EXE "& DblQuote(URL) & " > " & DblQuote(File) & "& Start /wait " & File &""
Call Executer(MaCommande,0,False)'La valeur 0 pour cacher la console MS-DOS
'**************************************************************************************************************
Function Executer(StrCmd,Console,bWaitOnReturn)
    Dim ws,MyCmd,Resultat
    Set ws = CreateObject("wscript.Shell")
'La valeur 0 pour cacher la console MS-DOS
    If Console = 0 Then
        MyCmd = "CMD /C " & StrCmd & ""
        Resultat = ws.run(MyCmd,Console,bWaitOnReturn)
        If Resultat = 0 Then
        Else
            MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
        End If
    End If
'La valeur 1 pour montrer la console MS-DOS
    If Console = 1 Then
        MyCmd = "CMD /K " & StrCmd & " "
        Resultat = ws.run(MyCmd,Console,bWaitOnReturn)
        If Resultat = 0 Then
        Else
            MsgBox "Une erreur inconnue est survenue !",16,"Une erreur inconnue est survenue !"
        End If
    End If
    Executer = Resultat
End Function
'***********************************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'**********************************************************************************************

[kilou88]

C'est pas mal, mais je récupère le code source de la page (balises ...) moi je recherche l' équivalent d'un control-A/control-C ... d'ou ma volonté du sendkeys, mais cela semble complexe ...

Merci quand même

[hackoofr]

C'est pas mal, mais je récupère le code source de la page (balises ...) moi je recherche l' équivalent d'un control-A/control-C

Dans ce cas et à la limite, je vous suggère d'utiliser ce Vbscript :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Option Explicit
Dim Ws,Fso,MaCopie,URL,LogFile
Set Ws = CreateObject("Wscript.Shell")
Set Fso = CreateObject("Scripting.FileSystemObject")
LogFile = Left(Wscript.ScriptFullName, InstrRev(Wscript.ScriptFullName, ".")) & "txt"
if Fso.FileExists(LogFile) Then
    Fso.DeleteFile LogFile
end if
URL = "http://www.developpez.net/"
MaCopie = CopierColler(URL)
Call WriteLog(MaCopie)
Ws.Run DblQuote(LogFile)
'******************************************************************************************************************************************
Function CopierColler(URL)
    Dim ie
    Set ie = CreateObject("InternetExplorer.Application") 
    ie.Navigate(URL) 
    ie.Visible=false
    DO While ie.busy
    Loop
    CopierColler = ie.document.documentElement.innertext 
    ie.Quit 
    Set ie=Nothing
End Function
'******************************************************************************************************************************************
Sub WriteLog(strText)
    Dim fs,ts 
    Const ForAppending = 8
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set ts = fs.OpenTextFile(Left(Wscript.ScriptFullName, InstrRev(Wscript.ScriptFullName, ".")) & "txt", ForAppending, True)
    ts.WriteLine strText
    ts.Close
End Sub
'******************************************************************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'******************************************************************************************************************************************

[kilou88]

beaucoup !!!!!
C'est génial, c'est exactement ce que je souhaitais obtenir.