Discussion :

[pepsister]

Bonjour,

voila je souhaite quand ma macro rencontre une anomalie qu'elle m'envoie un mail et s'arrête.
J'ai cherché il y a bcp de choses sur internet plus ou moins compliqué, certains passent directement par SFTP (je ne sais pas trop ce que c'est), enfin j'ai essayé pas mal de choses et ca ne marche pas.
J'ai vu sur ce forum une solution en passant par outlook soit disant plus simple donc pourquoi pas.
Mais quand je lance ma macro et qu'on arrive sur l'envoie de mail j'ai le message suivant:
Erreur d'exécution '429': Un composant ActiveX ne peut pas créer d'objet.

Peut-être faut il télécharger une librairie supplémentaire? Mais où? Excel ou outlook? Laquelle? J'ai coché dans outils > Référence, la librairie microsoft outlook.
Peut etre est-ce un pb dans ma macro?

Je mets mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
 Dim Maille As String
 Dim Sujet As String
 Dim DernLigne as long
 
DernLigne = Range("A1048576").End(xlUp).Row
For a = 2 To DernLigne
  If Sheets("Feuil3").Cells(a, 4).Value <> "SUCCEED" Then
  'alors on rejette directement
  Sheets("Résultat").Range("A1").Value = "ANOMALIE"
  Maille = "moi@gmail.com"
  Sujet = "Anomalie"
 
Set OL = CreateObject("Outlook.Application")
Set MyItem = OL.CreateItem(olMailItem)
With MyItem
    .To = Maille
    .Subject = Sujet
    .Categories = "Banking-Info"
    .OriginatorDeliveryReportRequested = False
    .ReadReceiptRequested = False
    .Send
End With
Exit Sub
End If
Next

Merci pour votre aide,

[parmi]

Bonjour,

Comment déclares-tu tes objets OL et MyItem ?

Si tu ne mets pas de référence à Outlook, utilise 0 comme paramètre ici
Set MyItem = OL.CreateItem(0)

[FrancoisDassault]

Bonjour ,

Je ne vois pas comment tu envoies ton mail (a si .send a la fin) , mais voici ce que j'ai fait de mon coté si ca peu t'aider
enlèves les commentaires que tu veux et insere ce code dans ta boucle FOR a ....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Private Sub CreateMail()
'**********************************************************************************
' Création d'un mail pour un envoi de données via Outlook
' le 28 mars 2012 par Francois
' Nécessite les références : Microsoft outlook xx.0 Object library
'***********************************************************************************
 
'Permet la visualisation du mail sans l'ouverture d'Outlook
Dim OLappli As Outlook.Application
Set OLappli = New Outlook.Application
 
'Variables informations du mail
Dim OLemail As Outlook.MailItem
Dim DestiMail As String
Dim DestiMail2 As String
Dim DestiMail3 As String
Dim TitreMail As String
Dim CorpsMail As Variant
Dim Hyperlien As Variant
Dim Hyperlien1 As Variant
Dim Hyperlien2 As Variant
Dim Hyperlien3 As Variant
 
'Variables des destinataires
'principal
DestiMail = "prenom.nom1@gmail.com"
'en copie
'DestiMail2 = "prenom.nom2@gmail.com"
'en copie cachée
'DestiMail3 = "prenom.nom3@gmail.com"
 
'---------------------------------
'Construction du titre et du corps
'---------------------------------
'Titre
TitreMail = "Fichier ALERTE"
 
'Corps   & = concatene  et vbCrlf = Retour à la ligne
CorpsMail = "Bonjour, " & vbCrLf _
          & "Le fichier ALERTE vient d'etre crée ..." & vbCrLf _
          & "                                       " & vbCrLf _
          & "Cordialement"
 
'---------------------------------------
'Construction du Mail avec les variables
'---------------------------------------
    Set OLemail = OLappli.CreateItem(olMailItem)
        OLemail.To = DestiMail
'        OLemail.CC = DestiMail2
'        OLemail.BCC = DestiMail3
        OLemail.Subject = TitreMail
        OLemail.Body = CorpsMail
 
        'Si on désire mettre un format
        'Olemail.HTMLBody=
        'OLemail.BodyFormat = olFormatHTML
 
    'Demande un accusé de réception
'    OLemail.OriginatorDeliveryReportRequested = True
 
    'Demande un accusé de lecture
'        OLemail.ReadReceiptRequested = True
 
    'Supprime le Mail dans le dossier : Éléments envoyés
'        OLemail.DeleteAfterSubmit = True
 
    ' Affiche le Mail et envoi en manuel
        OLemail.Display
    'OU
    ' Envoie le message directement
        'OLemail.Send
Fin:
    ' Vide la mémoire
    Set OLemail = Nothing
    Set OLappli = Nothing
 
End Sub

[jijie]

ici ton mail sera envoyer automatiquement avec ".send"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Public Sub EnvoiAutomatiqueMail()
Dim OutlookApp As Object
Dim OutlookMail As Object
Dim DernLigne As Long
Dim a As Long
Dim Maille As String
Dim Sujet As String
 
   On Error GoTo EnvoiAutomatiqueMail_Error
 
DernLigne = Sheets("Feuil3").Range("A1048576").End(xlUp).Row
For a = 2 To DernLigne
  If Sheets("Feuil3").Cells(a, 4).Value <> "SUCCEED" Then
  'alors on rejette directement
  Sheets("Résultat").Range("A1").Value = "ANOMALIE"
  Maille = "moi@gmail.com"
  Sujet = "Anomalie"
 
Set OutlookApp = CreateObject("outlook.application")
Set OutlookMail = OutlookApp.CreateItem(0)
With OutlookMail
 
 ' pour choisir l'expéditeur : http://www.developpez.net/forums/d1315835/logiciels/microsoft-office/excel/macros-vba-excel/envoyer-email-from-expediteur/
.Subject = Sujet
.To = Maille
.Body = "Anomalie sur ligne: " & a
.Send 'sans autorisation
 
 
Exit Sub 'pour arrêter l'envoi de mail à la première anomali trouvé!
End With
End If
Next a
  On Error GoTo 0
   Exit Sub
 
EnvoiAutomatiqueMail_Error:
 
  MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure EnvoiAutomatiqueMail of Module Mail"
 
End Sub

Par contre il te faut inscrire la référence "Michrosoft office outlook view control"
Je pense qu'il te faut également que Outlook soit ouvert!

Sans outlook tu as un exemple ici mais il te faut renseigné ton FAI avant ! si tu travail toujours sur le même post cela ne pose pas de problème! regarde ici il y a un fichier sur la 9ème discussion

[pepsister]

la ligne exacte qui pose problème c'est vraiment celle-ci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set OutlookApp = CreateObject("outlook.application")

J'ai essayé avec outlook ouvert et outlook fermé mais rien ne marche.

[parmi]

Enlève toutes les références sauf les 4 de base:
- Visual Basic for Applications
- Microsoft Excel X.X Object Library
- OLE Automation
- Microsoft Office X.X Object Library

Au cas où... pour enlever les références, aller dans l'éditeur VBA (Alt-F11), menus Outils, puis Références

As-tu toujours l'erreur 429 après cette modif ?