Discussion :

[epsilonenadia]

Bonjour, j'ai beau cherché sur le net , mais je suis perdue sachant que je suis débutante sur VBA

Je m'explique j'ai 2 Feuilles

Feuil1 : représente une base de donnée des produits que j'ai dans mon stocks
(j'ai 8 colonnes "A,B,C,D,E,F,G,H) (7sont déja saisies et verrouillées, la 8em "H" est a saisir avec le temps)

Feuil2: représente un "bon de commande" qui doit être remplie automatiquement:

Un boutton qui reçoit une macro qui :

une fois colonne H dans "feuil1" reçoit une valeur (c'est a dire elle est <> null , on recopie dans un tableau qui commence à partir de "D11", les lignes dont la colonne H <>0, sachant que je dois recopier que les colonnes (A,B,C,D,H)


Si quelqu'un peut m'aider je lui serrais énormément reconnaissante , merci d'avance vous faites un super travaille

[Invité]

Bonsoir,


Une solution possible à adapter à vos feuilles :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
Public ShArticles As Worksheet
Public TitreArticles As Long
Public DerniereLigneArticles As Long
Public CelluleArticles As Range
Public AireArticles As Range
 
Public ShCommande As Worksheet
Public TitreCommande As Long
Public DerniereLigneCommande As Long
Public LigneCommandeEnCours As Long
Public ColonneDebutTableau As Long
 
Sub CopierLesArticlesSelectionnesDansLaFeuilleCommande()
 
    Set ShArticles = Sheets("Articles")
    TitreArticles = 10
    DerniereLigneArticles = ShArticles.Cells(ShArticles.Rows.Count, 8).End(xlUp).Row
 
    Set ShCommande = Sheets("Commande")
    TitreCommande = 10
    DerniereLigneCommande = ShCommande.Cells(ShCommande.Rows.Count, 8).End(xlUp).Row
    LigneCommandeEnCours = TitreCommande + 1
    ColonneDebutTableau = 4
 
    If DerniereLigneCommande > TitreCommande Then
        Range(ShCommande.Cells(TitreCommande + 1, 4), ShCommande.Cells(DerniereLigneCommande, 8)).ClearContents
    End If
 
    Set AireArticles = Range(ShArticles.Cells(TitreArticles + 1, 8), ShArticles.Cells(DerniereLigneArticles, 8))
 
    If DerniereLigneArticles > TitreArticles Then
 
       For Each CelluleArticles In AireArticles
 
            If CelluleArticles <> "" Then
                With ShCommande
                     .Cells(LigneCommandeEnCours, ColonneDebutTableau) = CelluleArticles.Offset(0, 1 - 8)
                     .Cells(LigneCommandeEnCours, ColonneDebutTableau + 1) = CelluleArticles.Offset(0, 2 - 8)
                     .Cells(LigneCommandeEnCours, ColonneDebutTableau + 2) = CelluleArticles.Offset(0, 3 - 8)
                     .Cells(LigneCommandeEnCours, ColonneDebutTableau + 3) = CelluleArticles.Offset(0, 4 - 8)
                     .Cells(LigneCommandeEnCours, ColonneDebutTableau + 4) = CelluleArticles
                     LigneCommandeEnCours = LigneCommandeEnCours + 1
                End With
            End If
 
       Next CelluleArticles
 
       ShCommande.Activate
 
    Else
 
       MsgBox "Pas d'article sélectionné !", vbCritical, "Etablir une commande"
 
    End If
 
 
    Set AireArticles = Nothing
    Set ShCommande = Nothing
    Set ShArticles = Nothing
 
End Sub

Cordialement.

[keygen08]

Bonjour,
Juste un debut de solution en collant ce code dans le bouton qui active la macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CommandButton1_Click()
Dim cell As Range
'pour toute les cellules de la colonne H
For Each cell In Worksheets("BDD").Range("h1:h" & Sheets("BDD").[h65000].End(xlUp).Row)
'dont la valeur est differente de rien
    If cell.Value <> "" Then
        'recherche la derniere ligne vide sur Bon de commande
        r = Sheets("Bon de commande").Range("a65000").End(xlUp).Row + 1
        'pour les colonnes 1 à 4(a,b,c,d)
        For c = 1 To 4
        'coller la valeur de BDD sur bon de commande
        Sheets("bon de commande").Cells(r, c) = Sheets("BDD").Cells(cell.Row, c)
        Next c
        'pour la colonne 8(H)
        Sheets("bon de commande").Cells(r, 5) = Sheets("BDD").Cells(cell.Row, 5)
    End If
Next cell
End Sub

[epsilonenadia]

Merci énormément Eric KERGRESSE et keygen08
J'ai fais mes modifications sur le fichier de Eric KERGRESSE

Mais svp je veux ajouter une condition sur BC (la colonne a remplier)
Si (Contrôle>=0)alors msg d'erreur
"quantité dépassé"
Sachant que contrôle , c QT-BC
c a dire (qt en stock-quantité qu on veut commander)

Merci bcp , j'avais une grande pression

[Invité]

Bonjour,

Je n'ai pas la possibilité de lire les fichiers compressés en .rar. Si votre fichier est en xlsm, faîtes en une copie en .xls en 1997-2003 et mettez le ligne.

Cordialement.

[epsilonenadia]

Désolée le voila , et Merci

[Invité]

J'ai ajouté une macro événementielle dans la feuille Articles, créé une zone nommée : ZoneBonDeCommande correspondant à la colonne sous le titre BC et une mise en forme conditionnelle sur la colonne Contrôle.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Sub Worksheet_Change(ByVal ZZ As Range)
 
   If ZZ.Count > 1 Then Exit Sub
 
   On Error Resume Next
   If Not Application.Intersect(ZZ, Range("ZoneBonDeCommande")) Is Nothing Then
 
        Select Case ZZ.Offset(0, -1)
        Case Is < 0
            MsgBox "Quantité disponible dépassée !" & Chr(10) & "Diminuez votre quantité !", vbCritical, "Contrôle du stock disponible"
            ZZ = ""
        Case 0
            MsgBox "Stock à 0 !" & Chr(10) & "Réapprovisionnez cet article !", vbCritical, "Contrôle du stock disponible"
        End Select
   End If
 
End Sub

Pour votre autre demande sur la feuille Commande, mettez en ligne un autre message car je n'aurai pas la possibilité de vous répondre.

Bon courage.


Cordialement.