Discussion :

[nacereddine.mourad]

Bonjour :

Une fois encor j’ai besoin de votre soutien pour faciliter mon travail.
Explication :

J’ais un UserForm3 dans mon classeur Excel, avec :

-Quatre OptionButton
-Une TextBox1 = le texte a recherche (mot dans tous les positions de la phrase)
-CommandButton4 = la recherche (le code)
-Une ListBox1 = le résultat de la recherche (affichage de toute les donnée de la ligne)

Objectif :

Recherche filtré avec CommandButton4

OptionButton1 (Descriptions) = filtre sur colonne A
OptionButton2 (Qnt) = filtre sur colonne B
OptionButton3 (Code) = filtre sur colonne C
OptionButton4 (Norme) = filtre sur colonne D
OptionButton5 (Lieux) = filtre sur colonne E

J’ai essayé plusieurs code mais je ne c’est pas comment l’adapter a mon classeur, ces pour cela que je n’ais pas de code.

Merci pour votre compréhension.

[defluc]

Bonjour,

Il faudrait au moins savoir ce qui provoque l'affichage du UserForm

[nacereddine.mourad]

Bonjour :
Un simple
UserForm3.Show dans un bouton sur une feuille.

[nacereddine.mourad]

Bonjour

Sa marche bien pour la première recherche, mais quand je veux changer de OptionButton pour autre recherche ; sa donne
Erreur d’exécution 9
L’indice n’appartient pas à la sélection.

dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Sub Recherche()
‘ReDim Tb2(1 To Indice, 1 To 5)

Le mieux, c’est que la recherche ce déclencher une fois que j’appui sur CommandButton4, non pas sur les OptionButton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Option Explicit
Option Compare Text
 
Dim Ws As Worksheet
Dim Colonne As Integer
 
Private Sub CommandButton4_Click()
  Recherche
End Sub
 
Private Sub OptionButton1_Click()
' Descriptions
  Colonne = 1
  Recherche
End Sub
 
Private Sub OptionButton2_Click()
' Quantité
  Colonne = 2
  Recherche
End Sub
 
Private Sub OptionButton3_Click()
' Code
  Colonne = 3
  Recherche
End Sub
 
Private Sub OptionButton4_Click()
' Norme
  Colonne = 4
  Recherche
End Sub
 
Private Sub OptionButton5_Click()
' Lieux
  Colonne = 5
  Recherche
End Sub
 
Private Sub UserForm_Initialize()
 
  Set Ws = Sheets("BDD")
 
  With Me.ListBox1
    .ColumnCount = 5
    .ColumnWidths = "-1;-1;-1;-1;-1"
  End With
 
  Me.OptionButton1 = True
 
End Sub
 
Sub Recherche()
 
Dim J As Long, NbLg As Long
Dim Tb1, Tb2()
Dim I As Integer, Indice As Integer
 
  NbLg = Ws.Range("A" & Rows.Count).End(xlUp).Row
  Tb1 = Ws.Range("A3:F" & NbLg)
  For J = 1 To UBound(Tb1)
    If Tb1(J, Colonne) Like "*" & Me.TextBox1 & "*" Then
      Tb1(J, 6) = "X"
      Indice = Indice + 1
    End If
  Next J
 
  ReDim Tb2(1 To Indice, 1 To 5)
  Indice = 0
  For J = 1 To UBound(Tb1)
    If Tb1(J, 6) = "X" Then
      Indice = Indice + 1
      For I = 1 To 5
        Tb2(Indice, I) = Tb1(J, I)
      Next I
    End If
  Next J
  With Me.ListBox1
    .Clear
    .List() = Tb2
  End With
 
  End Sub

merci encor.

[defluc]

Normal, Indice = 0 donc il faut prévoir une action dans ce cas, soit attribuer une valeur par défaut > 0, soit ne pas exécuter les instructions qu suivent.

[nacereddine.mourad]

Banzai64

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Recherche()
Dim J As Long, NbLg As Long
Dim Tb1, Tb2()
Dim I As Integer, Indice As Integer
 
  Me.ListBox1.Clear
  NbLg = Ws.Range("A" & Rows.Count).End(xlUp).Row
  Tb1 = Ws.Range("A3:F" & NbLg)
  For J = 1 To UBound(Tb1)
    If Tb1(J, Colonne) Like "*" & Me.TextBox1 & "*" Then
      Tb1(J, 6) = "X"
      Indice = Indice + 1
    End If
  Next J
  If Indice > 0 Then
    ReDim Tb2(1 To Indice, 1 To 5)
    Indice = 0
    For J = 1 To UBound(Tb1)
      If Tb1(J, 6) = "X" Then
        Indice = Indice + 1
        For I = 1 To 5
          Tb2(Indice, I) = Tb1(J, I)
        Next I
      End If
    Next J
    With Me.ListBox1
      .List() = Tb2
    End With
  End If
 
End Sub