Discussion :

[devilsnake88]

Bonjour, j'aurais aimé savoir si il était possible/savoir comment je pourrais faire ceci:
Pour chaque clés dans: HKLM\Software\Microsoft\Windows NT\CurrentVersion\Profile List
vérifier que chaque utilisateurs, vérifier que la clé "ProfileImagePath" est égale à "C:\Users\%username%" et non pas "C:\Users\%username%.nomdelamachine".
Si c'est le cas, modifier "C:\Users\%username%.nomdelamachine" en "C:\Users\%username%".

Merci pour votre aide!

[I'm_HERE]

salut,

tester sous un xpsp2:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off

set computer=%computername%

for /f "tokens=*" %%a in ('
 reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList"^|findstr "HKEY_"') do (
    for /f "tokens=1,2*" %%i in ('
      reg query "%%a"^|find /i "ProfileImagePath"^|findstr /ie "\.%computer%"') do (
           Set "ImgPath=%%~k"
           Setlocal enabledelayedexpansion
              if defined ImgPath (
                Set "ImgPath=!ImgPath:.%computername%=!"
                echo SUBKEY: %%~na 
                echo BEFORE: %%~k
                echo AFTER : !ImgPath!
                echo(
                reg add "%%a" /v ProfileImagePath /t REG_EXPAND_SZ /d "!ImgPath!" /f >Nul
              )
           endlocal        
    )
)
pause

[devilsnake88]

Merci bien I'm_HERE!