Discussion :

[jpvba65]

Bonjour le forum

J'utilise le code ci-dessous proposé par mercatog dans ce forum, je l'ai légèrement modifié pour qu'il s'adapte au nombre de cellule de la colonne.
Il me permet de générer un graphique après le traitement d'une autre macro.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Graphique()
'Macro proposée par mercatog
Dim Grf As ChartObject
Dim Sh As Worksheet
 
Set Sh = Sheets("Feuil1")
'On supprime tous les graphiques
For Each Grf In Sh.ChartObjects
    Grf.Delete
Next Grf
'On crée notre graphique
Set Grf = Sh.ChartObjects.Add(620, 30, 500, 200)
With Grf.Chart
    .ChartType = xlLineMarkers
    .SeriesCollection.NewSeries
    With .SeriesCollection(1)
        .Values = Sh.Range("J2:J" & Range("J" & Cells.Rows.Count).End(xlUp).Row)
        .XValues = Sh.Range("D2:D" & Range("D" & Cells.Rows.Count).End(xlUp).Row)
    End With
End With
Set Grf = Nothing
Set Sh = Nothing
 
End Sub

Ce code fonctionne très bien mais je voudrais rajouter une colonne (voir plusieurs autres qui ne sont pas forcement à côté) en .Values.
XValues resterait sur une colonne unique (D).

Je voudrais également pouvoir avec cette même macro modifier le nom des courbes qui par défaut s'appellent Série xxxx.

Je n'arrive pas à solutionner ces deux questions.

Pouvez-vous m'indiquer des pistes.

Merci pour votre aide

[mercatog]

Bonjour

Exemple avec 2 séries (colonnes J et P)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit
 
Sub Graphique()
Dim Grf As ChartObject
Dim Sh As Worksheet
Dim LastLig As Long
 
Application.ScreenUpdating = False
Set Sh = Worksheets("Feuil1")
With Sh
    'On supprime tous les graphiques
    For Each Grf In Sh.ChartObjects
        Grf.Delete
    Next Grf
    LastLig = .Range("D" & .Rows.Count).End(xlUp).Row
 
    'On crée notre graphique
    Set Grf = .ChartObjects.Add(620, 30, 500, 200)
End With
Set Sh = Nothing
 
With Grf.Chart
    .ChartType = xlLineMarkers
 
    With .SeriesCollection.NewSeries
        .Name = Sh.Range("J1")
        .XValues = Sh.Range("D2:D" & LastLig)
        .Values = Sh.Range("J2:J" & LastLig)
    End With
 
    With .SeriesCollection.NewSeries
        .Name = Sh.Range("P1")
        .Values = Sh.Range("P2:P" & LastLig)
    End With
End With
Set Grf = Nothing
End Sub

S'il y a plusieurs séries à ajouter on peut simplifier le code initial en faisant appel à une sous procédure qui se charge du traçage
(Exemple J, L et Q)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Explicit
 
Sub Graphique()
Dim Grf As ChartObject
Dim Sh As Worksheet
Dim LastLig As Long
 
Application.ScreenUpdating = False
Set Sh = Worksheets("Feuil1")
With Sh
    'On supprime tous les graphiques
    For Each Grf In Sh.ChartObjects
        Grf.Delete
    Next Grf
    LastLig = .Range("D" & .Rows.Count).End(xlUp).Row
    'On crée nos graphiques
    Set Grf = .ChartObjects.Add(620, 30, 500, 200)
End With
Set Sh = Nothing
Grf.Chart.ChartType = xlLineMarkers
 
TraceSerie Grf.Chart, 10, LastLig                     'colonne 10 J
TraceSerie Grf.Chart, 12, LastLig                     'colonne 12 L
TraceSerie Grf.Chart, 17, LastLig                     'colonne 17 Q
'on peut ajouter tant de colonnes...
 
Set Grf = Nothing
End Sub
 
Private Sub TraceSerie(ByVal Ch As Chart, ByVal Col As Integer, ByVal N As Long)
 
With Ch.SeriesCollection.NewSeries
    .Name = Ch.Parent.Parent.Cells(1, Col)
    .XValues = Ch.Parent.Parent.Range("D2:D" & N)
    .Values = Ch.Parent.Parent.Cells(2, Col).Resize(N - 1)
End With
End Sub

[jpvba65]

Bonjour mercatog

Merci pour ta réponse rapide.
Pour l'instant je teste la première solution qui me génère une erreur d'exécution 91: variable ou objet de bloc with non définie.
L'erreur se situe ici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.name = Sh.Range("J1")

J'ai déclaré "name" en temps que variable sans succès.
Je remarque que dans ton code name est écrit Name.
Dans "mon" code le N est systématiquement ramené à n.

Merci pour ton aide


Je viens d'essayer la solution N°2 qui fonctionne sans problème.
Pour l'instant je ne clos pas le post à cause du petit souci sur la solution N°1.

Merci

[mercatog]

C'est mon manque d'inattention
Déplace la ligne 20 à la fin du code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Sh = Nothing

[jpvba65]

effectivement c'est mieux.

Je vais néanmoins partir sur la solution N°2 qui est vraiment sympathique (sélection "multi" colonnes).

Dernière question:
Je voudrais insérer à coté de chaque points la valeur de la cellule correspondante.
Avec l'enregistreur de macro j'ai abouti à ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
ActiveSheet.ChartObjects("Graphique 2").Activate
    ActiveChart.FullSeriesCollection(2).Select
    ActiveChart.ClearToMatchStyle
    ActiveChart.ChartStyle = 228

Celà fonctionne quand on le fait en live mais le bout de code seul ou intégré à la macro ne fonctionne pas.

Merci encore mercatog

[mercatog]

Ajouter .ApplyDataLabels


Sinon code 2 légèrement modifié

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub Graphique()
Dim Grf As ChartObject
Dim Sh As Worksheet
Dim LastLig As Long
 
Application.ScreenUpdating = False
Set Sh = Worksheets("Feuil1")
With Sh
    'On supprime tous les graphiques
    For Each Grf In Sh.ChartObjects
        Grf.Delete
    Next Grf
    LastLig = .Range("D" & .Rows.Count).End(xlUp).Row
    'On crée nos graphiques
    Set Grf = .ChartObjects.Add(620, 30, 500, 200)
End With
Set Sh = Nothing
Grf.Chart.ChartType = xlLineMarkers
 
TraceSerie Grf, 10, LastLig                     'colonne 10 J
TraceSerie Grf, 12, LastLig                     'colonne 12 L
TraceSerie Grf, 17, LastLig                     'colonne 17 Q
'on peut ajouter tant de colonnes...
 
Set Grf = Nothing
End Sub
 
Private Sub TraceSerie(ByVal Ch As ChartObject, ByVal Col As Integer, ByVal N As Long)
 
With Ch.Chart.SeriesCollection.NewSeries
    .Name = Ch.Parent.Cells(1, Col)
    .XValues = Ch.Parent.Range("D2:D" & N)
    .Values = Ch.Parent.Cells(2, Col).Resize(N - 1)
    .ApplyDataLabels
End With
End Sub