Discussion :

[Vincilian]

Bonjour, je ne comprends pas comment résoudre mon problème.
J'ai un classeur 1 que je crée chaque jour et je bosse dessus...
En fin de journée, un bouton (une macro) devrait permettre d'exporter l'une des feuilles de ce classeur dans un second qui doit se créer.
J'ai une bel erreur 9 comme quoi il arrive pas à trouver le nouveau classeur que je viens d'ouvrir...
Si une âme charitable veut bien me porter secours....

Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub Export_blabla()
'
'
Dim nom, nom2 As String
Dim datduJour, jj, mm, aa As String
 
    datduJour = Date
    jj = Mid(datduJour, 1, 2)
    mm = Mid(datduJour, 4, 2)
    aa = Mid(datduJour, 7, 4)
    datduJour = jj & "-" & mm & "-" & aa
 
    nom = ActiveWorkbook.Name
    nom2 = "Com " & datduJour & ".xls"
 
    Sheets("Com_origine").Select
    Cells.Select
    Selection.Copy
 
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Add
    xlBook.SaveAs Filename:= _
        "(mon chemin)" & nom2, FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
    xlApp.Visible = True
 
'logiquement pour moi le classeur en ligne est celui que je viens d'ouvrir ???
 
    Sheets("Feuil1").Activate
' j'ai une erreur 9
 
    Sheets("Feuil1").Select
    Cells.Select
    ActiveSheet.Paste
 
    Sheets("Feuil1").Name = "Com_a_envoyer"
    Sheets("Feuil2").Select
    Sheets("Feuil2").Name = "Com_secondaire"    
 
End Sub

[Marc-L]

Bonjour,

merci d'éditer ton message et d'y utiliser l'icône # dévolue pour le code puis enfin d'indiquer quelle n° de ligne déclenche l'erreur
et le message exact !

Si le code part bien d'Excel, pourquoi donc ouvrir un second Excel en ligne n° … ?!

Tu peux tout reprendre en utilisant l'Enregistreur de macros pour te donner une nouvelle base de code …

[Theze]

Bonjour,

Teste ce qui suit en adaptant le chemin sur le disque. Lors de la copie d'une feuille, si Before ou After sont omis, un nouveau classeur est créé par défaut :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub Exporter()
 
    Dim Classeur As Workbook
    Dim Nom As String
    Dim Chemin As String
 
    'à adapter...
    Chemin = "C:\"
 
    Nom = "Com " & Format(Date, "dd-mm-yy") & ".xls"
 
    'si Before ou After sont omis, un nouveau classeur est créé par défaut
    Sheets("Feuil1").Copy
 
    Set Classeur = ActiveWorkbook
 
   With Classeur
 
        .Worksheets("Feuil1").Name = "Com_a_envoyer"
        .Worksheets("Feuil2").Name = "Com_secondaire"
        .SaveAs Chemin & Nom
 
    End With
 
End Sub

Hervé.

[Theze]

Oups, désolé,

petite erreur dans mon code car le classeur créé ne contient qu'une feuille (ça m'apprendra à le tester avant !). Celui-ci fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub Exporter()
 
    Dim Classeur As Workbook
    Dim Fe As Worksheet
    Dim Nom As String
    Dim Chemin As String
 
    'à adapter...
    Chemin = "D:\"
 
    Nom = "Com " & Format(Date, "dd-mm-yy") & ".xls"
 
    'si Before ou After sont omis, un nouveau classeur est créé par défaut
    Sheets("Feuil1").Copy
 
    Set Classeur = ActiveWorkbook
 
   With Classeur
 
        .Worksheets("Feuil1").Name = "Com_a_envoyer"
        Set Fe = .Worksheets.Add(.Worksheets("Com_a_envoyer"))
        Fe.Name = "Com_secondaire"
        .SaveAs Chemin & Nom
 
    End With
 
End Sub

Hervé.