Discussion :

[m1cfv]

Bonjour,

Je viens vers vous parce que j'ai un problème sur mon projet, je voudrais réaliser un fichier de suivi client avec un suivi des reglements. J'aimerais que ce suivi soit matérialisé par un tableau dans mon userform, d'où la listbox. Et que celui-ci récapitule tous les règlements d'un même client choisi par une combobox.

Il me semble qu'il y a plusieurs possibilités :
- soit qu'il sélectionne directement dans la listbox ( j'ai essayer d'adapter un code mais il ne marche pas.. je l'ai laissé dans la pièce jointe)
- soit que la sélection dans la liste déroulante permet de faire un filtre vers une autre feuille et qu'on puisse ensuite faire un visuel de la recherche grâce au row source de la propriété de la listbox

si vous pouviez m'aider je vous en serait très reconnaissante ! =)

Merci d'avanceVBA PROJET1.zip

[mercatog]

Un début de réponse pour le remplissage de la listbox resultats à partir des données de la feuille règlements en fonction du choix de la combobox RefC.

Commence par effacer la propriété RowSource de ta combobox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Option Explicit
 
Private Sub UserForm_Initialize()
Dim LastLig As Long
 
With Feuil2
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    Me.RefC.List = .Range("A2:A" & LastLig).Value
End With
 
Me.resultats.ColumnCount = 4
End Sub
 
Private Sub RefC_Change()
Dim LastLig As Long, i As Long
Dim k As Byte
 
Me.resultats.Clear
With Feuil3
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 2 To LastLig
        If .Range("A" & i) = Me.RefC Then
            Me.resultats.AddItem Format(.Range("E" & i), "dd/mm/yyyy")
 
            For k = 1 To 4
                Me.resultats.List(Me.resultats.ListCount - 1, k) = .Range("E" & i).Offset(, k)
            Next k
        End If
    Next i
End With
End Sub

[m1cfv]

Merci beaucoup, désolée de pas avoir répondu avant, mais maintenant que j'ai essayé ça marche très bien !

Je me demandais tout de même si il y avait une possibilité pour que liste déroulante n'ait pas de doublon?

Encore merci

Cordialement