Discussion :

[Missouflo]

Bonjour à tous,

Voilà ma question est relativement simple :
J'ai créé un userform qui permet à l'utilisateur de rechercher toutes les valeurs d'une feuille en rentrant deux informations : une valeur et un opérateur. Concrètement j'ai une ComboBox avec trois possibilités : = , <= et >= suivie d'une textbox où l'utilisateur peut entrer une valeur.
Et j'aimerais donc que lorsque l'on clique sur le bouton "OK" la macro compare les valeurs de ma feuille de calcul suivant ces deux critères.
J'ai rentré le code suivant mais ça ne fonctionne pas (Incompatibilité de type) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
If Range("A1").Value + Comparateur.Value + CInt(Valeur.Value) Then
    MsgBox "C'est bon"
Else: MsgBox "C'est pas bon"
End If

Il s'agit juste d'un code permettant de tester si la concaténation de la valeur de ma combobox (Comparateur) avec une valeur de la feuille et la valeur rentrée par l'utilisateur fonctionne. Et ça ne marche pas.
J'ai réussi à faire ce que je voulais avec un Select Case mais c'est un peu lourd d'autant que cette condition viendrait idéalement s'ajouter à d'autres dans un grand If donc j'aurais voulu savoir s'il y avait la possibilité de procéder par concaténation.

Merci d'avance.

[Invité]

à moins de factoriser je ne voies pas! en plus si tu factorises, tu pourra simplifier les testes IF...ELSE.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Function Compar(V1 As String, Comparateur As String, V2 As String) As Boolean
    Select Case Comparateur
        Case "<"
            If V1 < V2 Then Compar = True
        Case "<="
             If V1 <= V2 Then Compar = True
        Case "="
             If V1 = V2 Then Compar = True
        Case "=>"
             If V1 >= V2 Then Compar = True
        Case ">"
             If V1 > V2 Then Compar = True
    End Select
End Function
Sub TestCompar()
If Compar(Range("A1").Value, Comparateur.Value, Valeur.Value) = True Then
    MsgBox "C'est bon"
Else: MsgBox "C'est pas bon"
End If
End Sub

[casefayere]

Bonjour Robert,
je mets ce que j'avais préparé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Select Case Comparateur
  Case "="
    If Range("A1") = CInt(Valeur) Then
      MsgBox "c'est bon"
    Else: MsgBox "ce n'est pas bon"
    End If
  Case "<="
    If Range("A1") <= CInt(Valeur) Then
      MsgBox "c'est bon"
    Else: MsgBox "ce n'est pas bon"
    End If
  Case ">="
    If Range("A1") >= CInt(Valeur) Then
      MsgBox "c'est bon"
    Else: MsgBox "ce n'est pas bon"
    End If
  End Select

avec mes excuses

[Missouflo]

Super merci beaucoup.
Je vais factoriser en effet, ça sera plus simple.

Casefayere : j'ai exactement le même code, à la lettre près ^^

[mercatog]

Utilisation de Evaluate

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
If Evaluate(Range("A1").Value & Comparateur.Value & CInt(Valeur.Value)) Then
    MsgBox "C'est bon"
Else
    MsgBox "C'est pas bon"
End If

[casefayere]

Bonjour à tou(te)s,

Toujours aussi efficace mercatog, il me semblais qu'il y avais une possibilité, mais à mon aaaaage, on oublie.